Update to EAPI=2 and USE deps.

Package-Manager: portage-2.2_rc11/cvs/Linux 2.6.26-gentoo-r1 x86_64

12 files changed, 429 insertions, 6 deletions

diff --git a/media-sound/padevchooser/ChangeLog b/media-sound/padevchooser/ChangeLog
index ae20b8b7268e..9650118371ea 100644
--- a/media-sound/padevchooser/ChangeLog
+++ b/media-sound/padevchooser/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-sound/padevchooser
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/padevchooser/ChangeLog,v 1.12 2008/08/02 20:28:57 betelgeuse Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/padevchooser/ChangeLog,v 1.13 2008/10/09 21:36:43 flameeyes Exp $
+
+*padevchooser-0.9.3-r1 (09 Oct 2008)
+
+  09 Oct 2008; Diego Pettenò <flameeyes@gentoo.org>
+  +padevchooser-0.9.3-r1.ebuild:
+  Update to EAPI=2 and USE deps.
 
   02 Aug 2008; Petteri Räty <betelgeuse@gentoo.org>
   padevchooser-0.9.3.ebuild:
diff --git a/media-sound/padevchooser/padevchooser-0.9.3-r1.ebuild b/media-sound/padevchooser/padevchooser-0.9.3-r1.ebuild
new file mode 100644
index 000000000000..b5808ce226bb
--- /dev/null
+++ b/media-sound/padevchooser/padevchooser-0.9.3-r1.ebuild
@@ -0,0 +1,38 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/padevchooser/padevchooser-0.9.3-r1.ebuild,v 1.1 2008/10/09 21:36:43 flameeyes Exp $
+
+EAPI=2
+
+inherit eutils
+
+DESCRIPTION="PulseAudio Device Chooser, tool for quick access to PulseAudio features"
+HOMEPAGE="http://0pointer.de/lennart/projects/padevchooser/"
+SRC_URI="http://0pointer.de/lennart/projects/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~sparc ~x86"
+
+IUSE=""
+
+DEPEND=">=x11-libs/gtk+-2.0
+	>=gnome-base/libglade-2.0
+	>=gnome-base/gconf-2.0
+	x11-libs/libnotify
+	>=media-sound/pulseaudio-0.9.2[avahi,glib]"
+RDEPEND="${DEPEND}
+	x11-themes/gnome-icon-theme"
+
+src_configure() {
+	# Lynx is used during make dist basically
+	econf \
+		--disable-dependency-tracking \
+		--disable-lynx || die "econf failed"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "make install failed"
+	dohtml -r doc
+	dodoc README doc/todo
+}
diff --git a/media-sound/paman/ChangeLog b/media-sound/paman/ChangeLog
index 0e4beb25c8f4..b1b0485274c1 100644
--- a/media-sound/paman/ChangeLog
+++ b/media-sound/paman/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-sound/paman
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/paman/ChangeLog,v 1.13 2008/02/11 04:01:39 tester Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/paman/ChangeLog,v 1.14 2008/10/09 21:39:25 flameeyes Exp $
+
+*paman-0.9.4-r1 (09 Oct 2008)
+
+  09 Oct 2008; Diego Pettenò <flameeyes@gentoo.org> +paman-0.9.4-r1.ebuild:
+  Update to EAPI=2 and USE deps.
 
   11 Feb 2008; Olivier Crête <tester@gentoo.org> paman-0.9.4.ebuild:
   Stable on amd64, bug #204219
