Fix jingle support, thanks to Llloeki in bug #151006.

Package-Manager: portage-2.1.2_pre2-r9

3 files changed, 139 insertions, 1 deletions

diff --git a/kde-base/kopete/ChangeLog b/kde-base/kopete/ChangeLog
index dc9573bb7e6e..a31abeda7dc2 100644
--- a/kde-base/kopete/ChangeLog
+++ b/kde-base/kopete/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for kde-base/kopete
 # Copyright 1999-2006 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-base/kopete/ChangeLog,v 1.81 2006/10/12 09:31:19 flameeyes Exp $
+# $Header: /var/cvsroot/gentoo-x86/kde-base/kopete/ChangeLog,v 1.82 2006/10/12 16:49:34 flameeyes Exp $
+
+*kopete-3.5.5-r1 (12 Oct 2006)
+
+  12 Oct 2006; Diego Pettenò <flameeyes@gentoo.org> -kopete-3.5.5.ebuild,
+  +kopete-3.5.5-r1.ebuild:
+  Fix jingle support, thanks to Llloeki in bug #151006.
 
   12 Oct 2006; Diego Pettenò <flameeyes@gentoo.org> kopete-3.5.5.ebuild:
   Remove alpha and ia64 keywords as they need to keyword/mask gsmlib.
