Version bump with minor bugfixes.

Package-Manager: portage-2.2.0_alpha100/cvs/Linux x86_64

3 files changed, 249 insertions, 6 deletions

diff --git a/dev-libs/glib/ChangeLog b/dev-libs/glib/ChangeLog
index addae4d748b4..6fb596db78fa 100644
--- a/dev-libs/glib/ChangeLog
+++ b/dev-libs/glib/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-libs/glib
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/glib/ChangeLog,v 1.509 2012/03/27 03:16:18 tetromino Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/glib/ChangeLog,v 1.510 2012/04/14 03:30:40 tetromino Exp $
+
+*glib-2.32.1 (14 Apr 2012)
+
+  14 Apr 2012; Alexandre Rostovtsev <tetromino@gentoo.org> +glib-2.32.1.ebuild:
+  Version bump with minor bugfixes.
 
   27 Mar 2012; Alexandre Rostovtsev <tetromino@gentoo.org> glib-2.28.8.ebuild,
   glib-2.30.2.ebuild, glib-2.30.2-r1.ebuild, glib-2.30.3.ebuild,
diff --git a/dev-libs/glib/Manifest b/dev-libs/glib/Manifest
index 4cc4bc20c13e..c8cb778a1c72 100644
--- a/dev-libs/glib/Manifest
+++ b/dev-libs/glib/Manifest
@@ -27,6 +27,7 @@ DIST glib-2.28.8.tar.xz 5223564 RMD160 9f665eee95990ace173676a4ad7aeeb0cc17fef9
 DIST glib-2.30.2.tar.xz 5818860 RMD160 d8fc7c876bd15ea3a9255d4d0a67d745e3790488 SHA1 bc7be8572122997e4d5fc6691f51602f28cd4e3a SHA256 f0e91e6333321ddb48fa12b5c66f56c3d5f05325748c66dd2e9016c278ff8e82
 DIST glib-2.30.3.tar.xz 5642448 RMD160 0887b08e2fff75c325ed1fb1123baaf42dc9779b SHA1 ec97dd659862dca05d18093a6ea6c309dcff0cdd SHA256 e6cbb27c71c445993346e785e8609cc75cea2941e32312e544872feba572dd27
 DIST glib-2.32.0.tar.xz 6090792 RMD160 475941a8193c19dc443012ba8931b456482aaf55 SHA1 c4f9b6feb76b1b2364d6132fc55599d928622f0a SHA256 cde9d9f25ed648069c547e323897ad9379974e1f936b4477fa51bcf1bb261ae4
+DIST glib-2.32.1.tar.xz 6138200 RMD160 d56ab662502916574e2286f92c2c56dc8aad210d SHA1 3f94733d0e79e5ff10d5ca8735ae5d7f11f2edc0 SHA256 484d5b7fc09f3fa398355adaf74b369768f5859866c299f229c99721990f8398
 DIST pkg-config-0.26.tar.gz 396399 RMD160 face3d16ec338b9b1ab41d56d6e4d1a5624b52d0 SHA1 fd71a70b023b9087c8a7bb76a0dc135a61059652 SHA256 94c1936a797c930fb3e4e5a154165b6268caba22b32d24083dd4c492a533c8af
 EBUILD glib-1.2.10-r5.ebuild 1777 RMD160 eaf01d9d6f1ba55edb93e46f46110b9e9c2fb778 SHA1 dbedf2bc146dcbec47ad308621bf1077c9f735cb SHA256 9d9dd1ea44c25087918148c2ba1203f3b38be09996bd7e48a26f9b4f93405d36
 EBUILD glib-2.28.8.ebuild 7500 RMD160 9ae98a76ac0470169c2c8470b33ab50599a782a9 SHA1 a3e32be6d7f05bf85494c08256de021f1a0f0d37 SHA256 838956e4b1a364e28424a40a129c0ceb8ed7c480889ff458edc8295d7c373878
@@ -34,12 +35,13 @@ EBUILD glib-2.30.2-r1.ebuild 8849 RMD160 8b5bfc01031158cffec83bdaa53fce01d8ebb7f
 EBUILD glib-2.30.2.ebuild 8733 RMD160 7a79c7845ff1cb49cff4fdb291e883988ac73a00 SHA1 1fbe14b56672d98da714ed8b639666e4ab071d77 SHA256 09d52abef697d6eaff86fb3546cf3f0a6385c72b76ce5a78a58338be59e17e5d
 EBUILD glib-2.30.3.ebuild 8959 RMD160 48324455fd5946c9cacf3fddafc15ed057e833a5 SHA1 24079baf54fc0a0576967e4bd6aeaad2989d7562 SHA256 45178cf30b9ead956922a0560528d769a9019dc4b2a234ecde763af1f587ecdd
 EBUILD glib-2.32.0.ebuild 8236 RMD160 2216818d00c62c799a082690cb37924e4c8de220 SHA1 28bd0bb125b44938c972133c0233ee51efc948ab SHA256 c2ad340dd6bf5d28a7158267ae5e5d68c31a2d7b024bc5745ce9ceb937469fd0