diff --git a/media-sound/paman/paman-0.9.4-r1.ebuild b/media-sound/paman/paman-0.9.4-r1.ebuild
new file mode 100644
index 000000000000..53922423526c
--- /dev/null
+++ b/media-sound/paman/paman-0.9.4-r1.ebuild
@@ -0,0 +1,37 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/paman/paman-0.9.4-r1.ebuild,v 1.1 2008/10/09 21:39:25 flameeyes Exp $
+
+EAPI=2
+
+inherit eutils
+
+DESCRIPTION="Pulseaudio Manager, a simple GTK frontend for Pulseaudio"
+HOMEPAGE="http://0pointer.de/lennart/projects/paman/"
+SRC_URI="http://0pointer.de/lennart/projects/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~sparc ~x86 ~x86-fbsd"
+
+IUSE=""
+
+DEPEND=">=dev-cpp/gtkmm-2.4
+	>=dev-cpp/libglademm-2.4
+	>=media-sound/pulseaudio-0.9.5[glib]"
+RDEPEND="${DEPEND}
+	x11-themes/gnome-icon-theme"
+DEPEND="${DEPEND}
+	dev-util/pkgconfig"
+
+src_configure() {
+	# Lynx is used during make dist basically
+	econf \
+		--disable-lynx || die "econf failed"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "make install failed"
+	dohtml -r doc
+	dodoc README
+}
diff --git a/media-sound/paprefs/ChangeLog b/media-sound/paprefs/ChangeLog
index 8dfd95aeb020..c81623aeb0a3 100644
--- a/media-sound/paprefs/ChangeLog
+++ b/media-sound/paprefs/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-sound/paprefs
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/paprefs/ChangeLog,v 1.14 2008/05/03 13:24:55 drac Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/paprefs/ChangeLog,v 1.15 2008/10/09 21:41:25 flameeyes Exp $
+
+*paprefs-0.9.6-r1 (09 Oct 2008)
+
+  09 Oct 2008; Diego Pettenò <flameeyes@gentoo.org>
+  +paprefs-0.9.6-r1.ebuild:
+  Update to EAPI=2 and USE deps.
 
   03 May 2008; Samuli Suominen <drac@gentoo.org>
   +files/paprefs-0.9.6-gcc43.patch, paprefs-0.9.6.ebuild:
diff --git a/media-sound/paprefs/paprefs-0.9.6-r1.ebuild b/media-sound/paprefs/paprefs-0.9.6-r1.ebuild
new file mode 100644
index 000000000000..9c70b6b49b5a
--- /dev/null
+++ b/media-sound/paprefs/paprefs-0.9.6-r1.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/paprefs/paprefs-0.9.6-r1.ebuild,v 1.1 2008/10/09 21:41:25 flameeyes Exp $
+
+EAPI=2
+
+inherit eutils
+
+DESCRIPTION="PulseAudio Preferences, configuration dialog for PulseAudio"
+HOMEPAGE="http://0pointer.de/lennart/projects/paprefs"
+SRC_URI="http://0pointer.de/lennart/projects/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~sparc ~x86"
+IUSE="nls"
+
+RDEPEND=">=dev-cpp/gtkmm-2.4
+	>=dev-cpp/libglademm-2.4
+	>=dev-cpp/gconfmm-2.6
+	>=dev-libs/libsigc++-2
+	>=media-sound/pulseaudio-0.9.5[glib]
+	x11-themes/gnome-icon-theme"
+DEPEND="${RDEPEND}
+	nls? ( sys-devel/gettext dev-util/intltool )
+	dev-util/pkgconfig"
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+	epatch "${FILESDIR}"/${P}-gcc43.patch
+}
+
+src_configure() {
+	econf $(use_enable nls) --disable-lynx
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install failed."
+	dohtml -r doc
+	dodoc README
+}
diff --git a/media-sound/pavucontrol/ChangeLog b/media-sound/pavucontrol/ChangeLog
index 31345c0bc05a..7e21740dbfc7 100644
--- a/media-sound/pavucontrol/ChangeLog
+++ b/media-sound/pavucontrol/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-sound/pavucontrol
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/pavucontrol/ChangeLog,v 1.16 2008/04/18 04:53:34 flameeyes Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/pavucontrol/ChangeLog,v 1.17 2008/10/09 21:42:28 flameeyes Exp $
+
+*pavucontrol-0.9.6-r1 (09 Oct 2008)
+
+  09 Oct 2008; Diego Pettenò <flameeyes@gentoo.org>
+  +pavucontrol-0.9.6-r1.ebuild:
+  Update to EAPI=2 and USE deps.
 
 *pavucontrol-0.9.6 (18 Apr 2008)
 
