Version bump #112267 by Ludek Stepan.

Package-Manager: portage-2.0.53_rc7

1 files changed, 60 insertions, 0 deletions

diff --git a/dev-embedded/avr-libc/avr-libc-1.2.6.ebuild b/dev-embedded/avr-libc/avr-libc-1.2.6.ebuild
new file mode 100644
index 000000000000..2ec190db709f
--- /dev/null
+++ b/dev-embedded/avr-libc/avr-libc-1.2.6.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2005 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-embedded/avr-libc/avr-libc-1.2.6.ebuild,v 1.1 2005/11/13 04:08:12 vapier Exp $
+
+inherit eutils flag-o-matic
+
+DESCRIPTION="Libc for the AVR microcontroller architecture"
+HOMEPAGE="http://www.nongnu.org/avr-libc/"
+SRC_URI="http://savannah.nongnu.org/download/avr-libc/${P}.tar.bz2
+		http://savannah.nongnu.org/download/avr-libc/${PN}-manpages-${PV}.tar.bz2
+		doc? ( http://savannah.nongnu.org/download/avr-libc/${PN}-user-manual-${PV}.tar.bz2 )"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+
+IUSE="doc nls"
+DEPEND=">=sys-devel/crossdev-0.9.1"
+[[ ${CATEGORY/cross-} != ${CATEGORY} ]] \
+	&& RDEPEND="!dev-embedded/avr-libc" \
+	|| RDEPEND=""
+
+src_unpack() {
+	unpack ${A}
+
+	cd "${S}"
+	epatch "${FILESDIR}"/${PN}-macros.patch
+}
+
+src_compile() {
+	export AS=avr-as AR=avr-ar RANLIB=avr-ranlib CC=avr-gcc ABI=retarded
+
+	strip-flags
+	strip-unsupported-flags
+
+	mkdir obj-avr
+	cd "${S}"/obj-avr
+
+	ECONF_SOURCE="${S}" CHOST="avr" CTARGET="avr" econf \
+		$(use_enable nls) \
+		|| die "econf failed"
+
+	emake || die "emake failed"
+}
+
+src_install() {
+	dodoc AUTHORS ChangeLog* NEWS README
+
+	cd "${S}"/obj-avr
+	make DESTDIR="${D}" install || die "make install failed"
+
+	# man pages can not go into standard locations
+	# as they would then overwrite libc man pages
+	dosed "s:\$(VERSION):${PVR}:" /usr/bin/avr-man
+	insinto /usr/share/doc/${PF}/man/man3
+	doins "${WORKDIR}"/man3/*
+	prepman /usr/share/doc/${PF}
+
+	use doc	&& dohtml "${WORKDIR}"/${PN}-user-manual-${PV}/*
+}