Version bump

Package-Manager: portage-2.2_rc23/cvs/Linux x86_64

1 files changed, 50 insertions, 0 deletions

diff --git a/dev-cpp/muParser/muParser-1.30.ebuild b/dev-cpp/muParser/muParser-1.30.ebuild
new file mode 100644
index 000000000000..a58738307dce
--- /dev/null
+++ b/dev-cpp/muParser/muParser-1.30.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-cpp/muParser/muParser-1.30.ebuild,v 1.1 2009/03/09 16:21:14 bicatali Exp $
+
+EAPI=2
+inherit eutils
+
+DESCRIPTION="Library for parsing mathematical expressions"
+HOMEPAGE="http://muparser.sourceforge.net/"
+SLOT="0"
+LICENSE="MIT"
+KEYWORDS="~amd64 ~ppc64 ~x86"
+IUSE="doc"
+MY_PN="${PN/P/p}"
+MY_PV="v${PV/./}"
+SRC_URI="mirror://sourceforge/${MY_PN}/${MY_PN}_${MY_PV}.tar.gz"
+
+RDEPEND=""
+DEPEND="${RDEPEND}"
+
+S="${WORKDIR}/${MY_PN}"
+
+src_prepare() {
+	# fix destdir and respect cxxflags
+	# cant really use autotools cause muparser use bakefile
+	# and too lasy to make an ebuild for it.
+	epatch "${FILESDIR}"/${P}-build.patch
+}
+
+src_configure() {
+	econf --disable-samples
+}
+
+src_test() {
+	econf --enable-samples
+	emake || die "emake failed"
+	echo "LD_LIBRARY_PATH=${PWD}/lib samples/example1/example1 << EOF" > test.sh
+	echo "quit" >> test.sh
+	echo "EOF" >> test.sh
+	sh ./test.sh || die "test failed"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install failed"
+	dodoc Changes.txt  Credits.txt || die "dodoc failed"
+	if use doc; then
+		insinto /usr/share/doc/${PF}
+		doins -r docs/html || die
+	fi
+}