Removed bundled libraries, added suggested dependencies and optional ones as run depedencies. Propagate global patch prefix friendly. Fix tests, some other modifications from Arfrever

Package-Manager: portage-2.1.10.41/cvs/Linux x86_64

6 files changed, 181 insertions, 96 deletions

diff --git a/dev-python/ipython/ChangeLog b/dev-python/ipython/ChangeLog
index a91a0a671c88..e6705f8fdb9a 100644
--- a/dev-python/ipython/ChangeLog
+++ b/dev-python/ipython/ChangeLog
@@ -1,6 +1,14 @@
 # ChangeLog for dev-python/ipython
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/ipython/ChangeLog,v 1.88 2012/01/08 22:07:39 bicatali Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/ipython/ChangeLog,v 1.89 2012/01/10 22:14:58 bicatali Exp $
+
+*ipython-0.12-r1 (10 Jan 2012)
+
+  10 Jan 2012; Sébastien Fabbro <bicatali@gentoo.org> -ipython-0.12.ebuild,
+  +ipython-0.12-r1.ebuild, +files/ipython-0.12-globalpath.patch, metadata.xml:
+  Removed bundled libraries, added suggested dependencies and optional ones as
+  run depedencies. Propagate global patch prefix friendly. Fix tests, some
+  other modifications from Arfrever
 
 *ipython-0.12 (08 Jan 2012)
 
diff --git a/dev-python/ipython/Manifest b/dev-python/ipython/Manifest
index ac4dae431f24..9bc9d9655186 100644
--- a/dev-python/ipython/Manifest
+++ b/dev-python/ipython/Manifest
@@ -2,6 +2,7 @@
 Hash: SHA1
 
 AUX 62ipython-gentoo.el 127 RMD160 01a862c77ce09ef0d1613504607db4fa5d840dc1 SHA1 a3650b3e477620e4977820d21a93bf68ab18bfa8 SHA256 b5900b95df4f197aedea20432f3c71de5bc7149fa1022f8417be7a606647b449
+AUX ipython-0.12-globalpath.patch 430 RMD160 c57a89751e4d0f0782115ffcb2e8dd3262c8a743 SHA1 9a99dfadd3a83ef704e92206ada5ad0271bf656f SHA256 f0b2dbc53aa20dc1350af956a40ab748e092d0a471e0ac49e5ede75619658713
 AUX ipython-0.9.1-globalpath.patch 332 RMD160 8ab28812c4b9f3b2b6ccca7cc98cc4931f1f6585 SHA1 5ba9e5a02a429d5c2597db1c7f495996adce83fe SHA256 3e27dc5fce4f5ec594a389960e63e4707687c2306cfb6f4148b4d6d5b7176fcc
 DIST ipython-0.10.1.tar.gz 5837840 RMD160 c4f0177f466f6bfb32d98e73b5235885bc470871 SHA1 1e5cfde5ba6d704e0ccd414e633116e4199d0d7a SHA256 227607ce3768ff84c2d7a272e50200f7ad180267bf735633e1e2d85fc4cbfca3
 DIST ipython-0.10.2.tar.gz 5842688 RMD160 365a4eb9b534df1a9aa8717f173e9a032224ea01 SHA1 d45b97b0f458fd517cb2bfa9ebb3c671c46a21c0 SHA256 9ed5fe693d92e6ba9ecc3e367ae5607b80d66db53b0a636fa39fe15ae3df8c47
@@ -10,13 +11,13 @@ DIST ipython-0.12.tar.gz 9316219 RMD160 7086a8a5ebb5717091d1868907f6ae80abc9c7ab
 EBUILD ipython-0.10.1.ebuild 2830 RMD160 fa3b66842c965c04363a35a95aff112f8975772b SHA1 66c7d7545ab55bfe0b56e1d7653b1ac034192025 SHA256 14018fee0d0543003ae46932e475c2b6360f7d4278dd82ab483c5b162df5f3c2
 EBUILD ipython-0.10.2.ebuild 3267 RMD160 64ec4c72df6aa15a478691a9b7d719f6c8ec6c4b SHA1 e942173dc1fe6ec38a82a5269f15317ca6037513 SHA256 523713370d3a29eacecdab68b8c279b42f33730c07389276e35a9ce14130c809
 EBUILD ipython-0.10.ebuild 2660 RMD160 442e9f8025eb1e43c8c55f6d457319fde4382b18 SHA1 a1a721b5a278df278c1509a1243f24f39c5d5168 SHA256 0bf2dd1d7db7455e61aaf11b03ce990bcd96efe0b608f095ea6e5846d9944bef
