Bug #298390: All the Subversion ebuilds now offer perl, so we can USE-dep on it.

Package-Manager: portage-2.2_rc58/cvs/Linux x86_64

4 files changed, 426 insertions, 5 deletions

diff --git a/dev-util/git/ChangeLog b/dev-util/git/ChangeLog
index 03c24d431db5..02fbcb78d916 100644
--- a/dev-util/git/ChangeLog
+++ b/dev-util/git/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for dev-util/git
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/git/ChangeLog,v 1.391 2009/12/26 00:10:34 robbat2 Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/git/ChangeLog,v 1.392 2009/12/26 00:44:34 robbat2 Exp $
+
+*git-1.6.6-r2 (26 Dec 2009)
+
+  26 Dec 2009; Robin H. Johnson <robbat2@gentoo.org> +git-1.6.6-r2.ebuild,
+  git-9999.ebuild:
+  Bug #298390: All the Subversion ebuilds now offer perl, so we can USE-dep
+  on it.
 
 *git-1.6.6-r1 (26 Dec 2009)
 
diff --git a/dev-util/git/Manifest b/dev-util/git/Manifest
index 3d713b583162..67332f0cb172 100644
--- a/dev-util/git/Manifest
+++ b/dev-util/git/Manifest
@@ -86,9 +86,10 @@ EBUILD git-1.6.5.ebuild 10151 RMD160 b604e61e1c293f315fb3c65cf68fbc00f1f16b76 SH
 EBUILD git-1.6.5_rc1.ebuild 9810 RMD160 23db321ce87550053fdd25faf3dee43b051a9bdc SHA1 d984a36291740c627761a9b6f9e601b70f038f1f SHA256 0661b98bb406fd7ea7a46b4c9094bbd6ad0220feaddf8406950e0f53b251bee3
 EBUILD git-1.6.5_rc2.ebuild 9825 RMD160 7f95a77f7711d8432e3b489e7802e2b1190ac2cd SHA1 d47951f7fa820446551dea608471f2388d77b7df SHA256 eec4c8f43b9bb211580e01e36cae0732e55fb6742d9068bea9c4a16344ccac0e
 EBUILD git-1.6.6-r1.ebuild 11125 RMD160 52882c3f30ab63578caf10e8f2e8288c94905082 SHA1 cfa1461379d3f82ef22623ba47cb8264d14f21e7 SHA256 9569e8c8490bb74430169be0842be91c880793dd9f4e3d5e4f77c292797060bf
+EBUILD git-1.6.6-r2.ebuild 11130 RMD160 93f4e79cf93185064a266b9ca52cb56c7eb9818d SHA1 f1ce076cc53a5c74d6af189fd3750d6c6e5b6259 SHA256 cde2853503277f18eef83250bc9042fa884b134b3026a615724695e99da86025
 EBUILD git-1.6.6.ebuild 10944 RMD160 5fbeb97e618d70fd89d769625b3f326e4807a663 SHA1 92d66eb3692532b79ad27823cbad7de83088d7c7 SHA256 8ef6535cf8d2016e2e4797071d11f9878b877c711d4e2a45efe95b06ae624772
 EBUILD git-1.6.6_rc3.ebuild 10948 RMD160 d26ee1d80db76370257ef1a9dc98d147dac8998e SHA1 fa5850d6fd8b645e766cea7f7db0f13c01727fd5 SHA256 39316fe2f1e1b6dcf36ee3cb67f1c949ee2cb86d83fe3ec20bc2337b9c42a223
 EBUILD git-1.6.6_rc4.ebuild 10948 RMD160 a8a6e815a9bad3b2b0bd585a03249ba5ebaac3ab SHA1 31f2c22aed19ae373096deceee109e8812a5b1d4 SHA256 02dba7f8470d2bfef0116c8b8266de9200693745bf396bdf2e93036f0a2fb540
