sys-fs/rar2fs/rar2fs-1.29.5.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36

# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

inherit autotools

DESCRIPTION="A FUSE based filesystem that can mount one or multiple RAR archive(s)"
HOMEPAGE="https://hasse69.github.io/rar2fs/ https://github.com/hasse69/rar2fs"
SRC_URI="https://github.com/hasse69/${PN}/releases/download/v${PV}/${P}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="debug"

# Note that upstream unrar sometimes breaks ABI without updating the SONAME
# version so try rebuilding rar2fs if it doesn't work following an unrar
# upgrade.
RDEPEND=">=app-arch/unrar-5:=
	sys-fs/fuse:0"
DEPEND="${RDEPEND}"

src_prepare() {
	default
	eautoreconf
}

src_configure() {
	export USER_CFLAGS="${CFLAGS}"

	econf \
		--with-unrar="${ESYSROOT}"/usr/include/libunrar \
		--disable-static-unrar \
		$(use_enable debug)
}