-MISC ChangeLog 68639 RMD160 f590b67d73eff1128ae98a12e94603cbb114b9c1 SHA1 43a3cc7e2a71826dfccc1c2bbb34f9182c350313 SHA256 e01744551d35785b0e461fb5d8264929f8001d2667fc86fbb299f1f42a604245
+EBUILD glib-2.32.1.ebuild 8236 RMD160 3a3ac13cbd68dee91d7309fb1d333999b729a599 SHA1 f95b277fa136604e7e7b17d05f4146a2402ddd93 SHA256 fc5567b1ec8ee3cbac721df4369fb5612ea2da0d7bfc33fabcf858302109cb04
+MISC ChangeLog 68784 RMD160 0cf564c6efd9642781140da5191b8313ccf499f7 SHA1 da60e975ccb126efeb1e152374b0d06088cacc9a SHA256 7835e1319faa2e41b424c128169e81cf98c04c704ede67486c82d39942a320c2
 MISC metadata.xml 497 RMD160 447ae0d07ac529dbe1830e383d2ef4eae7359ea7 SHA1 4cb36fafa32d53a0dbeec978b0d75f4e7acb3fa0 SHA256 a1840f7e6af57edc9fe5b54deae9e2083858d27792fda3f4e1e8e04624b17d0d
 -----BEGIN PGP SIGNATURE-----
-Version: GnuPG v2.0.18 (GNU/Linux)
+Version: GnuPG v2.0.19 (GNU/Linux)
 
-iF4EAREIAAYFAk9xMQkACgkQdjK8w9WeBnDNoAEArVC4cxlvQFU5Q/ke0QpW7tYl
-fxmEkzLGt/1oFi8Aun0A/jKxYr5W/4O4iHG4tBA8yOq95t4+PkdfzzsB8Hzb7eth
-=NOuV
+iF4EAREIAAYFAk+I72YACgkQdjK8w9WeBnANFgD/QWQex/H+1HapC/H8FajHc15J
+8ptYA2CAU/HS1oU5fukA/AiR3TURfwF07yRnqiZWgMYfp5LuKAGVHher4FscmksU
+=06zS
 -----END PGP SIGNATURE-----