-EBUILD git-9999.ebuild 11122 RMD160 2ad88ff5d32e8fceeb2f5f612470e2a6ce9b4363 SHA1 f5e646ac29afc0260d0f1358e91ffe361a9416f4 SHA256 d3a4bfa45f958d2614e5d58a65a4b740cee2f97c14ddd33e46cae120b825daf4
-MISC ChangeLog 60573 RMD160 a58a1ddababe51b8efa431309634c796cefa90a0 SHA1 1b96d2c470b72865873172f7e2366c46a5f43f69 SHA256 c1d5ed57fb717a6700f486e597dafa17b159f30cd72b3b1976ef920764ab5c94
+EBUILD git-9999.ebuild 11127 RMD160 f8d5ae620a551c4ff473356a931ad8d445e6b8cb SHA1 4eb76484dc64f5aff32e1dba45eb2d3319c686b0 SHA256 23ef849a0321e3237cd5c909e774078e6ada59a5a92a08407d81a1d257ee0883
+MISC ChangeLog 60782 RMD160 76b1beaa8ffb6b48289c25250c41fd3909c08306 SHA1 dca7eee53de7e04e6dc2d705096e065233a674c1 SHA256 b812ecef8e6073052896d0c6473317d7d137ec6522544c24b2dbfb919db26b9e
 MISC metadata.xml 1610 RMD160 6b03b898986d26bba7ff441dc1c8c9ec04a9a2b9 SHA1 a0a0d304138c648729d225954de89c1aac359008 SHA256 d070dc8e46e0fd44676d0491353f95385e65c1ffcd1313193dc59d495245c007
