bump to push daemon_directory fix - bug #402367

Package-Manager: portage-2.1.10.45/cvs/Linux x86_64

3 files changed, 330 insertions, 15 deletions

diff --git a/mail-mta/postfix/ChangeLog b/mail-mta/postfix/ChangeLog
index 7fa1252df266..c70eebd86088 100644
--- a/mail-mta/postfix/ChangeLog
+++ b/mail-mta/postfix/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for mail-mta/postfix
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/mail-mta/postfix/ChangeLog,v 1.333 2012/02/05 06:13:58 eras Exp $
+# $Header: /var/cvsroot/gentoo-x86/mail-mta/postfix/ChangeLog,v 1.334 2012/02/06 13:20:05 eras Exp $
+
+*postfix-2.9.0-r1 (06 Feb 2012)
+
+  06 Feb 2012; Eray Aslan <eras@gentoo.org> +postfix-2.9.0-r1.ebuild:
+  bump to push daemon_directory fix - bug #402367
 
   05 Feb 2012; Eray Aslan <eras@gentoo.org> postfix-2.10_pre20120202.ebuild:
   install daemons to /usr/libexec/postfix for version 2.10 as well
diff --git a/mail-mta/postfix/Manifest b/mail-mta/postfix/Manifest
index fd298d27cb7f..b2fd313ce646 100644
--- a/mail-mta/postfix/Manifest
+++ b/mail-mta/postfix/Manifest
@@ -35,23 +35,24 @@ EBUILD postfix-2.8.5.ebuild 8447 RMD160 d783620f452d45b164b81c3f32fea5488dd703d1
 EBUILD postfix-2.8.6.ebuild 8435 RMD160 d794ccd5fae24cbef65034aedb5f8919ca216483 SHA1 3a0e9b1920bc6fab81287057f1f15bf00a5376a2 SHA256 6c25ce81553164eb797f83b4b170e0b8dd4049ee984653b043e27605ca32ce3a
 EBUILD postfix-2.8.7.ebuild 8427 RMD160 c5760fb0e0c943aebaa86af2ddaf0cff819e6b2f SHA1 46987dcf88be669d43d1859c836ce88f327bd407 SHA256 b04ac78d4dc3743246c4c680ea8e4b10a1b32aac485d5719fd0eba86dabe04cb
 EBUILD postfix-2.8.8.ebuild 8433 RMD160 a1670cca48ff09cb8ec6243bda4c14fe6c2baad8 SHA1 051e023f04cc06bb87448ce2307cc94ca0b79469 SHA256 bba214631e160d68020f83b1f8fbadffb45e5d2e1d097c2a6de75f3bf9de39e6
+EBUILD postfix-2.9.0-r1.ebuild 9296 RMD160 6f0d691eeff7bece376438d431bb7b4539dee5f6 SHA1 53414118d483659d5c62108c0b761b5de7d5317e SHA256 e8ddbdd3702dea309f20a75096901155641ed9d61b8955f1e47522985c429cf5
 EBUILD postfix-2.9.0.ebuild 9293 RMD160 2fb2f64001aa8e7f1ab57fb6388cb465ddd97d45 SHA1 0b0d0df36f2d78126f5e1ac6374bca83862df9be SHA256 57a2d43e2cec130971381e62e73336a0f0ed9338203b3984102f049e2d5094dd
-MISC ChangeLog 77074 RMD160 0812f1fab3516ec79c0c775ff6004e0759846df0 SHA1 a75a83c433571d26e3300a87401072fcda4126e4 SHA256 f4ca2ac4fdb32a43a997902cab0242c25c1650ccce93151ae89c536107ed950e
+MISC ChangeLog 77228 RMD160 6a2678d78a9e4cfb3546fb6df17fedf7df2f3f2b SHA1 e17c33762512a0d33dc6237d8a7dcb10b46e3b65 SHA256 5941e080fc780f7955ad7e11b1783a83ae6c6b8990ebb88910c2688901a7ec1a
 MISC metadata.xml 610 RMD160 095d8cd529350f58c64d6d2eb40e8534d3dddfae SHA1 d53048933e7490f3f342ccf8972c191ee8030ccd SHA256 00b7ef524664b20a9df7642573745b1d17b0b51f005ffd150ac6dccba38dee88
 -----BEGIN PGP SIGNATURE-----
 Version: GnuPG v2.0.18 (GNU/Linux)
 
