version bump

Package-Manager: portage-2.2.0_alpha108/cvs/Linux x86_64

4 files changed, 326 insertions, 5 deletions

diff --git a/media-video/ffmpeg/ChangeLog b/media-video/ffmpeg/ChangeLog
index e938204e6446..323798ca06bd 100644
--- a/media-video/ffmpeg/ChangeLog
+++ b/media-video/ffmpeg/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-video/ffmpeg
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/ffmpeg/ChangeLog,v 1.556 2012/05/17 20:45:16 aballier Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/ffmpeg/ChangeLog,v 1.557 2012/05/26 18:19:05 aballier Exp $
+
+*ffmpeg-0.11 (26 May 2012)
+
+  26 May 2012; Alexis Ballier <aballier@gentoo.org> +ffmpeg-0.11.ebuild,
+  +files/ffmpeg-0.11-tests.patch:
+  version bump
 
   17 May 2012; Alexis Ballier <aballier@gentoo.org> ffmpeg-0.10.2.ebuild,
   ffmpeg-0.10.3.ebuild, ffmpeg-9999.ebuild:
diff --git a/media-video/ffmpeg/Manifest b/media-video/ffmpeg/Manifest
index 5cde2e0aacbe..d4ef1463c694 100644
--- a/media-video/ffmpeg/Manifest
+++ b/media-video/ffmpeg/Manifest
@@ -1,18 +1,21 @@
 -----BEGIN PGP SIGNED MESSAGE-----
 Hash: SHA1
 
+AUX ffmpeg-0.11-tests.patch 772 RMD160 4ca2a8d5d0bbf6228f01c9175e3c0284e36ef5ec SHA1 46782b5665638e5eb83d744e799ece8064b29dbe SHA256 c0d42cf1c339b1a09c94fb5b3d627701d2dbda8f5d08f716ddb7226ddb43dbba
 AUX freiordl.patch 611 RMD160 e11a21202acaae10e9c1f626c271c59cd85828db SHA1 3a434ef85cd32d9cf5be4acccdfe6a9d1f98e4bd SHA256 4857bbf856e2014f41d89d0ed0744f7bb3277e5600a877f2b84e0aae571f3dcf
 DIST ffmpeg-0.10.2.tar.bz2 5780204 RMD160 b9dd617935e106e4a1980167bdb7ec8d76d3f2f7 SHA1 743f44a71f93b14c9b26ca2424b0da8457cef4be SHA256 2d990012091c07849843c456eb34ad015a00f45a66cba5be7c81a28e45fb6711
 DIST ffmpeg-0.10.3.tar.bz2 5855494 RMD160 1fa566eb75489ed48faf8f818561399b3d426791 SHA1 4fb6f682dbc1b4ea54178040d515fc3a4c05d415 SHA256 7d1ca0abc80e2f6161e2a48878b62a2e6d0301c231f91e7677b889ef048b931f
+DIST ffmpeg-0.11.tar.bz2 6071924 RMD160 042d199f0fc8733a8c4790f42966186b503812da SHA1 1aa3443c20b1c5d132d1fe06de7cc949a7219edd SHA256 b1662f6f0d61c3070d8c64904c3c912e724f780d4bea7187012b99d4500a042f
 EBUILD ffmpeg-0.10.2.ebuild 8557 RMD160 e0e083ea792e5fcf20680328c2697288d60e01b8 SHA1 303e97a92e80664645e6e1a0b086df8ee2cd0be8 SHA256 ddef6a22679025c5c18da9684e13fd500366cd0352933748af3b027a43bf68d5
 EBUILD ffmpeg-0.10.3.ebuild 8577 RMD160 b6ec22bbf885f9a09e00c0892c7653ee99a32991 SHA1 42e8335b45990c040aa95b7aafd88c93b43f4774 SHA256 1e31987ee5e02b2cad99c963766ede378cb8a402ef945c1d52eb3520a8586960