diff --git a/media-sound/pavucontrol/pavucontrol-0.9.6-r1.ebuild b/media-sound/pavucontrol/pavucontrol-0.9.6-r1.ebuild
new file mode 100644
index 000000000000..b531ffe29812
--- /dev/null
+++ b/media-sound/pavucontrol/pavucontrol-0.9.6-r1.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/pavucontrol/pavucontrol-0.9.6-r1.ebuild,v 1.1 2008/10/09 21:42:28 flameeyes Exp $
+
+EAPI=2
+
+inherit eutils
+
+DESCRIPTION="Pulseaudio Volume Control, GTK based mixer for Pulseaudio"
+HOMEPAGE="http://0pointer.de/lennart/projects/pavucontrol/"
+SRC_URI="http://0pointer.de/lennart/projects/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~sparc ~x86 ~x86-fbsd"
+
+IUSE=""
+
+DEPEND=">=dev-cpp/gtkmm-2.4
+	>=dev-cpp/libglademm-2.4
+	>=dev-libs/libsigc++-2.0
+	>=media-sound/pulseaudio-0.9.7[glib]"
+
+RDEPEND="${DEPEND}
+	x11-themes/gnome-icon-theme"
+
+DEPEND="${DEPEND}
+	dev-util/pkgconfig"
+
+src_configure() {
+	# Lynx is used during make dist basically
+	econf \
+		--disable-dependency-tracking \
+		--disable-lynx || die "econf failed"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "make install failed"
+	dohtml -r doc
+	dodoc README
+}
diff --git a/media-sound/pavumeter/ChangeLog b/media-sound/pavumeter/ChangeLog
index 9370c7c54d97..6425e9687ac5 100644
--- a/media-sound/pavumeter/ChangeLog
+++ b/media-sound/pavumeter/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-sound/pavumeter
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/pavumeter/ChangeLog,v 1.11 2008/02/11 04:03:15 tester Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/pavumeter/ChangeLog,v 1.12 2008/10/09 21:44:11 flameeyes Exp $
+
+*pavumeter-0.9.3-r1 (09 Oct 2008)
+
+  09 Oct 2008; Diego Pettenò <flameeyes@gentoo.org>
+  +pavumeter-0.9.3-r1.ebuild:
+  Update to EAPI=2 and USE deps.
 
   11 Feb 2008; Olivier Crête <tester@gentoo.org> pavumeter-0.9.3.ebuild:
   Stable on amd64, bug #204219
diff --git a/media-sound/pavumeter/pavumeter-0.9.3-r1.ebuild b/media-sound/pavumeter/pavumeter-0.9.3-r1.ebuild
new file mode 100644
index 000000000000..4627a549be80
--- /dev/null
+++ b/media-sound/pavumeter/pavumeter-0.9.3-r1.ebuild
@@ -0,0 +1,38 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/pavumeter/pavumeter-0.9.3-r1.ebuild,v 1.1 2008/10/09 21:44:11 flameeyes Exp $
+
+EAPI=2
+
+inherit eutils
+
+DESCRIPTION="PulseAudio Volume Meter, simple GTK volume meter for PulseAudio"
+HOMEPAGE="http://0pointer.de/lennart/projects/pavumeter/"
+SRC_URI="http://0pointer.de/lennart/projects/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~sparc ~x86"
+
+IUSE=""
+
+DEPEND=">=dev-cpp/gtkmm-2.4
+	>=dev-libs/libsigc++-2.0
+	>=media-sound/pulseaudio-0.9.7[glib]"
+RDEPEND="${DEPEND}
+	x11-themes/gnome-icon-theme"
+DEPEND="${DEPEND}
+	dev-util/pkgconfig"
+
+src_configure() {
+	# Lynx is used during make dist basically
+	econf \
+		--disable-dependency-tracking \
+		--disable-lynx || die "econf failed"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "make install failed"
+	dohtml -r doc
+	dodoc README
+}
diff --git a/media-sound/pulseaudio/ChangeLog b/media-sound/pulseaudio/ChangeLog
index 54eae6d53f40..2ee06dbcb236 100644
--- a/media-sound/pulseaudio/ChangeLog
+++ b/media-sound/pulseaudio/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-sound/pulseaudio
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/pulseaudio/ChangeLog,v 1.111 2008/09/28 10:15:17 aballier Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/pulseaudio/ChangeLog,v 1.112 2008/10/09 21:38:02 flameeyes Exp $
+
+*pulseaudio-0.9.12-r1 (09 Oct 2008)
+
+  09 Oct 2008; Diego Pettenò <flameeyes@gentoo.org>
+  +pulseaudio-0.9.12-r1.ebuild:
+  Update to EAPI=2 and USE deps.
 
   28 Sep 2008; Alexis Ballier <aballier@gentoo.org>
   pulseaudio-0.9.12.ebuild:
