Revision bumps to support new Java system.

Package-Manager: portage-2.1.1_pre2-r4

1 files changed, 54 insertions, 0 deletions

diff --git a/dev-java/commons-betwixt/commons-betwixt-0.6-r2.ebuild b/dev-java/commons-betwixt/commons-betwixt-0.6-r2.ebuild
new file mode 100644
index 000000000000..677231b3b134
--- /dev/null
+++ b/dev-java/commons-betwixt/commons-betwixt-0.6-r2.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2006 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-java/commons-betwixt/commons-betwixt-0.6-r2.ebuild,v 1.1 2006/07/13 21:59:14 nichoj Exp $
+
+inherit java-pkg-2 eutils java-ant-2
+
+DESCRIPTION="Introspective Bean to XML mapper"
+HOMEPAGE="http://jakarta.apache.org/commons/betwixt/"
+SRC_URI="mirror://apache/jakarta/commons/betwixt/source/${P}-src.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~ppc"
+IUSE="doc source"
+
+COMMON_DEP="
+	>=dev-java/commons-logging-1.0.2
+	=dev-java/commons-beanutils-1.7*
+	>=dev-java/commons-digester-1.6"
+RDEPEND=">=virtual/jre-1.3
+	${COMMON_DEP}"
+DEPEND=">=virtual/jdk-1.3
+	${COMMON_DEP}
+	dev-java/ant-core
+	source? ( app-arch/zip )"
+
+S="${WORKDIR}/${P}-src/"
+
+ant_src_unpack() {
+	unpack ${A}
+
+	cd ${S}
+	epatch ${FILESDIR}/${P}-noget.patch
+
+	mkdir -p ${S}/target/lib && cd ${S}/target/lib
+	java-pkg_jar-from commons-beanutils-1.7
+	java-pkg_jar-from commons-digester
+	java-pkg_jar-from commons-logging
+}
+
+src_compile() {
+	eant init jar $(use_doc)
+}
+
+src_install() {
+	java-pkg_newjar target/${PN}*.jar ${PN}.jar
+
+	dodoc RELEASE-NOTES.txt
+	if use doc; then
+		java-pkg_dohtml PROPOSAL.html STATUS.html userguide.html
+		java-pkg_dohtml -r dist/docs/
+	fi
+	use source && java-pkg_dosrc src/java/*
+}