-EBUILD ipython-0.12.ebuild 2056 RMD160 bbcb3b0a3815ce50c72096762085648225c9a08d SHA1 4c1bf97b0dbcab06dd1c4c31c3363a705057b31a SHA256 73cbdc022b3b0d2e2925d28b1f13d3aa30e63f92eacddbec45e1e079af8cf4f8
-MISC ChangeLog 13129 RMD160 6590b2137c786a7759cddb9460ecd588fbe3ae37 SHA1 f097a3629702852767c1c00ae439a5f4b0d38567 SHA256 6afdc4048b686b7124a643f99e8dc150e31c9f7e8b25d8db109b16010843f19b
-MISC metadata.xml 3396 RMD160 898ba344c013a770ae29c414ab36d5af4d8f381a SHA1 4923849a1f2f356ec248944c93c6f4898dc75eab SHA256 dc08c8a961e1c30997cfe3ddc9e03081bef2f8344ccbb3d27c1ec25668428a00
+EBUILD ipython-0.12-r1.ebuild 4024 RMD160 572ddba8ee8638d850f6f3dcaf430f723d161ac4 SHA1 88ef1fd05765d7f50324efda4f544a17b8f1b5a8 SHA256 f5954adf22bd4aaab1e0f9b70942ce56d0b351820dc29404ae19e30e71780ad1
+MISC ChangeLog 13508 RMD160 3dd722a1a3b44e412226ecd4df5c7879be53a3b9 SHA1 9dacedcf06b98e4a26f1b769a13b67acdbe330f6 SHA256 865110d2c1257bd977d4a14198aa8db0d753d8bd27cece62361a06d202913667
+MISC metadata.xml 3569 RMD160 4e4223df70aaa9dd0332dfd2a85beb6f31c9920a SHA1 a5efe5ea0972dbaca19ccbd6ea4b58ba89d41584 SHA256 dd07b0fe9b89cfc0bb285cb96ec6026c4e88e26352886cd7d8c6006eb1599c4b
 -----BEGIN PGP SIGNATURE-----
 Version: GnuPG v2.0.18 (GNU/Linux)
 
-iEYEARECAAYFAk8KE7QACgkQ1ycZbhPLE2D2uACgibh+gW6TJ8woKlYf5Oy2nlIZ
-/XMAnR9uvEsW0xgc4V7TEdYJFuhclr+N
-=l9f+
+iEYEARECAAYFAk8MuG0ACgkQ1ycZbhPLE2DgxgCfV5HvWrVjQKaxpF8Qk0yxr3d9
+SosAoJi4+qDEdkWERVqT5z2gMS3lpgH0
+=enw+
 -----END PGP SIGNATURE-----