diff --git a/media-sound/pulseaudio/pulseaudio-0.9.12-r1.ebuild b/media-sound/pulseaudio/pulseaudio-0.9.12-r1.ebuild
new file mode 100644
index 000000000000..766a5c803552
--- /dev/null
+++ b/media-sound/pulseaudio/pulseaudio-0.9.12-r1.ebuild
@@ -0,0 +1,192 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/pulseaudio/pulseaudio-0.9.12-r1.ebuild,v 1.1 2008/10/09 21:38:02 flameeyes Exp $
+
+EAPI=2
+
+inherit eutils libtool autotools flag-o-matic
+
+DESCRIPTION="A networked sound server with an advanced plugin system"
+HOMEPAGE="http://0pointer.de/lennart/projects/pulseaudio/"
+SRC_URI="http://0pointer.de/lennart/projects/${PN}/${P}.tar.gz"
+
+LICENSE="LGPL-2 GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc64 ~sparc ~x86"
+IUSE="alsa avahi caps jack lirc oss tcpd X hal dbus libsamplerate gnome bluetooth policykit asyncns +glib"
+
+RDEPEND="X? ( x11-libs/libX11 x11-libs/libSM x11-libs/libXau x11-libs/libXdmcp )
+	caps? ( sys-libs/libcap )
+	libsamplerate? ( >=media-libs/libsamplerate-0.1.1-r1 )
+	alsa? ( >=media-libs/alsa-lib-1.0.17-r1 )
+	glib? ( >=dev-libs/glib-2.4.0 )
+	avahi? ( >=net-dns/avahi-0.6.12[dbus] )
+	>=dev-libs/liboil-0.3.0
+	jack? ( >=media-sound/jack-audio-connection-kit-0.100 )
+	tcpd? ( sys-apps/tcp-wrappers )
+	lirc? ( app-misc/lirc )
+	dbus? ( >=sys-apps/dbus-1.0.0 )
+	gnome? ( >=gnome-base/gconf-2.4.0 )
+	hal? (
+		>=sys-apps/hal-0.5.7
+		>=sys-apps/dbus-1.0.0
+	)
+	app-admin/eselect-esd
+	bluetooth? (
+		>=net-wireless/bluez-libs-3
+		>=sys-apps/dbus-1.0.0
+	)
+	policykit? ( sys-auth/policykit )
+	asyncns? ( net-libs/libasyncns )
+	>=media-libs/audiofile-0.2.6-r1
+	>=media-libs/speex-1.2_beta
+	>=media-libs/libsndfile-1.0.10
+	>=dev-libs/liboil-0.3.6
+	sys-libs/gdbm
+	|| ( sys-apps/openrc >=sys-apps/baselayout-2.0_rc5 )
+	>=sys-devel/libtool-1.5.24" # it's a valid RDEPEND, libltdl.so is used
+DEPEND="${RDEPEND}
+	X? ( x11-proto/xproto )
+	dev-libs/libatomic_ops
+	dev-util/pkgconfig
+	|| ( dev-util/unifdef sys-freebsd/freebsd-ubin )"
+
+# alsa-utils dep is for the alsasound init.d script (see bug #155707)
+# bluez-utils dep is for the bluetooth init.d script
+RDEPEND="${RDEPEND}
+	gnome-extra/gnome-audio
+	alsa? ( media-sound/alsa-utils )
+	bluetooth? ( >=net-wireless/bluez-utils-3 )"
+
+pkg_setup() {
+	enewgroup audio 18 # Just make sure it exists
+	enewgroup realtime
+	enewgroup pulse-access
+	enewgroup pulse
+	enewuser pulse -1 -1 /var/run/pulse pulse,audio
+}
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+
+	# Avoid building - and especially linking - test programs
+	# outside of make check
+	sed -i -e 's:noinst_PROGRAMS:check_PROGRAMS:' \
+		"${S}/src/Makefile.am"
+
+	eautoreconf
+	elibtoolize
+}
+
+src_configure() {
+	# To properly fix CVE-2008-0008
+	append-flags -UNDEBUG
+
+	econf \
+		--enable-largefile \
+		$(use_enable glib) \
+		--disable-solaris \
+		$(use_enable asyncns) \
+		$(use_enable oss) \
+		$(use_enable alsa) \
+		$(use_enable lirc) \
+		$(use_enable tcpd tcpwrap) \
+		$(use_enable jack) \
+		$(use_enable lirc) \
+		$(use_enable avahi) \
+		$(use_enable hal) \
+		$(use_enable dbus) \
+		$(use_enable gnome gconf) \
+		$(use_enable libsamplerate samplerate) \
+		$(use_enable bluetooth bluez) \
+		$(use_enable policykit polkit) \
+		$(use_with caps) \
+		$(use_with X x) \
+		--disable-ltdl-install \
+		--localstatedir=/var \
+		--with-realtime-group=realtime \
+		--disable-per-user-esound-socket \
+		|| die "econf failed"
+}
+
+src_install() {
+	emake -j1 DESTDIR="${D}" install || die "make install failed"
+
+	newconfd "${FILESDIR}/pulseaudio.conf.d" pulseaudio
+
+	use_define() {
+		local define=${2:-$(echo $1 | tr '[:lower:]' '[:upper:]')}
+
+		use "$1" && echo "-D$define" || echo "-U$define"
+	}
+
+	unifdef $(use_define hal) \
+		$(use_define avahi) \
+		$(use_define alsa) \
+		$(use_define bluetooth) \
+		"${FILESDIR}/pulseaudio.init.d-4" \
+		> "${T}/pulseaudio"
+	doinitd "${T}/pulseaudio"
+
+	use avahi && sed -i -e '/module-zeroconf-publish/s:^#::' "${D}/etc/pulse/default.pa"
+
+	dohtml -r doc
+	dodoc README
+
+	# this should fix system daemon startup #233789
+	cp "${D}/etc/pulse/default.pa" "${D}/etc/pulse/system.pa"
+
+	# Create the state directory
+	diropts -o pulse -g pulse -m0755
+	keepdir /var/run/pulse
+
+	find "${D}" -name '*.la' -delete
+}
+
+pkg_postinst() {
+	elog "PulseAudio in Gentoo can use a system-wide pulseaudio daemon."
+	elog "This support is enabled by starting the pulseaudio init.d ."
+	elog "To be able to access that you need to be in the group pulse-access."
+	elog "For more information about system-wide support, please refer to"
+	elog "	 http://pulseaudio.org/wiki/SystemWideInstance"
+	if use gnome; then
+		elog
+		elog "By enabling gnome USE flag, you enabled gconf support. Pleaes note"
+		elog "that you might need to remove the gnome USE flag or disable the"
+		elog "gconf module on /etc/pulse/default.pa to be able to use PulseAudio"
+		elog "with a system-wide instance."
+	fi
+	elog
+	elog "To use the ESounD wrapper while using a system-wide daemon, you also"
+	elog "need to enable auth-anonymous for the esound-unix module, or to copy"
+	elog "/var/run/pulse/.esd_auth into each home directory."
+	elog
+	elog "If you want to make use of realtime capabilities of PulseAudio"
+	elog "you should follow the realtime guide to create and set up a realtime"
+	elog "user group: http://www.gentoo.org/proj/en/desktop/sound/realtime.xml"
+	elog "Make sure you also have baselayout installed with pam USE flag"
+	elog "enabled, if you're using the rlimit method."
+	if use bluetooth; then
+		elog
+		elog "The BlueTooth proximity module is not enabled in the default"
+		elog "configuration file. If you do enable it, you'll have to have"
+		elog "your BlueTooth controller enabled and inserted at bootup or"
+		elog "PulseAudio will refuse to start."
+		elog
+		elog "Please note that the BlueTooth proximity module seems itself"
+		elog "still experimental, so please report to upstream if you have"
+		elog "problems with it."
+	fi
+	if use alsa; then
+		local pkg="media-plugins/alsa-plugins"
+		if has_version ${pkg} && ! built_with_use --missing false ${pkg} pulseaudio; then
+			elog
+			elog "You have alsa support enabled so you probably want to install"
+			elog "${pkg} with pulseaudio support to have"
+			elog "alsa using applications route their sound through pulseaudio"
+		fi
+	fi
+
+	eselect esd update --if-unset
+}