diff --git a/kde-base/kopete/files/digest-kopete-3.5.5-r1 b/kde-base/kopete/files/digest-kopete-3.5.5-r1
new file mode 100644
index 000000000000..e013575200c5
--- /dev/null
+++ b/kde-base/kopete/files/digest-kopete-3.5.5-r1
@@ -0,0 +1,6 @@
+MD5 07d313f91154d3c2f4620b921277fdc8 kdenetwork-3.5-patchset-01.tar.bz2 2986
+RMD160 288113734e7767a7526f4b9311c1985ac8aa91bf kdenetwork-3.5-patchset-01.tar.bz2 2986
+SHA256 0bbde1adaa4e8fff02c1f1fd6ceb66ec9af14dd19ff64567ab0fd03926d7d05b kdenetwork-3.5-patchset-01.tar.bz2 2986
+MD5 a6e642c070cbd50d4a817f6588bf8e46 kdenetwork-3.5.5.tar.bz2 9235564
+RMD160 3e757d10ee5bf24b2ccf131e693fb614b9fdb9f4 kdenetwork-3.5.5.tar.bz2 9235564
+SHA256 c3f36e69bbd23902f2bdd9a1a8cda93b0436338ada422bb8ac6bc3d2bcd8e38f kdenetwork-3.5.5.tar.bz2 9235564
diff --git a/kde-base/kopete/kopete-3.5.5-r1.ebuild b/kde-base/kopete/kopete-3.5.5-r1.ebuild
new file mode 100644
index 000000000000..6ee184d7a3c3
--- /dev/null
+++ b/kde-base/kopete/kopete-3.5.5-r1.ebuild
@@ -0,0 +1,126 @@
+# Copyright 1999-2006 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/kde-base/kopete/kopete-3.5.5-r1.ebuild,v 1.1 2006/10/12 16:49:34 flameeyes Exp $
+
+KMNAME=kdenetwork
+MAXKDEVER=$PV
+KM_DEPRANGE="$PV $MAXKDEVER"
+inherit kde-meta eutils
+
+SRC_URI="${SRC_URI}
+	mirror://gentoo/kdenetwork-3.5-patchset-01.tar.bz2"
+
+DESCRIPTION="KDE multi-protocol IM client"
+HOMEPAGE="http://kopete.kde.org/"
+
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~x86-fbsd"
+IUSE="jingle sametime ssl xmms xscreensaver slp kernel_linux latex crypt
+	  winpopup sms irc yahoo gadu groupwise netmeeting statistics autoreplace
+	  connectionstatus contactnotes translator webpresence texteffect highlight
+	  alias autoreplace history nowlistening addbookmarks"
+
+# The kernel_linux? ( ) conditional dependencies are for webcams, not supported
+# on other kernels AFAIK
+BOTH_DEPEND="dev-libs/libxslt
+	dev-libs/libxml2
+	net-dns/libidn
+	>=dev-libs/glib-2
+	app-crypt/qca
+	sametime? ( =net-libs/meanwhile-0.4* )
+	xmms? ( media-sound/xmms )
+	jingle? (
+		>=media-libs/speex-1.1.6
+		dev-libs/expat
+		~net-libs/ortp-0.7.1 )
+	|| ( (
+		x11-libs/libX11
+		x11-libs/libXext
+		x11-libs/libXrender
+		xscreensaver? ( x11-libs/libXScrnSaver )
+		) <virtual/x11-7 )
+	kernel_linux? ( virtual/opengl )
+	sms? ( app-mobilephone/gsmlib )"
+
+RDEPEND="${BOTH_DEPEND}
+	ssl? ( app-crypt/qca-tls )
+	!kde-base/kopete
+	!kde-base/kdenetwork
+	latex? ( virtual/tetex
+		media-gfx/imagemagick )
+	crypt? ( app-crypt/gnupg )"
+#	gnomemeeting is deprecated and ekiga is not yet ~ppc64
+#	only needed for calling
+#	netmeeting? ( net-im/gnomemeeting )"
+
+DEPEND="${BOTH_DEPEND}
+	kernel_linux? ( virtual/os-headers )
+	|| ( (
+			x11-proto/videoproto
+			kernel_linux? ( x11-libs/libXv )
+			xscreensaver? ( x11-proto/scrnsaverproto )
+		) <virtual/x11-7 )"
+
+pkg_setup() {
+	if use kernel_linux && ! built_with_use =x11-libs/qt-3* opengl; then
+		eerror "To support Video4Linux webcams in this package is required to have"
+		eerror "=x11-libs/qt-3* compiled with OpenGL support."
+		eerror "Please reemerge =x11-libs/qt-3* with USE=\"opengl\"."
+		die "Please reemerge =x11-libs/qt-3* with USE=\"opengl\"."
+	fi
+}
+
+kopete_disable() {
+	einfo "Disabling $2 $1"
+	sed -i -e "s/$2//" "${S}/kopete/$1s/Makefile.am"
+}
+
+src_unpack() {
+	kde-meta_src_unpack
+
+	epatch "${FILESDIR}/kopete-0.12_alpha1-xscreensaver.patch"
+	# use ekiga instead of gnomemeeting by default
+	epatch "${FILESDIR}/gnomemeeting-ekiga.patch"
+
+	use latex || kopete_disable plugin latex
+	use crypt || kopete_disable plugin cryptography
+	use netmeeting || kopete_disable plugin netmeeting
+	use statistics || kopete_disable plugin statistics
+	use autoreplace || kopete_disable plugin autoreplace
+	use connectionstatus || kopete_disable plugin connectionstatus
+	use contactnotes || kopete_disable plugin contactnotes
+	use translator || kopete_disable plugin translator
+	use webpresence || kopete_disable plugin webpresence
+	use texteffect || kopete_disable plugin texteffect
+	use highlight || kopete_disable plugin highlight
+	use alias || kopete_disable plugin alias
+	use addbookmarks || kopete_disable plugin addbookmarks
+	use history || kopete_disable plugin history
+	use nowlistening || kopete_disable plugin nowlistening
+
+	use winpopup || kopete_disable protocol winpopup
+	use gadu || kopete_disable protocol '\$(GADU)'
+	use irc || kopete_disable protocol irc
+	use groupwise || kopete_disable protocol groupwise
+	use yahoo || kopete_disable protocol yahoo
+
+	rm -f "${S}/configure"
+}
+
+src_compile() {
+	# External libgadu support - doesn't work, kopete requires a specific development snapshot of libgadu.
+	# Maybe we can enable it in the future.
+	# The nowlistening plugin has xmms support.
+	local myconf="$(use_enable jingle)
+		$(use_enable sametime sametime-plugin)
+		$(use_with xmms) --without-external-libgadu
+		$(use_with xscreensaver) $(use_enable sms smsgsm)
+		$(use_enable debug testbed)"
+
+	kde_src_compile
+}
+
+src_install() {
+	kde_src_install
+
+	rm -f "${D}"/usr/bin/{stun,relay}server
+}