diff --git a/dev-libs/glib/glib-2.32.1.ebuild b/dev-libs/glib/glib-2.32.1.ebuild
new file mode 100644
index 000000000000..cbf9b5252e33
--- /dev/null
+++ b/dev-libs/glib/glib-2.32.1.ebuild
@@ -0,0 +1,236 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/glib/glib-2.32.1.ebuild,v 1.1 2012/04/14 03:30:40 tetromino Exp $
+
+EAPI="4"
+PYTHON_DEPEND="utils? 2"
+# Avoid runtime dependency on python when USE=test
+
+inherit autotools gnome.org libtool eutils flag-o-matic gnome2-utils multilib pax-utils python virtualx
+
+DESCRIPTION="The GLib library of C routines"
+HOMEPAGE="http://www.gtk.org/"
+SRC_URI="${SRC_URI}
+	http://pkgconfig.freedesktop.org/releases/pkg-config-0.26.tar.gz" # pkg.m4 for eautoreconf
+
+LICENSE="LGPL-2"
+SLOT="2"
+IUSE="debug doc fam selinux static-libs systemtap test utils xattr"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~sparc-fbsd ~x86-fbsd ~x86-linux"
+
+RDEPEND="virtual/libiconv
+	virtual/libffi
+	sys-libs/zlib
+	xattr? ( sys-apps/attr )
+	fam? ( virtual/fam )
+	utils? ( >=dev-util/gdbus-codegen-${PV} )"
+DEPEND="${RDEPEND}
+	dev-libs/elfutils
+	>=sys-devel/gettext-0.11
+	>=dev-util/gtk-doc-am-1.15
+	doc? (
+		>=dev-libs/libxslt-1.0
+		>=dev-util/gdbus-codegen-${PV}
+		>=dev-util/gtk-doc-1.15
+		~app-text/docbook-xml-dtd-4.1.2 )
+	systemtap? ( >=dev-util/systemtap-1.3 )
+	test? (
+		sys-devel/gdb
+		=dev-lang/python-2*
+		>=dev-util/gdbus-codegen-${PV}
+		>=sys-apps/dbus-1.2.14 )
+	!<dev-util/gtk-doc-1.15-r2"
+PDEPEND="x11-misc/shared-mime-info
+	!<gnome-base/gvfs-1.6.4-r990"
+# shared-mime-info needed for gio/xdgmime, bug #409481
+# Earlier versions of gvfs do not work with glib
+
+pkg_setup() {
+	# Needed for gio/tests/gdbus-testserver.py
+	if use test ; then
+		python_set_active_version 2
+		python_pkg_setup
+	fi
+}
+
+src_prepare() {
+	mv -vf "${WORKDIR}"/pkg-config-*/pkg.m4 "${WORKDIR}"/ || die
+
+	if use ia64 ; then
+		# Only apply for < 4.1
+		local major=$(gcc-major-version)
+		local minor=$(gcc-minor-version)
+		if (( major < 4 || ( major == 4 && minor == 0 ) )); then
+			epatch "${FILESDIR}/glib-2.10.3-ia64-atomic-ops.patch"
+		fi
+	fi
+
+	# Don't fail gio tests when ran without userpriv, upstream bug 552912
+	# This is only a temporary workaround, remove as soon as possible
+#	epatch "${FILESDIR}/${PN}-2.18.1-workaround-gio-test-failure-without-userpriv.patch"
+
+	# Fix gmodule issues on fbsd; bug #184301
+	epatch "${FILESDIR}"/${PN}-2.12.12-fbsd.patch
+
+	# Do not try to remove files on live filesystem, upstream bug #619274
+	sed 's:^\(.*"/desktop-app-info/delete".*\):/*\1*/:' \
+		-i "${S}"/gio/tests/desktop-app-info.c || die "sed failed"
+
+	# need to build tests if USE=doc for bug #387385
+	if ! use test && ! use doc; then
+		# don't waste time building tests
+		sed 's/^\(.*\SUBDIRS .*\=.*\)tests\(.*\)$/\1\2/' -i $(find . -name Makefile.am -o -name Makefile.in) || die
+	else
+		# Disable tests requiring dev-util/desktop-file-utils when not installed, bug #286629
+		if ! has_version dev-util/desktop-file-utils ; then
+			ewarn "Some tests will be skipped due dev-util/desktop-file-utils not being present on your system,"
+			ewarn "think on installing it to get these tests run."
+			sed -i -e "/appinfo\/associations/d" gio/tests/appinfo.c || die
+			sed -i -e "/desktop-app-info\/default/d" gio/tests/desktop-app-info.c || die
+			sed -i -e "/desktop-app-info\/fallback/d" gio/tests/desktop-app-info.c || die
+			sed -i -e "/desktop-app-info\/lastused/d" gio/tests/desktop-app-info.c || die
+		fi
+
+		# Disable tests requiring dbus-python and pygobject; bugs #349236, #377549, #384853
+		if ! has_version dev-python/dbus-python || ! has_version 'dev-python/pygobject:2' ; then
+			ewarn "Some tests will be skipped due to dev-python/dbus-python or dev-python/pygobject:2"
+			ewarn "not being present on your system, think on installing them to get these tests run."
+			sed -i -e "/connection\/filter/d" gio/tests/gdbus-connection.c || die
+			sed -i -e "/connection\/large_message/d" gio/tests/gdbus-connection-slow.c || die
+			sed -i -e "/gdbus\/proxy/d" gio/tests/gdbus-proxy.c || die
+			sed -i -e "/gdbus\/proxy-well-known-name/d" gio/tests/gdbus-proxy-well-known-name.c || die
+			sed -i -e "/gdbus\/introspection-parser/d" gio/tests/gdbus-introspection.c || die
+			sed -i -e "/g_test_add_func/d" gio/tests/gdbus-threading.c || die
+			sed -i -e "/gdbus\/method-calls-in-thread/d" gio/tests/gdbus-threading.c || die
+			# needed to prevent gdbus-threading from asserting
+			ln -sfn $(type -P true) gio/tests/gdbus-testserver.py
+		fi
+	fi
+
+	# gdbus-codegen is a separate package
+	epatch "${FILESDIR}/${PN}-2.31.x-external-gdbus-codegen.patch"
+
+	# disable pyc compiling
+	use test && python_clean_py-compile_files
+
+	# Needed for the punt-python-check patch, disabling timeout test
+	# Also needed to prevent croscompile failures, see bug #267603
+	# Also needed for the no-gdbus-codegen patch
+	AT_M4DIR="${WORKDIR}" eautoreconf
+
+	[[ ${CHOST} == *-freebsd* ]] && elibtoolize
+
+	epunt_cxx
+}
+
+src_configure() {
+	# Avoid circular depend with dev-util/pkgconfig
+	if ! has_version dev-util/pkgconfig; then
+		if has_version sys-apps/dbus; then
+			export DBUS1_CFLAGS="-I/usr/include/dbus-1.0 -I/usr/$(get_libdir)/dbus-1.0/include"
+			export DBUS1_LIBS="-ldbus-1"
+		fi
+		export LIBFFI_CFLAGS="-I$(echo /usr/$(get_libdir)/libffi-*/include)"
+		export LIBFFI_LIBS="-lffi"
+	fi
+
+	local myconf
+
+	# Building with --disable-debug highly unrecommended.  It will build glib in
+	# an unusable form as it disables some commonly used API.  Please do not
+	# convert this to the use_enable form, as it results in a broken build.
+	# -- compnerd (3/27/06)
+	use debug && myconf="--enable-debug"
+
+	# Always use internal libpcre, bug #254659
+	econf ${myconf} \
+		$(use_enable xattr) \
+		$(use_enable doc man) \
+		$(use_enable doc gtk-doc) \
+		$(use_enable fam) \
+		$(use_enable selinux) \
+		$(use_enable static-libs static) \
+		$(use_enable systemtap dtrace) \
+		$(use_enable systemtap systemtap) \
+		--with-pcre=internal \
+		--with-threads=posix
+}
+
+src_install() {
+	local f
+
+	# install-exec-hook substitutes ${PYTHON} in glib/gtester-report
+	emake DESTDIR="${D}" PYTHON="${EPREFIX}/usr/bin/python2" install
+
+	if ! use utils; then
+		rm "${ED}usr/bin/gtester-report"
+	fi
+
+	# Do not install charset.alias even if generated, leave it to libiconv
+	rm -f "${ED}/usr/lib/charset.alias"
+
+	# Don't install gdb python macros, bug 291328
+	rm -rf "${ED}/usr/share/gdb/" "${ED}/usr/share/glib-2.0/gdb/"
+
+	dodoc AUTHORS ChangeLog* NEWS* README
+
+	insinto /usr/share/bash-completion
+	for f in gdbus gsettings; do
+		newins "${ED}/etc/bash_completion.d/${f}-bash-completion.sh" ${f}
+	done
+	rm -rf "${ED}/etc"
+
+	# Completely useless with or without USE static-libs, people need to use
+	# pkg-config
+	find "${D}" -name '*.la' -exec rm -f {} +
+}
+
+src_test() {
+	gnome2_environment_reset
+
+	unset DBUS_SESSION_BUS_ADDRESS
+	export XDG_CONFIG_DIRS=/etc/xdg
+	export XDG_DATA_DIRS=/usr/local/share:/usr/share
+	export G_DBUS_COOKIE_SHA1_KEYRING_DIR="${T}/temp"
+	unset GSETTINGS_BACKEND # bug 352451
+
+	# Related test is a bit nitpicking
+	mkdir "$G_DBUS_COOKIE_SHA1_KEYRING_DIR"
+	chmod 0700 "$G_DBUS_COOKIE_SHA1_KEYRING_DIR"
+
+	# Hardened: gdb needs this, bug #338891
+	if host-is-pax ; then
+		pax-mark -mr "${S}"/tests/.libs/assert-msg-test \
+			|| die "Hardened adjustment failed"
+	fi
+
+	# Need X for dbus-launch session X11 initialization
+	Xemake check
+}
+
+pkg_preinst() {
+	# Only give the introspection message if:
+	# * The user has gobject-introspection
+	# * Has glib already installed
+	# * Previous version was different from new version
+	if has_version "dev-libs/gobject-introspection" && ! has_version "=${CATEGORY}/${PF}"; then
+		ewarn "You must rebuild gobject-introspection so that the installed"
+		ewarn "typelibs and girs are regenerated for the new APIs in glib"
+	fi
+}
+
+pkg_postinst() {
+	# Inform users about possible breakage when updating glib and not dbus-glib, bug #297483
+	if has_version dev-libs/dbus-glib; then
+		ewarn "If you experience a breakage after updating dev-libs/glib try"
+		ewarn "rebuilding dev-libs/dbus-glib"
+	fi
+
+	if has_version '<x11-libs/gtk+-3.0.12:3'; then
+		# To have a clear upgrade path for gtk+-3.0.x users, have to resort to
+		# a warning instead of a blocker
+		ewarn
+		ewarn "Using <gtk+-3.0.12:3 with ${P} results in frequent crashes."
+		ewarn "You should upgrade to a newer version of gtk+:3 immediately."
+	fi
+}