diff --git a/dev-util/git/git-1.6.6-r2.ebuild b/dev-util/git/git-1.6.6-r2.ebuild
new file mode 100644
index 000000000000..d91343bbc109
--- /dev/null
+++ b/dev-util/git/git-1.6.6-r2.ebuild
@@ -0,0 +1,413 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-util/git/git-1.6.6-r2.ebuild,v 1.1 2009/12/26 00:44:34 robbat2 Exp $
+
+EAPI=2
+
+inherit toolchain-funcs eutils elisp-common perl-module bash-completion
+[ "$PV" == "9999" ] && inherit git
+
+MY_PV="${PV/_rc/.rc}"
+MY_P="${PN}-${MY_PV}"
+
+DOC_VER=${MY_PV}
+
+DESCRIPTION="GIT - the stupid content tracker, the revision control system heavily used by the Linux kernel team"
+HOMEPAGE="http://www.git-scm.com/"
+if [ "$PV" != "9999" ]; then
+	SRC_URI="mirror://kernel/software/scm/git/${MY_P}.tar.bz2
+			mirror://kernel/software/scm/git/${PN}-manpages-${DOC_VER}.tar.bz2
+			doc? ( mirror://kernel/software/scm/git/${PN}-htmldocs-${DOC_VER}.tar.bz2 )"
+	KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~s390 ~sh ~sparc ~x86 ~sparc-fbsd ~x86-fbsd"
+else
+	SRC_URI=""
+	EGIT_BRANCH="master"
+	EGIT_REPO_URI="git://git.kernel.org/pub/scm/git/git.git"
+	# EGIT_REPO_URI="http://www.kernel.org/pub/scm/git/git.git"
+	KEYWORDS=""
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="+blksha1 +curl cgi doc emacs gtk iconv +perl ppcsha1 tk +threads +webdav xinetd cvs subversion"
+
+# Common to both DEPEND and RDEPEND
+CDEPEND="
+	!blksha1? ( dev-libs/openssl )
+	sys-libs/zlib
+	perl?   ( dev-lang/perl )
+	tk?     ( dev-lang/tk )
+	curl?   (
+		net-misc/curl
+		webdav? ( dev-libs/expat )
+	)
+	emacs?  ( virtual/emacs )"
+
+RDEPEND="${CDEPEND}
+	perl? ( dev-perl/Error
+			dev-perl/Net-SMTP-SSL
+			dev-perl/Authen-SASL
+			cgi? ( virtual/perl-CGI )
+			cvs? ( >=dev-util/cvsps-2.1 dev-perl/DBI dev-perl/DBD-SQLite )
+			subversion? ( dev-util/subversion[-dso,perl] dev-perl/libwww-perl dev-perl/TermReadKey )
+			)
+	gtk?
+	(
+		>=dev-python/pygtk-2.8
+		|| ( dev-python/pygtksourceview:2  dev-python/gtksourceview-python )
+	)"
+
+# This is how info docs are created with Git:
+#   .txt/asciidoc --(asciidoc)---------> .xml/docbook
+#   .xml/docbook  --(docbook2texi.pl)--> .texi
+#   .texi         --(makeinfo)---------> .info
+DEPEND="${CDEPEND}
+	app-arch/cpio
+	doc?    (
+		app-text/asciidoc
+		app-text/docbook2X
+		sys-apps/texinfo
+	)"
+
+# Live ebuild builds HTML docs, additionally
+if [ "$PV" == "9999" ]; then
+	DEPEND="${DEPEND}
+		doc?    (
+			app-text/xmlto
+		)"
+fi
+
+SITEFILE=50${PN}-gentoo.el
+S="${WORKDIR}/${MY_P}"
+
+pkg_setup() {
+	if ! use perl ; then
+		use cgi && ewarn "gitweb needs USE=perl, ignoring USE=cgi"
+		use cvs && ewarn "CVS integration needs USE=perl, ignoring USE=cvs"
+		use subversion && ewarn "git-svn needs USE=perl, it won't work"
+	fi
+	if use webdav && ! use curl ; then
+		ewarn "USE=webdav needs USE=curl. Ignoring"
+	fi
+	if use subversion && has_version dev-util/subversion && built_with_use --missing false dev-util/subversion dso ; then
+		ewarn "Per Gentoo bugs #223747, #238586, when subversion is built"
+		ewarn "with USE=dso, there may be weird crashes in git-svn. You"
+		ewarn "have been warned."
+	fi
+}
+
+# This is needed because for some obscure reasons future calls to make don't
+# pick up these exports if we export them in src_unpack()
+exportmakeopts() {
+	local myopts
+
+	if use blksha1 ; then
+		myopts="${myopts} BLK_SHA1=YesPlease"
+	elif use ppcsha1 ; then
+		myopts="${myopts} PPC_SHA1=YesPlease"
+	fi
+
+	if use curl ; then
+		use webdav || myopts="${myopts} NO_EXPAT=YesPlease"
+	else
+		myopts="${myopts} NO_CURL=YesPlease"
+	fi
+
+	use iconv \
+		|| myopts="${myopts} NO_ICONV=YesPlease"
+	use tk \
+		|| myopts="${myopts} NO_TCLTK=YesPlease"
+	use perl \
+		&& myopts="${myopts} INSTALLDIRS=vendor" \
+		|| myopts="${myopts} NO_PERL=YesPlease"
+	use threads \
+		&& myopts="${myopts} THREADED_DELTA_SEARCH=YesPlease"
+	use subversion \
+		|| myopts="${myopts} NO_SVN_TESTS=YesPlease"
+
+	has_version '>=app-text/asciidoc-8.0' \
+		&& myopts="${myopts} ASCIIDOC8=YesPlease"
+	myopts="${myopts} ASCIIDOC_NO_ROFF=YesPlease"
+
+	# Bug 290465:
+	# builtin-fetch-pack.c:816: error: 'struct stat' has no member named 'st_mtim'
+	[[ "${CHOST}" == *-uclibc* ]] && \
+		myopts="${myopts} NO_NSEC=YesPlease"
+
+	export MY_MAKEOPTS="${myopts}"
+}
+
+src_unpack() {
+	if [ "${PV}" != "9999" ]; then
+		unpack ${MY_P}.tar.bz2
+		cd "${S}"
+		unpack ${PN}-manpages-${DOC_VER}.tar.bz2
+		use doc && \
+			cd "${S}"/Documentation && \
+			unpack ${PN}-htmldocs-${DOC_VER}.tar.bz2
+		cd "${S}"
+	else
+		git_src_unpack
+		cd "${S}"
+		#cp "${FILESDIR}"/GIT-VERSION-GEN .
+	fi
+
+}
+
+src_prepare() {
+	# Noperl is being merged to upstream as of 2009/04/05
+	#epatch "${FILESDIR}"/20090305-git-1.6.2-noperl.patch
+
+	# GetOpt-Long v2.38 is strict
+	# Merged in 1.6.3 final 2009/05/07
+	#epatch "${FILESDIR}"/20090505-git-1.6.2.5-getopt-fixes.patch
+
+	# JS install fixup
+	epatch "${FILESDIR}"/git-1.6.6-always-install-js.patch
+
+	sed -i \
+		-e 's:^\(CFLAGS =\).*$:\1 $(OPTCFLAGS) -Wall:' \
+		-e 's:^\(LDFLAGS =\).*$:\1 $(OPTLDFLAGS):' \
+		-e 's:^\(CC = \).*$:\1$(OPTCC):' \
+		-e 's:^\(AR = \).*$:\1$(OPTAR):' \
+		Makefile || die "sed failed"
+
+	# Never install the private copy of Error.pm (bug #296310)
+	sed -i \
+		-e '/private-Error.pm/s,^,#,' \
+		perl/Makefile.PL
+
+	# Fix docbook2texi command
+	sed -i 's/DOCBOOK2X_TEXI=docbook2x-texi/DOCBOOK2X_TEXI=docbook2texi.pl/' \
+		Documentation/Makefile || die "sed failed"
+
+}
+
+git_emake() {
+	emake ${MY_MAKEOPTS} \
+		DESTDIR="${D}" \
+		OPTCFLAGS="${CFLAGS}" \
+		OPTLDFLAGS="${LDFLAGS}" \
+		OPTCC="$(tc-getCC)" \
+		OPTAR="$(tc-getAR)" \
+		prefix=/usr \
+		htmldir=/usr/share/doc/${PF}/html \
+		"$@"
+}
+
+src_configure() {
+	exportmakeopts
+}
+
+src_compile() {
+	git_emake || die "emake failed"
+
+	if use emacs ; then
+		elisp-compile contrib/emacs/git{,-blame}.el \
+			|| die "emacs modules failed"
+	fi
+
+	if use perl && use cgi ; then
+		git_emake \
+			gitweb/gitweb.cgi \
+			|| die "emake gitweb/gitweb.cgi failed"
+	fi
+
+	cd "${S}"/Documentation
+	if [[ "$PV" == "9999" ]] ; then
+		git_emake man \
+			|| die "emake man failed"
+		if use doc ; then
+			git_emake info html \
+				|| die "emake info html failed"
+		fi
+	else
+		if use doc ; then
+			git_emake info \
+				|| die "emake info html failed"
+		fi
+	fi
+}
+
+src_install() {
+	git_emake \
+		install || \
+		die "make install failed"
+
+	doman man?/*.[157] Documentation/*.[157]
+
+	dodoc README Documentation/{SubmittingPatches,CodingGuidelines}
+	use doc && dodir /usr/share/doc/${PF}/html
+	for d in / /howto/ /technical/ ; do
+		docinto ${d}
+		dodoc Documentation${d}*.txt
+		use doc && dohtml -p ${d} Documentation${d}*.html
+	done
+	docinto /
+	# Upstream does not ship this pre-built :-(
+	use doc && doinfo Documentation/{git,gitman}.info
+
+	dobashcompletion contrib/completion/git-completion.bash ${PN}
+
+	if use emacs ; then
+		elisp-install ${PN} contrib/emacs/git.{el,elc} || die
+		elisp-install ${PN} contrib/emacs/git-blame.{el,elc} || die
+		#elisp-install ${PN}/compat contrib/emacs/vc-git.{el,elc} || die
+		# don't add automatically to the load-path, so the sitefile
+		# can do a conditional loading
+		touch "${D}${SITELISP}/${PN}/compat/.nosearch"
+		elisp-site-file-install "${FILESDIR}"/${SITEFILE} || die
+	fi
+
+	if use gtk ; then
+		dobin "${S}"/contrib/gitview/gitview
+		dodoc "${S}"/contrib/gitview/gitview.txt
+	fi
+
+	dobin contrib/fast-import/git-p4
+	dodoc contrib/fast-import/git-p4.txt
+	newbin contrib/fast-import/import-tars.perl import-tars
+
+	dodir /usr/share/${PN}/contrib
+	# The following are excluded:
+	# svnimport - use git-svn
+	# p4import - excluded because fast-import has a better one
+	# examples - these are stuff that is not used in Git anymore actually
+	# patches - stuff the Git guys made to go upstream to other places
+	for i in continuous fast-import hg-to-git \
+		hooks remotes2config.sh stats \
+		workdir convert-objects blameview ; do
+		cp -rf \
+			"${S}"/contrib/${i} \
+			"${D}"/usr/share/${PN}/contrib \
+			|| die "Failed contrib ${i}"
+	done
+
+	if use perl && use cgi ; then
+		dodir /usr/share/${PN}/gitweb
+		insinto /usr/share/${PN}/gitweb
+		doins "${S}"/gitweb/gitweb.cgi
+		doins "${S}"/gitweb/gitweb.css
+		js=gitweb.js
+		[ -f "${S}"/gitweb/gitweb.min.js ] && js=gitweb.min.js
+		doins "${S}"/gitweb/${js}
+		doins "${S}"/gitweb/git-{favicon,logo}.png
+
+		# Make sure it can run
+		fperms 0755 /usr/share/${PN}/gitweb/gitweb.cgi
+
+		# INSTALL discusses configuration issues, not just installation
+		docinto /
+		newdoc  "${S}"/gitweb/INSTALL INSTALL.gitweb
+		newdoc  "${S}"/gitweb/README README.gitweb
+
+		find "${D}"/usr/lib64/perl5/ \
+			-name .packlist \
+			-exec rm \{\} \;
+	fi
+	if ! use subversion ; then
+		rm -f "${D}"/usr/libexec/git-core/git-svn \
+			"${D}"/usr/share/man/man1/git-svn.1*
+	fi
+
+	if use xinetd ; then
+		insinto /etc/xinetd.d
+		newins "${FILESDIR}"/git-daemon.xinetd git-daemon
+	fi
+
+	newinitd "${FILESDIR}"/git-daemon.initd git-daemon
+	newconfd "${FILESDIR}"/git-daemon.confd git-daemon
+
+	fixlocalpod
+}
+
+src_test() {
+	local disabled=""
+	local tests_cvs="t9200-git-cvsexportcommit.sh \
+					t9400-git-cvsserver-server.sh \
+					t9600-cvsimport.sh"
+	local tests_perl="t5502-quickfetch.sh \
+					t5512-ls-remote.sh \
+					t5520-pull.sh"
+	# Bug #225601 - t0004 is not suitable for root perm
+	# Bug #219839 - t1004 is not suitable for root perm
+	# t0001-init.sh - check for init notices EPERM*  fails
+	local tests_nonroot="t0001-init.sh \
+		t0004-unwritable.sh \
+		t1004-read-tree-m-u-wf.sh \
+		t3700-add.sh \
+		t7300-clean.sh"
+
+	# Unzip is used only for the testcase code, not by any normal parts of Git.
+	if ! has_version app-arch/unzip ; then
+		einfo "Disabling tar-tree tests"
+		disabled="${disabled} t5000-tar-tree.sh"
+	fi
+
+	cvs=0
+	use cvs && let cvs=$cvs+1
+	if [[ ${EUID} -eq 0 ]]; then
+		if [[ $cvs -eq 1 ]]; then
+			ewarn "Skipping CVS tests because CVS does not work as root!"
+			ewarn "You should retest with FEATURES=userpriv!"
+			disabled="${disabled} ${tests_cvs}"
+		fi
+		einfo "Skipping other tests that require being non-root"
+		disabled="${disabled} ${tests_nonroot}"
+	else
+		[[ $cvs -gt 0 ]] && \
+			has_version dev-util/cvs && \
+			let cvs=$cvs+1
+		[[ $cvs -gt 1 ]] && \
+			built_with_use dev-util/cvs server && \
+			let cvs=$cvs+1
+		if [[ $cvs -lt 3 ]]; then
+			einfo "Disabling CVS tests (needs dev-util/cvs[USE=server])"
+			disabled="${disabled} ${tests_cvs}"
+		fi
+	fi
+
+	if ! use perl ; then
+		einfo "Disabling tests that need Perl"
+		disabled="${disabled} ${tests_perl}"
+	fi
+
+	# Reset all previously disabled tests
+	cd "${S}/t"
+	for i in *.sh.DISABLED ; do
+		[[ -f "${i}" ]] && mv -f "${i}" "${i%.DISABLED}"
+	done
+	einfo "Disabled tests:"
+	for i in ${disabled} ; do
+		[[ -f "${i}" ]] && mv -f "${i}" "${i}.DISABLED" && einfo "Disabled $i"
+	done
+	cd "${S}"
+	# Now run the tests
+	einfo "Start test run"
+	git_emake \
+		test || die "tests failed"
+}
+
+showpkgdeps() {
+	local pkg=$1
+	shift
+	elog "  $(printf "%-17s:" ${pkg}) ${@}"
+}
+
+pkg_postinst() {
+	use emacs && elisp-site-regen
+	if use subversion && has_version dev-util/subversion && ! built_with_use --missing false dev-util/subversion perl ; then
+		ewarn "You must build dev-util/subversion with USE=perl"
+		ewarn "to get the full functionality of git-svn!"
+	fi
+	elog "These additional scripts need some dependencies:"
+	echo
+	showpkgdeps git-quiltimport "dev-util/quilt"
+	showpkgdeps git-instaweb \
+		"|| ( www-servers/lighttpd www-servers/apache )"
+	echo
+}
+
+pkg_postrm() {
+	use emacs && elisp-site-regen
+}
diff --git a/dev-util/git/git-9999.ebuild b/dev-util/git/git-9999.ebuild
index ba8e5c3970fa..6cd1f9ba6a50 100644
--- a/dev-util/git/git-9999.ebuild
+++ b/dev-util/git/git-9999.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2009 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/git/git-9999.ebuild,v 1.18 2009/12/26 00:10:34 robbat2 Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/git/git-9999.ebuild,v 1.19 2009/12/26 00:44:34 robbat2 Exp $
 
 EAPI=2
 
@@ -49,7 +49,7 @@ RDEPEND="${CDEPEND}
 			dev-perl/Authen-SASL
 			cgi? ( virtual/perl-CGI )
 			cvs? ( >=dev-util/cvsps-2.1 dev-perl/DBI dev-perl/DBD-SQLite )
-			subversion? ( dev-util/subversion[-dso] dev-perl/libwww-perl dev-perl/TermReadKey )
+			subversion? ( dev-util/subversion[-dso,perl] dev-perl/libwww-perl dev-perl/TermReadKey )
 			)
 	gtk?
 	(