-iQIcBAEBCAAGBQJPLh4sAAoJEHfx8XVYajsfCQkP/0IdSSFkQufCmZ2cl5jYKWtc
-CPTVdHzWzPSW6N8gG1zcpCxCT/NdV+Ht7dquBLlPgLG0cpHsEiUwWfSTXFWxg+eo
-aE+oRoNpRTzNBhJEsHV5RVn65pYRuVRWNWuZPmC+1DSwr37MvR3lAVv9eLhoQZib
-k4yZaFF68s4eFZv1ixhSaYP2D2R7I6ahXH4QTjXhcd03PhL/JvuotwEOWiF6b7pa
-19Nrjt9ZjQg593vSQOneFEckJ+XLpLqDQ3ux9y2PNurErsd2tWiN8EC3WmazxRtF
-n2n0aIq7L8AM+pC3sy0JveDiZ5Z2jAYcSoxcQHd0wzZNl5VQtJS9XIdKXeXuz0N0
-Mjf/td5TkFbVBno3BSriceOWJffoB460nwjI/llm//FrFxgeQT3y69CCVTCjmdhm
-PwE9ZOWyXOrjzfU3CISmen5d8fpt2daQ3A55m/UZPGVqcGB1U1Ta5qs5NW7N2KYa
-h7qSn/JhIRmjWPgLM+fAQ0pVw2OrIGP/O1+fJ8BR+b87UNRPLsaU0cJTwo9ZLaa+
-bSe6LxiLP3aJdw2NytBESepgWbxlTvoDcatAht64RdIbLhVT5M41+TWA9mhc/kCT
-gROflHJGnViOmiq0hFdbRf8VjozHta0bSmiucaWLNFK0u+h+UHACpFzcY+mnBlhf
-9iNXisIYpRSOob+WYHc8
-=OX/+
+iQIcBAEBCAAGBQJPL9OTAAoJEHfx8XVYajsfXqUP/1R9vzuKIEpd0VXHOhCeA5Pu
+ZJUfFo5m3o8LP2wyyCWkOzkhzDp4jK33TTFsLy8zZ1zZ/iKK5F6ehhHftCdey2VU
+RT1pXIA/iOst5t7dvGf/USvXCsnAmUL8k92EwRRHXHSDxyCy7+bky7TSVXIwfFXh
+wol2iJ1FGF96mkwbqRkqnAiPCTKM3+gHXDj/2gZatCXc49OovrZwtCRY1A4UWGUz
+s32/bE6iLLtsJoOT/irYQjz4TvAB41sgDOKhAO/jSWjrILY22vT9zy8yIkbpuBaS
+g+EEAHt8onyoeMzruHisnzw53T8nXylHJngoR1sYlzpLsqaKMPcATC1CaTz+Rzfd
+OEsUZ9sBpFAeogKxVT1qnRAyTeLfY2JKpSBnySzMGSlO5eTTuWSEPOlSx6YyXxCk
+M2+sDKpyQi3B5+oGPwc/v0LBarIH7eCZyTmzbav+vZ+ihkMwt06ZB9nHcpJuOLeN
+EDFi4amTM1nmPRchvyMz49A5aGgcAcrwjiJIUnj63CUeG1AgsobB8aqNX6GXfsmA
+Z9HSXpoCj3y4jWnKFEuf8vBt1nH46qAgzdAAIZRkCmdFoOFTFgXU+iJxo6io/2Tj
+NFg4XUB9pDOVgB9ypO5rfXOnn6G9WlJ/czwftgfQo4mn960YCpE7z7i0UZT9yHFc
+01bECdH141ZOQpFuDRc1
+=Ug82
 -----END PGP SIGNATURE-----
