dev-libs/boehm-gc: Version Bump, handling of static libs

Package-Manager: portage-2.2.0_alpha108/cvs/Linux x86_64

4 files changed, 92 insertions, 17 deletions

diff --git a/dev-libs/boehm-gc/ChangeLog b/dev-libs/boehm-gc/ChangeLog
index e54e7ca267c9..b833d7858a73 100644
--- a/dev-libs/boehm-gc/ChangeLog
+++ b/dev-libs/boehm-gc/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-libs/boehm-gc
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/boehm-gc/ChangeLog,v 1.79 2012/01/10 19:18:00 flameeyes Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/boehm-gc/ChangeLog,v 1.80 2012/05/29 19:17:13 jlec Exp $
+
+*boehm-gc-7.2_alpha6 (29 May 2012)
+
+  29 May 2012; Justin Lecher <jlec@gentoo.org> boehm-gc-7.2_alpha4-r1.ebuild,
+  +boehm-gc-7.2_alpha6.ebuild, metadata.xml:
+  Version Bump, handling of static libs
 
   13 Nov 2011; Mike Frysinger <vapier@gentoo.org> boehm-gc-6.8.ebuild,
   boehm-gc-7.0-r1.ebuild, boehm-gc-7.1-r1.ebuild,
diff --git a/dev-libs/boehm-gc/boehm-gc-7.2_alpha4-r1.ebuild b/dev-libs/boehm-gc/boehm-gc-7.2_alpha4-r1.ebuild
index fc750ab25f57..6828c6711dff 100644
--- a/dev-libs/boehm-gc/boehm-gc-7.2_alpha4-r1.ebuild
+++ b/dev-libs/boehm-gc/boehm-gc-7.2_alpha4-r1.ebuild
@@ -1,11 +1,12 @@
-# Copyright 1999-2011 Gentoo Foundation
+# Copyright 1999-2012 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/boehm-gc/boehm-gc-7.2_alpha4-r1.ebuild,v 1.2 2011/11/13 18:56:12 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/boehm-gc/boehm-gc-7.2_alpha4-r1.ebuild,v 1.3 2012/05/29 19:17:13 jlec Exp $
 
-inherit eutils
+EAPI=4
+
+inherit autotools-utils
 
 MY_P="gc-${PV/_/}"
-S="${WORKDIR}/${MY_P}"
 
 DESCRIPTION="The Boehm-Demers-Weiser conservative garbage collector"
 HOMEPAGE="http://www.hpl.hp.com/personal/Hans_Boehm/gc/"
@@ -14,25 +15,34 @@ SRC_URI="http://www.hpl.hp.com/personal/Hans_Boehm/gc/gc_source/${MY_P}.tar.gz"
 LICENSE="as-is"
 SLOT="0"
 KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
-IUSE="cxx threads"
+IUSE="cxx static-libs threads"
 
 DEPEND="dev-libs/libatomic_ops"
 RDEPEND="${DEPEND}"
 
-src_compile() {
+S="${WORKDIR}/${MY_P}"
+
+DOCS=( README.QUICK doc/README{,.environment,.linux,.macros} doc/barrett_diagram )
+
+src_prepare() {
 	sed '/Cflags/s:$:/gc:g' -i bdw-gc.pc.in || die
+	rm -rvf libatomic_ops || die
+	autotools-utils_src_prepare
+}
 
-	econf \
-		--with-libatomic-ops=yes \
-		$(use_enable cxx cplusplus) \
+src_configure() {
+	local myeconfargs=(
+		--with-libatomic-ops=yes
+		$(use_enable cxx cplusplus)
 		$(use threads || echo --disable-threads)
-	emake || die
+		)
+	autotools-utils_src_configure
 }
 
 src_install() {
-	emake DESTDIR="${D}" install || die
+	autotools-utils_src_install
 
-	rm -rf "${D}"/usr/share/gc || die
+	rm -rf "${ED}"/usr/share/gc || die
 
 	# dist_noinst_HEADERS
 	insinto /usr/include/gc
@@ -40,7 +50,6 @@ src_install() {
 	insinto /usr/include/gc/private
 	doins include/private/*.h
 
-	dodoc README.QUICK doc/README* doc/barrett_diagram
 	dohtml doc/*.html
 	newman doc/gc.man GC_malloc.1
 }
diff --git a/dev-libs/boehm-gc/boehm-gc-7.2_alpha6.ebuild b/dev-libs/boehm-gc/boehm-gc-7.2_alpha6.ebuild
new file mode 100644
index 000000000000..3ccc82221bdc
--- /dev/null
+++ b/dev-libs/boehm-gc/boehm-gc-7.2_alpha6.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/boehm-gc/boehm-gc-7.2_alpha6.ebuild,v 1.1 2012/05/29 19:17:13 jlec Exp $
+
+EAPI=4
+
+AUTOTOOLS_AUTORECONF=yes
+
+inherit autotools-utils
+
+MY_P="gc-${PV/_/}"
+
+DESCRIPTION="The Boehm-Demers-Weiser conservative garbage collector"
+HOMEPAGE="http://www.hpl.hp.com/personal/Hans_Boehm/gc/"
+SRC_URI="http://www.hpl.hp.com/personal/Hans_Boehm/gc/gc_source/${MY_P}.tar.gz"
+
+LICENSE="as-is"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="cxx static-libs threads"
+
+DEPEND="dev-libs/libatomic_ops"
+RDEPEND="${DEPEND}"
+
+S="${WORKDIR}/${MY_P}"
+
+DOCS=( README.QUICK doc/README{,.environment,.linux,.macros} doc/barrett_diagram )
+
+src_prepare() {
+	sed '/Cflags/s:$:/gc:g' -i bdw-gc.pc.in || die
+	sed \
+		-e '/gc_allocator.h/d' \
+		-i Makefile.am || die
+	rm -rf libatomic_ops || die
+	autotools-utils_src_prepare
+}
+
+src_configure() {
+	local myeconfargs=(
+		--with-libatomic-ops=yes
+		$(use_enable cxx cplusplus)
+		$(use threads || echo --disable-threads)
+		)
+	autotools-utils_src_configure
+}
+
+src_install() {
+	autotools-utils_src_install
+
+	rm -rf "${ED}"/usr/share/gc || die
+
+	# dist_noinst_HEADERS
+	insinto /usr/include/gc
+	doins include/{cord.h,ec.h,javaxfc.h}
+	insinto /usr/include/gc/private
+	doins include/private/*.h
+
+	dohtml doc/*.html
+	newman doc/gc.man GC_malloc.1
+}
diff --git a/dev-libs/boehm-gc/metadata.xml b/dev-libs/boehm-gc/metadata.xml
index b493e619a6d4..e222617a36fa 100644
--- a/dev-libs/boehm-gc/metadata.xml
+++ b/dev-libs/boehm-gc/metadata.xml
@@ -1,7 +1,7 @@
 <?xml version="1.0" encoding="UTF-8"?>
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
-<maintainer>
-  <email>matsuu@gentoo.org</email>
-</maintainer>
+	<maintainer>
+		<email>matsuu@gentoo.org</email>
+	</maintainer>
 </pkgmetadata>