diff --git a/dev-python/ipython/files/ipython-0.12-globalpath.patch b/dev-python/ipython/files/ipython-0.12-globalpath.patch
new file mode 100644
index 000000000000..fa7bbdc14fe8
--- /dev/null
+++ b/dev-python/ipython/files/ipython-0.12-globalpath.patch
@@ -0,0 +1,16 @@
+--- IPython/quarantine/ipy_gnuglobal.py.orig	2012-01-10 20:16:35.153515474 +0000
++++ IPython/quarantine/ipy_gnuglobal.py	2012-01-10 20:18:30.196504374 +0000
+@@ -7,10 +7,11 @@
+ 
+ from IPython.core import ipapi
+ ip = ipapi.get()
+-import os
++import os 
++import sys
+ 
+ # alter to your liking
+-global_bin = 'd:/opt/global/bin/global'
++global_bin = os.path.join(sys.prefix,'bin','global')
+ 
+ def global_f(self,cmdline):
+     simple = 0
diff --git a/dev-python/ipython/ipython-0.12-r1.ebuild b/dev-python/ipython/ipython-0.12-r1.ebuild
new file mode 100644
index 000000000000..0be542e336c8
--- /dev/null
+++ b/dev-python/ipython/ipython-0.12-r1.ebuild
@@ -0,0 +1,147 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/ipython/ipython-0.12-r1.ebuild,v 1.1 2012/01/10 22:14:58 bicatali Exp $
+
+EAPI=4
+
+# python eclass cruft
+PYTHON_USE_DEPEND="readline? sqlite?"
+PYTHON_MODNAME="IPython"
+SUPPORT_PYTHON_ABIS="1"
+RESTRICT_PYTHON_ABIS="2.[45]"
+
+inherit distutils elisp-common eutils virtualx
+
+DESCRIPTION="Advanced interactive shell for Python"
+HOMEPAGE="http://ipython.org/"
+SRC_URI="http://archive.ipython.org/release/${PV}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc emacs examples matplotlib mongodb notebook readline +smp
+	qt4 sqlite test wxwidgets"
+
+
+CDEPEND="dev-python/decorator
+	|| ( dev-python/argparse =dev-lang/python-2.7* >=dev-lang/python-3.2 )
+	dev-python/pexpect
+	dev-python/pyparsing
+	dev-python/simplegeneric
+	emacs? ( app-emacs/python-mode virtual/emacs )
+	matplotlib? ( dev-python/matplotlib )
+	mongodb? ( dev-python/pymongo )
+	smp? ( dev-python/pyzmq )
+	wxwidgets? ( dev-python/wxpython )"
+RDEPEND="${CDEPEND}
+	notebook? ( >=www-servers/tornado-2.1
+			dev-python/pygments
+			dev-python/pyzmq )
+	qt4? ( || ( dev-python/PyQt4 dev-python/pyside )
+			dev-python/pygments
+			dev-python/pyzmq )"
+DEPEND="${CDEPEND}
+	test? ( dev-python/nose )"
+
+src_prepare() {
+	distutils_src_prepare
+	epatch "${FILESDIR}"/${P}-globalpath.patch
+
+	# fix for gentoo python scripts
+	sed -i \
+		-e "/ipython_cmd/s/ipython3/ipython/g" \
+		IPython/frontend/terminal/console/tests/test_console.py \
+		IPython/lib/irunner.py \
+		IPython/testing/tools.py || die
+
+	sed -i \
+		-e "s/find_scripts(True, suffix='3')/find_scripts(True)/" \
+		setup3.py || die
+
+	# failing tests
+	sed -i \
+		-e 's/test_smoketest_aimport/_&/' \
+		-e 's/test_smoketest_autoreload/_&/' \
+		 IPython/extensions/tests/test_autoreload.py || die
+	sed -i \
+		-e 's/test_pylab_import_all_disabled/_&/' \
+		-e 's/test_pylab_import_all_enabled/_&/' \
+		IPython/lib/tests/test_irunner_pylab_magic.py || die
+	sed -i \
+		-e '/test_startup_py/i\\@dec.known_failure_py3' \
+		-e '/test_startup_ipy/i\\@dec.known_failure_py3' \
+		IPython/core/tests/test_profile.py || die
+	sed -i \
+		-e '/test_tclass/i\\    @dec.known_failure_py3' \
+		IPython/core/tests/test_run.py || die
+
+	# installation directory for documentation
+	sed -i \
+		-e "/docdirbase  = pjoin/s/ipython/${PF}/" \
+		-e "/pjoin(docdirbase,'manual')/s/manual/html/" \
+		setupbase.py || die "sed failed"
+
+	rm -rf docs/html/{.buildinfo,_sources,objects.inv} || die
+
+	if ! use doc; then
+		sed -i \
+			-e "/(pjoin(docdirbase, 'extensions'), igridhelpfiles),/d" \
+			-e 's/ + manual_files//' \
+			setupbase.py || die
+	fi
+
+	if ! use examples; then
+		sed -i \
+			-e 's/+ example_files//' \
+			setupbase.py || die
+	fi
+}
+
+src_compile() {
+	distutils_src_compile
+	use emacs && elisp-compile docs/emacs/ipython.el
+}
+
+src_test() {
+	if use mongodb; then
+		mkdir -p "${T}/mongo.db"
+		mongod --dbpath "${T}/mongo.db" --fork --logpath "${T}/mongo.log"
+	fi
+
+	testing() {
+		"$(PYTHON)" setup.py \
+			build -b "build-${PYTHON_ABI}" \
+			install --root="${T}/tests-${PYTHON_ABI}" > /dev/null || die
+		# Initialize ~/.ipython directory.
+		PATH="${T}/tests-${PYTHON_ABI}${EPREFIX}/usr/bin:${PATH}" \
+			PYTHONPATH="${T}/tests-${PYTHON_ABI}${EPREFIX}$(python_get_sitedir)" \
+			ipython <<< "" > /dev/null || return 1
+		# Run tests (-v for more verbosity).
+		PATH="${T}/tests-${PYTHON_ABI}${EPREFIX}/usr/bin:${PATH}" \
+			PYTHONPATH="${T}/tests-${PYTHON_ABI}${EPREFIX}$(python_get_sitedir)" \
+			iptest -v || return 1
+	}
+	VIRTUALX_COMMAND="python_execute_function" virtualmake testing
+
+	use mongodb && killall -u "$(id -nu)" mongod
+}
+
+src_install() {
+	distutils_src_install
+	if use emacs; then
+		pushd docs/emacs > /dev/null
+		elisp-install ${PN} ${PN}.el*
+		elisp-site-file-install "${FILESDIR}"/62ipython-gentoo.el
+		popd > /dev/null
+	fi
+}
+
+pkg_postinst() {
+	distutils_pkg_postinst
+	use emacs && elisp-site-regen
+}
+
+pkg_postrm() {
+	distutils_pkg_postrm
+	use emacs && elisp-site-regen
+}
diff --git a/dev-python/ipython/ipython-0.12.ebuild b/dev-python/ipython/ipython-0.12.ebuild
deleted file mode 100644
index d37e6bce6d78..000000000000
--- a/dev-python/ipython/ipython-0.12.ebuild
+++ /dev/null
@@ -1,89 +0,0 @@
-# Copyright 1999-2012 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/ipython/ipython-0.12.ebuild,v 1.1 2012/01/08 22:07:39 bicatali Exp $
-
-EAPI=4
-
-# python eclass cruft
-PYTHON_USE_DEPEND="readline sqlite"
-PYTHON_MODNAME="IPython"
-SUPPORT_PYTHON_ABIS="1"
-RESTRICT_PYTHON_ABIS="2.[45]"
-
-inherit distutils elisp-common eutils
-
-DESCRIPTION="Advanced interactive shell for Python"
-HOMEPAGE="http://ipython.org/"
-SRC_URI="http://archive.ipython.org/release/${PV}/${P}.tar.gz"
-
-LICENSE="BSD"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE="doc emacs examples notebook +smp qt4 test wxwidgets"
-
-CDEPEND="dev-python/pexpect
-	emacs? ( app-emacs/python-mode virtual/emacs )
-	smp? ( dev-python/pyzmq )
-	wxwidgets? ( dev-python/wxpython )"
-RDEPEND="${CDEPEND}
-	notebook? ( www-servers/tornado
-			dev-python/pygments
-			dev-python/pyzmq )
-	qt4? ( || ( dev-python/PyQt4 dev-python/pyside )
-			dev-python/pygments
-			dev-python/pyzmq )"
-DEPEND="${CDEPEND}
-	test? ( dev-python/nose )"
-
-SITEFILE="62ipython-gentoo.el"
-
-src_prepare() {
-	sed -i \
-		-e "/docdirbase/s:ipython:${PF}:" \
-		setupbase.py || die "sed failed"
-	if ! use doc; then
-		sed -i \
-			-e 's/+ manual_files//' \
-			setupbase.py || die "sed failed"
-	fi
-	if ! use examples; then
-		sed -i \
-			-e 's/+ example_files//' \
-			setupbase.py || die "sed failed"
-	fi
-}
-
-src_compile() {
-	distutils_src_compile
-	use emacs && elisp-compile docs/emacs/ipython.el
-}
-
-src_test() {
-	testing() {
-		pushd build-${PYTHON_ABI} > /dev/null
-		PYTHONPATH=lib PATH="scripts-${PYTHON_ABI}:${PTHONPATH}" \
-			iptest"$([[ ${PYTHON_ABI} == 3.* ]] && echo 3)"
-		popd > /dev/null
-	}
-	python_execute_function testing
-}
-
-src_install() {
-	distutils_src_install
-	if use emacs; then
-		pushd docs/emacs > /dev/null
-		elisp-install ${PN} ${PN}.el*
-		elisp-site-file-install "${FILESDIR}/${SITEFILE}"
-		popd > /dev/null
-	fi
-}
-
-pkg_postinst() {
-	distutils_pkg_postinst
-	use emacs && elisp-site-regen
-}
-
-pkg_postrm() {
-	distutils_pkg_postrm
-	use emacs && elisp-site-regen
-}
diff --git a/dev-python/ipython/metadata.xml b/dev-python/ipython/metadata.xml
index b8e2b1057faf..a99b6643630e 100644
--- a/dev-python/ipython/metadata.xml
+++ b/dev-python/ipython/metadata.xml
@@ -41,6 +41,8 @@ Main features:
 * pdbデバッガとprofilerへの統合アクセス。
 </longdescription>
 <use>
+  <flag name='matplotlib'>Add support for <pkg>dev-python/matplotlib</pkg></flag>
+  <flag name='mongodb'>Enable support for MongoDB via <pkg>dev-python/pymongo</pkg></flag>
   <flag name="notebook">Install requirements for the web notebook based on <pkg>www-servers/tornado</pkg></flag>
 </use>
 </pkgmetadata>