diff --git a/mail-mta/postfix/postfix-2.9.0-r1.ebuild b/mail-mta/postfix/postfix-2.9.0-r1.ebuild
new file mode 100644
index 000000000000..cf6b3bcb347a
--- /dev/null
+++ b/mail-mta/postfix/postfix-2.9.0-r1.ebuild
@@ -0,0 +1,309 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/mail-mta/postfix/postfix-2.9.0-r1.ebuild,v 1.1 2012/02/06 13:20:05 eras Exp $
+
+EAPI=4
+
+inherit eutils multilib ssl-cert toolchain-funcs flag-o-matic pam versionator
+
+MY_PV="${PV/_rc/-RC}"
+MY_SRC="${PN}-${MY_PV}"
+MY_URI="ftp://ftp.porcupine.org/mirrors/postfix-release/official"
+VDA_PV="2.8.5"
+VDA_P="${PN}-vda-v10-${VDA_PV}"
+RC_VER="2.6"
+
+DESCRIPTION="A fast and secure drop-in replacement for sendmail."
+HOMEPAGE="http://www.postfix.org/"
+SRC_URI="${MY_URI}/${MY_SRC}.tar.gz
+	vda? ( http://vda.sourceforge.net/VDA/${VDA_P}.patch ) "
+
+LICENSE="IBM"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
+IUSE="+berkdb cdb doc dovecot-sasl hardened ldap ldap-bind memcached mbox mysql nis pam postgres sasl selinux sqlite ssl vda"
+
+DEPEND=">=dev-libs/libpcre-3.4
+	dev-lang/perl
+	berkdb? ( >=sys-libs/db-3.2 )
+	cdb? ( || ( >=dev-db/tinycdb-0.76 >=dev-db/cdb-0.75-r1 ) )
+	ldap? ( net-nds/openldap )
+	ldap-bind? ( net-nds/openldap[sasl] )
+	mysql? ( virtual/mysql )
+	pam? ( virtual/pam )
+	postgres? ( dev-db/postgresql-base )
+	sasl? (  >=dev-libs/cyrus-sasl-2 )
+	sqlite? ( dev-db/sqlite:3 )
+	ssl? ( >=dev-libs/openssl-0.9.6g )"
+
+RDEPEND="${DEPEND}
+	dovecot-sasl? ( net-mail/dovecot )
+	memcached? ( net-misc/memcached )
+	net-mail/mailbase
+	selinux? ( sec-policy/selinux-postfix )
+	!mail-mta/courier
+	!mail-mta/esmtp
+	!mail-mta/exim
+	!mail-mta/mini-qmail
+	!mail-mta/msmtp[mta]
+	!mail-mta/nbsmtp
+	!mail-mta/netqmail
+	!mail-mta/nullmailer
+	!mail-mta/qmail-ldap
+	!mail-mta/sendmail
+	!<mail-mta/ssmtp-2.64-r2
+	!>=mail-mta/ssmtp-2.64-r2[mta]
+	!net-mail/fastforward"
+
+REQUIRED_USE="ldap-bind? ( ldap sasl )"
+
+S="${WORKDIR}/${MY_SRC}"
+
+pkg_setup() {
+	# Add postfix, postdrop user/group (bug #77565)
+	enewgroup postfix 207
+	enewgroup postdrop 208
+	enewuser postfix 207 -1 /var/spool/postfix postfix,mail
+}
+
+src_prepare() {
+	if use vda; then
+		epatch "${DISTDIR}"/${VDA_P}.patch
+	fi
+
+	if ! use berkdb; then
+		epatch "${FILESDIR}/${PN}_no-berkdb.patch"
+	fi
+
+	sed -i -e "/^#define ALIAS_DB_MAP/s|:/etc/aliases|:/etc/mail/aliases|" \
+		src/util/sys_defs.h || die "sed failed"
+
+	# change default paths to better comply with portage standard paths
+	sed -i -e "s:/usr/local/:/usr/:g" conf/master.cf || die "sed failed"
+}
+
+src_configure() {
+	# Make sure LDFLAGS get passed down to the executables.
+	local mycc="-DHAS_PCRE" mylibs="${LDFLAGS} -lpcre -lcrypt -lpthread"
+
+	use pam && mylibs="${mylibs} -lpam"
+
+	if use ldap; then
+		mycc="${mycc} -DHAS_LDAP"
+		mylibs="${mylibs} -lldap -llber"
+	fi
+
+	if use mysql; then
+		mycc="${mycc} -DHAS_MYSQL $(mysql_config --include)"
+		mylibs="${mylibs} $(mysql_config --libs)"
+	fi
+
+	if use postgres; then
+		mycc="${mycc} -DHAS_PGSQL -I$(pg_config --includedir)"
+		mylibs="${mylibs} -lpq -L$(pg_config --libdir)"
+	fi
+
+	if use sqlite; then
+		mycc="${mycc} -DHAS_SQLITE"
+		mylibs="${mylibs} -lsqlite3"
+	fi
+
+	if use ssl; then
+		mycc="${mycc} -DUSE_TLS"
+		mylibs="${mylibs} -lssl -lcrypto"
+	fi
+
+	# broken. and "in other words, not supported" by upstream.
+	# Use inet_protocols setting in main.cf
+	#if ! use ipv6; then
+	#	mycc="${mycc} -DNO_IPV6"
+	#fi
+
+	if use sasl; then
+		if use dovecot-sasl; then
+			# Set dovecot as default.
+			mycc="${mycc} -DDEF_SASL_SERVER=\\\"dovecot\\\""
+		fi
+		if use ldap-bind; then
+			mycc="${mycc} -DUSE_LDAP_SASL"
+		fi
+		mycc="${mycc} -DUSE_SASL_AUTH -DUSE_CYRUS_SASL -I/usr/include/sasl"
+		mylibs="${mylibs} -lsasl2"
+	elif use dovecot-sasl; then
+		mycc="${mycc} -DUSE_SASL_AUTH -DDEF_SERVER_SASL_TYPE=\\\"dovecot\\\""
+	fi
+
+	if ! use nis; then
+		sed -i -e "s|#define HAS_NIS|//#define HAS_NIS|g" \
+			src/util/sys_defs.h || die "sed failed"
+	fi
+
+	if ! use berkdb; then
+		mycc="${mycc} -DNO_DB"
+		if use cdb; then
+			# change default hash format from Berkeley DB to cdb
+			sed -i -e "s/hash/cdb/" src/util/sys_defs.h || die
+		fi
+	fi
+
+	if use cdb; then
+		mycc="${mycc} -DHAS_CDB -I/usr/include/cdb"
+		CDB_LIBS=""
+		# Tinycdb is preferred.
+		if has_version dev-db/tinycdb ; then
+			einfo "Building with dev-db/tinycdb"
+			CDB_LIBS="-lcdb"
+		else
+			einfo "Building with dev-db/cdb"
+			CDB_PATH="/usr/$(get_libdir)"
+			for i in cdb.a alloc.a buffer.a unix.a byte.a ; do
+				CDB_LIBS="${CDB_LIBS} ${CDB_PATH}/${i}"
+			done
+		fi
+		mylibs="${mylibs} ${CDB_LIBS}"
+	fi
+
+	# Robin H. Johnson <robbat2@gentoo.org> 17/Nov/2006
+	# Fix because infra boxes hit 2Gb .db files that fail a 32-bit fstat signed check.
+	mycc="${mycc} -D_FILE_OFFSET_BITS=64 -D_LARGEFILE_SOURCE -D_LARGEFILE64_SOURCE"
+	filter-lfs-flags
+
+	# Workaround for bug #76512
+	if use hardened; then
+		[[ "$(gcc-version)" == "3.4" ]] && replace-flags -O? -Os
+	fi
+
+	# Remove annoying C++ comment style warnings - bug #378099
+	append-flags -Wno-comment
+
+	emake DEBUG="" CC="$(tc-getCC)" OPT="${CFLAGS}" CCARGS="${mycc}" AUXLIBS="${mylibs}" makefiles
+}
+
+src_install () {
+	/bin/sh postfix-install \
+		-non-interactive \
+		install_root="${D}" \
+		config_directory="/etc/postfix" \
+		manpage_directory="/usr/share/man" \
+		readme_directory="/usr/share/doc/${PF}/readme" \
+		html_directory="/usr/share/doc/${PF}/html" \
+		command_directory="/usr/sbin" \
+		mailq_path="/usr/bin/mailq" \
+		newaliases_path="/usr/bin/newaliases" \
+		sendmail_path="/usr/sbin/sendmail" \
+		|| die "postfix-install failed"
+
+	# Fix spool removal on upgrade
+	rm -Rf "${D}"/var
+	keepdir /var/spool/postfix
+
+	# Install rmail for UUCP, closes bug #19127
+	dobin auxiliary/rmail/rmail
+
+	# Provide another link for legacy FSH
+	dosym /usr/sbin/sendmail /usr/$(get_libdir)/sendmail
+
+	# Install qshape tool
+	dobin auxiliary/qshape/qshape.pl
+	doman man/man1/qshape.1
+
+	# Performance tuning tools and their manuals
+	dosbin bin/smtp-{source,sink} bin/qmqp-{source,sink}
+	doman man/man1/smtp-{source,sink}.1 man/man1/qmqp-{source,sink}.1
+
+	# Set proper permissions on required files/directories
+	dodir /var/lib/postfix
+	keepdir /var/lib/postfix
+	fowners postfix:postfix /var/lib/postfix
+	fowners postfix:postfix /var/lib/postfix/.keep_${CATEGORY}_${PN}-${SLOT}
+	fperms 0750 /var/lib/postfix
+	fowners root:postdrop /usr/sbin/post{drop,queue}
+	fperms 02711 /usr/sbin/post{drop,queue}
+
+	keepdir /etc/postfix
+	if use mbox; then
+		mypostconf="mail_spool_directory=/var/spool/mail"
+	else
+		mypostconf="home_mailbox=.maildir/"
+	fi
+	"${D}"/usr/sbin/postconf -c "${D}"/etc/postfix \
+		-e ${mypostconf} || die "postconf failed"
+
+	insinto /etc/postfix
+	newins "${FILESDIR}"/smtp.pass saslpass
+	fperms 600 /etc/postfix/saslpass
+
+	newinitd "${FILESDIR}"/postfix.rc6.${RC_VER} postfix
+	# do not start mysql/postgres unnecessarily - bug #359913
+	use mysql || sed -i -e "s/mysql //" "${D}/etc/init.d/postfix"
+	use postgres || sed -i -e "s/postgresql //" "${D}/etc/init.d/postfix"
+
+	mv "${S}"/examples "${D}"/usr/share/doc/${PF}/
+	mv "${D}"/etc/postfix/{*.default,makedefs.out} "${D}"/usr/share/doc/${PF}/
+
+	dodoc *README COMPATIBILITY HISTORY INSTALL PORTING RELEASE_NOTES*
+
+	pamd_mimic_system smtp auth account
+
+	if use sasl; then
+		insinto /etc/sasl2
+		newins "${FILESDIR}"/smtp.sasl smtpd.conf
+	fi
+
+	# header files
+	insinto /usr/include/postfix
+	doins include/*.h
+
+	# Remove unnecessary files
+	rm -f "${D}"/etc/postfix/{*LICENSE,access,aliases,canonical,generic}
+	rm -f "${D}"/etc/postfix/{header_checks,relocated,transport,virtual}
+}
+
+pkg_preinst() {
+	# default for inet_protocols changed from ipv4 to all in postfix-2.9.
+	# check inet_protocols setting in main.cf and modify if necessary to prevent
+	# performance loss with useless DNS lookups and useless connection attempts.
+	[[ -d ${ROOT}/etc/postfix ]] && {
+	if [[ "$(${D}/usr/sbin/postconf -dh inet_protocols)" != "ipv4" ]]; then
+		if [[ ! -n "$(${D}/usr/sbin/postconf -c ${ROOT}/etc/postfix -nh inet_protocols)" ]];
+		then
+			ewarn "\nCOMPATIBILITY: adding inet_protocols=ipv4 to main.cf."
+			ewarn "That will keep the same behaviour as previous postfix versions."
+			ewarn "Specify inet_protocols explicitly if you want to enable IPv6.\n"
+		else
+			# delete inet_protocols setting. there is already one in /etc/postfix
+			sed -i -e /inet_protocols/d "${D}"/etc/postfix/main.cf || die
+		fi
+	fi
+	}
+}
+
+pkg_postinst() {
+	# Do not install server.{key,pem) SSL certificates if they already exist
+	if use ssl && [[ ! -f "${ROOT}"/etc/ssl/postfix/server.key \
+		&& ! -f "${ROOT}"/etc/ssl/postfix/server.pem ]] ; then
+		SSL_ORGANIZATION="${SSL_ORGANIZATION:-Postfix SMTP Server}"
+		install_cert /etc/ssl/postfix/server
+		chown postfix:mail "${ROOT}"/etc/ssl/postfix/server.{key,pem}
+	fi
+
+	if [[ ! -e /etc/mail/aliases.db ]] ; then
+		ewarn
+		ewarn "You must edit /etc/mail/aliases to suit your needs"
+		ewarn "and then run /usr/bin/newaliases. Postfix will not"
+		ewarn "work correctly without it."
+		ewarn
+	fi
+
+	if [[ $(get_version_component_range 2 ${REPLACING_VERSIONS}) -lt 9 ]]; then
+		elog "If you are using old style postfix instances by symlinking"
+		elog "startup scripts in ${ROOT}etc/init.d, please consider"
+		elog "upgrading your config for postmulti support. For more info:"
+		elog "http://www.postfix.org/MULTI_INSTANCE_README.html"
+		if ! use berkdb; then
+			ewarn "\nPostfix is installed without BerkeleyDB support."
+			ewarn "Please turn on berkdb USE flag for hash or btree table"
+			ewarn "lookup support.\n"
+		fi
+	fi
+}