+EBUILD ffmpeg-0.11.ebuild 8673 RMD160 031100c8121fe10ae431582443f30429498187bb SHA1 d94a21b4be2abaabd4f3b3aaad8bd767aba76eba SHA256 7e3f3990b4b37ef6b35e824dbd6b6d68dbde51e16d41b683ca2bb2136b900528
 EBUILD ffmpeg-9999.ebuild 8635 RMD160 c063aa834846a198c0e101446989cf81c7d4ed30 SHA1 d0e4ca8d5fe5473ad9ed7c9fc58e7f34e4d2700f SHA256 5c556f5439800c112e9a468ed2d8e13ba533f1c3d5c8a80d710731834c1667aa
-MISC ChangeLog 79185 RMD160 d98745addf3fa8d7d1e3348a41348f888feb4124 SHA1 deeb7c252794aa708ce0e4f9ec29b06bd71b6317 SHA256 6fb57ee4807ff8cb6d65429fa793477b5f1a085bdb0f6fb08eb23191f08177af
+MISC ChangeLog 79336 RMD160 24c5b903a88c9628337c40a3c93336e3dbce0be5 SHA1 95bf589a774529daa1c841ebadb15e4a27f30673 SHA256 4ce495b8e6e513c7a3abb3231461e4edae3a420c17c6ce311a5cb0707d4fa9ad
 MISC metadata.xml 3045 RMD160 dc7945d3f121a56d1c09794b47216fb1008a2f50 SHA1 2cc3e2d9ffc5647ce7880a618e26aa4ef029a25d SHA256 bfbce0eed908e9fe97bc59a1dcbf754ad2887c87a720394a1cb32f11d1231a91
 -----BEGIN PGP SIGNATURE-----
 Version: GnuPG v2.0.19 (GNU/Linux)
 
-iEYEARECAAYFAk+1Y2EACgkQvFcC4BYPU0qyiwCdEGu4O8dIlTHl3gT7kI2Cz+i8
-+2cAnRCoAX9etG8qB0CSxVxBzPcCQrlX
-=mOLX
+iEYEARECAAYFAk/BHp8ACgkQvFcC4BYPU0pmtQCcCJ9MGISja3gepLjRZO9sIizN
+AGsAn3et3G4s1QiDW3vgp0OgLy1uyX8S
+=o8Fo
 -----END PGP SIGNATURE-----
diff --git a/media-video/ffmpeg/ffmpeg-0.11.ebuild b/media-video/ffmpeg/ffmpeg-0.11.ebuild
new file mode 100644
index 000000000000..034553db1fe1
--- /dev/null
+++ b/media-video/ffmpeg/ffmpeg-0.11.ebuild
@@ -0,0 +1,287 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-video/ffmpeg/ffmpeg-0.11.ebuild,v 1.1 2012/05/26 18:19:06 aballier Exp $
+
+EAPI="4"
+
+SCM=""
+if [ "${PV#9999}" != "${PV}" ] ; then
+	SCM="git-2"
+	EGIT_REPO_URI="git://git.videolan.org/ffmpeg.git"
+fi
+
+inherit eutils flag-o-matic multilib toolchain-funcs ${SCM}
+
+DESCRIPTION="Complete solution to record, convert and stream audio and video. Includes libavcodec."
+HOMEPAGE="http://ffmpeg.org/"
+if [ "${PV#9999}" != "${PV}" ] ; then
+	SRC_URI=""
+elif [ "${PV%_p*}" != "${PV}" ] ; then # Snapshot
+	SRC_URI="mirror://gentoo/${P}.tar.bz2"
+else # Release
+	SRC_URI="http://ffmpeg.org/releases/${P/_/-}.tar.bz2"
+fi
+FFMPEG_REVISION="${PV#*_p}"
+
+LICENSE="GPL-2 amr? ( GPL-3 ) encode? ( aac? ( GPL-3 ) )"
+SLOT="0"
+if [ "${PV#9999}" = "${PV}" ] ; then
+	KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux"
+fi
+IUSE="
+	aac aacplus alsa amr ass bindist bluray +bzip2 cdio celt cpudetection debug
+	doc +encode faac fontconfig frei0r gnutls gsm +hardcoded-tables
+	ieee1394 jack jpeg2k libv4l modplug mp3 network openal openssl oss pic
+	pulseaudio rtmp schroedinger sdl speex static-libs test theora threads
+	truetype v4l vaapi vdpau vorbis vpx X x264 xvid +zlib
+	"
+
+# String for CPU features in the useflag[:configure_option] form
+# if :configure_option isn't set, it will use 'useflag' as configure option
+CPU_FEATURES="3dnow:amd3dnow 3dnowext:amd3dnowext altivec avx mmx mmxext:mmx2 ssse3 vis neon"
+
+for i in ${CPU_FEATURES}; do
+	IUSE="${IUSE} ${i%:*}"
+done
+
+FFTOOLS="aviocat cws2fws ffeval graph2dot ismindex pktdumper qt-faststart trasher"
+
+for i in ${FFTOOLS}; do
+	IUSE="${IUSE} +fftools_$i"
+done
+
+RDEPEND="
+	alsa? ( media-libs/alsa-lib )
+	amr? ( media-libs/opencore-amr )
+	ass? ( media-libs/libass )
+	bluray? ( media-libs/libbluray )
+	bzip2? ( app-arch/bzip2 )
+	cdio? ( dev-libs/libcdio )
+	celt? ( >=media-libs/celt-0.11.1 )
+	encode? (
+		aac? ( media-libs/vo-aacenc )
+		aacplus? ( media-libs/libaacplus )
+		amr? ( media-libs/vo-amrwbenc )
+		faac? ( media-libs/faac )
+		mp3? ( >=media-sound/lame-3.98.3 )
+		theora? ( >=media-libs/libtheora-1.1.1[encode] media-libs/libogg )
+		x264? ( >=media-libs/x264-0.0.20111017 )
+		xvid? ( >=media-libs/xvid-1.1.0 )
+	)
+	fontconfig? ( media-libs/fontconfig )
+	frei0r? ( media-plugins/frei0r-plugins )
+	gnutls? ( >=net-libs/gnutls-2.12.16 )
+	gsm? ( >=media-sound/gsm-1.0.12-r1 )
+	ieee1394? ( media-libs/libdc1394 sys-libs/libraw1394 )
+	jack? ( media-sound/jack-audio-connection-kit )
+	jpeg2k? ( >=media-libs/openjpeg-1.3-r2 )
+	libv4l? ( media-libs/libv4l )
+	modplug? ( media-libs/libmodplug )
+	openal? ( >=media-libs/openal-1.1 )
+	pulseaudio? ( media-sound/pulseaudio )
+	rtmp? ( >=media-video/rtmpdump-2.2f )
+	sdl? ( >=media-libs/libsdl-1.2.13-r1[audio,video] )
+	schroedinger? ( media-libs/schroedinger )
+	speex? ( >=media-libs/speex-1.2_beta3 )
+	truetype? ( media-libs/freetype:2 )
+	vaapi? ( >=x11-libs/libva-0.32 )
+	vdpau? ( x11-libs/libvdpau )
+	vorbis? ( media-libs/libvorbis media-libs/libogg )
+	vpx? ( >=media-libs/libvpx-0.9.6 )
+	X? ( x11-libs/libX11 x11-libs/libXext x11-libs/libXfixes )
+	zlib? ( sys-libs/zlib )
+	!media-video/qt-faststart
+	!media-libs/libpostproc
+"
+
+DEPEND="${RDEPEND}
+	>=sys-devel/make-3.81
+	doc? ( app-text/texi2html )
+	fontconfig? ( virtual/pkgconfig )
+	gnutls? ( virtual/pkgconfig )
+	ieee1394? ( virtual/pkgconfig )
+	libv4l? ( virtual/pkgconfig )
+	mmx? ( dev-lang/yasm )
+	rtmp? ( virtual/pkgconfig )
+	schroedinger? ( virtual/pkgconfig )
+	test? ( net-misc/wget )
+	truetype? ( virtual/pkgconfig )
+	v4l? ( sys-kernel/linux-headers )
+"
+# faac is license-incompatible with ffmpeg
+REQUIRED_USE="bindist? ( encode? ( !faac !aacplus ) !openssl )
+	libv4l? ( v4l )
+	fftools_cws2fws? ( zlib )
+	test? ( encode zlib )"
+
+S=${WORKDIR}/${P/_/-}
+
+src_prepare() {
+	if [ "${PV%_p*}" != "${PV}" ] ; then # Snapshot
+		export revision=git-N-${FFMPEG_REVISION}
+	fi
+	epatch "${FILESDIR}/${P}-tests.patch"
+}
+
+src_configure() {
+	local myconf="${EXTRA_FFMPEG_CONF}"
+	# Set to --enable-version3 if (L)GPL-3 is required
+	local version3=""
+
+	# enabled by default
+	for i in debug doc network vaapi vdpau zlib; do
+		use ${i} || myconf="${myconf} --disable-${i}"
+	done
+	use bzip2 || myconf="${myconf} --disable-bzlib"
+	use sdl || myconf="${myconf} --disable-ffplay"
+
+	use cpudetection && myconf="${myconf} --enable-runtime-cpudetect"
+	use openssl && myconf="${myconf} --enable-openssl --enable-nonfree"
+	for i in gnutls ; do
+		use $i && myconf="${myconf} --enable-$i"
+	done
+
+	# Encoders
+	if use encode
+	then
+		use mp3 && myconf="${myconf} --enable-libmp3lame"
+		use aac && { myconf="${myconf} --enable-libvo-aacenc" ; version3=" --enable-version3" ; }
+		use amr && { myconf="${myconf} --enable-libvo-amrwbenc" ; version3=" --enable-version3" ; }
+		for i in theora x264 xvid; do
+			use ${i} && myconf="${myconf} --enable-lib${i}"
+		done
+		use aacplus && myconf="${myconf} --enable-libaacplus --enable-nonfree"
+		use faac && myconf="${myconf} --enable-libfaac --enable-nonfree"
+	else
+		myconf="${myconf} --disable-encoders"
+	fi
+
+	# libavdevice options
+	use cdio && myconf="${myconf} --enable-libcdio"
+	use ieee1394 && myconf="${myconf} --enable-libdc1394"
+	use openal && myconf="${myconf} --enable-openal"
+	# Indevs
+	# v4l1 is gone since linux-headers-2.6.38
+	myconf="${myconf} --disable-indev=v4l"
+	use v4l || myconf="${myconf} --disable-indev=v4l2"
+	for i in alsa oss jack ; do
+		use ${i} || myconf="${myconf} --disable-indev=${i}"
+	done
+	use X && myconf="${myconf} --enable-x11grab"
+	use pulseaudio && myconf="${myconf} --enable-libpulse"
+	use libv4l && myconf="${myconf} --enable-libv4l2"
+	# Outdevs
+	for i in alsa oss sdl ; do
+		use ${i} || myconf="${myconf} --disable-outdev=${i}"
+	done
+	# libavfilter options
+	for i in frei0r fontconfig ; do
+		use ${i} && myconf="${myconf} --enable-${i}"
+	done
+	use truetype && myconf="${myconf} --enable-libfreetype"
+	use ass && myconf="${myconf} --enable-libass"
+
+	# Threads; we only support pthread for now but ffmpeg supports more
+	use threads && myconf="${myconf} --enable-pthreads"
+
+	# Decoders
+	use amr && { myconf="${myconf} --enable-libopencore-amrwb --enable-libopencore-amrnb" ; version3=" --enable-version3" ; }
+	for i in bluray celt gsm modplug rtmp schroedinger speex vorbis vpx; do
+		use ${i} && myconf="${myconf} --enable-lib${i}"
+	done
+	use jpeg2k && myconf="${myconf} --enable-libopenjpeg"
+
+	# CPU features
+	for i in ${CPU_FEATURES}; do
+		use ${i%:*} || myconf="${myconf} --disable-${i#*:}"
+	done
+	if use pic ; then
+		myconf="${myconf} --enable-pic"
+		# disable asm code if PIC is required
+		# as the provided asm decidedly is not PIC for x86.
+		use x86 && myconf="${myconf} --disable-asm"
+	fi
+
+	# Try to get cpu type based on CFLAGS.
+	# Bug #172723
+	# We need to do this so that features of that CPU will be better used
+	# If they contain an unknown CPU it will not hurt since ffmpeg's configure
+	# will just ignore it.
+	for i in $(get-flag march) $(get-flag mcpu) $(get-flag mtune) ; do
+		[ "${i}" = "native" ] && i="host" # bug #273421
+		myconf="${myconf} --cpu=${i}"
+		break
+	done
+
+	# Mandatory configuration
+	myconf="
+		--enable-gpl
+		${version3}
+		--enable-postproc
+		--enable-avfilter
+		--disable-stripping
+		${myconf}"
+
+	# cross compile support
+	if tc-is-cross-compiler ; then
+		myconf="${myconf} --enable-cross-compile --arch=$(tc-arch-kernel) --cross-prefix=${CHOST}-"
+		case ${CHOST} in
+			*freebsd*)
+				myconf="${myconf} --target-os=freebsd"
+				;;
+			mingw32*)
+				myconf="${myconf} --target-os=mingw32"
+				;;
+			*linux*)
+				myconf="${myconf} --target-os=linux"
+				;;
+		esac
+	fi
+
+	# Misc stuff
+	use hardcoded-tables && myconf="${myconf} --enable-hardcoded-tables"
+
+	cd "${S}"
+	./configure \
+		--prefix="${EPREFIX}/usr" \
+		--libdir="${EPREFIX}/usr/$(get_libdir)" \
+		--shlibdir="${EPREFIX}/usr/$(get_libdir)" \
+		--mandir="${EPREFIX}/usr/share/man" \
+		--enable-shared \
+		--cc="$(tc-getCC)" \
+		--cxx="$(tc-getCXX)" \
+		--ar="$(tc-getAR)" \
+		--optflags="${CFLAGS}" \
+		--extra-cflags="${CFLAGS}" \
+		--extra-cxxflags="${CXXFLAGS}" \
+		$(use_enable static-libs static) \
+		${myconf} || die
+}
+
+src_compile() {
+	emake
+
+	for i in ${FFTOOLS} ; do
+		if use fftools_$i ; then
+			emake tools/$i
+		fi
+	done
+}
+
+src_install() {
+	emake DESTDIR="${D}" install install-man
+
+	dodoc Changelog README INSTALL
+	dodoc -r doc/*
+
+	for i in ${FFTOOLS} ; do
+		if use fftools_$i ; then
+			dobin tools/$i
+		fi
+	done
+}
+
+src_test() {
+	LD_LIBRARY_PATH="${S}/libpostproc:${S}/libswscale:${S}/libswresample:${S}/libavcodec:${S}/libavdevice:${S}/libavfilter:${S}/libavformat:${S}/libavutil" \
+		emake fate
+}
diff --git a/media-video/ffmpeg/files/ffmpeg-0.11-tests.patch b/media-video/ffmpeg/files/ffmpeg-0.11-tests.patch
new file mode 100644
index 000000000000..6f6ba2cbfa82
--- /dev/null
+++ b/media-video/ffmpeg/files/ffmpeg-0.11-tests.patch
@@ -0,0 +1,25 @@
+From b4d36f60f68b87ee0bea6fb0b5e5437d12f5f894 Mon Sep 17 00:00:00 2001
+From: Alexis Ballier <aballier@gentoo.org>
+Date: Sat, 26 May 2012 14:06:12 -0400
+Subject: [PATCH] Fix tests without fate samples.
+
+---
+ tests/fate/video.mak |    2 +-
+ 1 files changed, 1 insertions(+), 1 deletions(-)
+
+diff --git a/tests/fate/video.mak b/tests/fate/video.mak
+index 8c42332..0e043dc 100644
+--- a/tests/fate/video.mak
++++ b/tests/fate/video.mak
+@@ -97,7 +97,7 @@ fate-dxa-scummvm: CMD = framecrc -i $(SAMPLES)/dxa/scummvm.dxa -pix_fmt rgb24
+ FATE_VIDEO += $(FATE_DXA)
+ fate-dxa: $(FATE_DXA)
+ 
+-FATE_PCM += fate-film-cvid
++FATE_SAMPLES_PCM += fate-film-cvid
+ fate-film-cvid: CMD = framecrc -i $(SAMPLES)/film/logo-capcom.cpk -an
+ 
+ FATE_FLIC += fate-flic-af11-palette-change
+-- 
+1.7.8.6
+