1 files changed, 40 insertions, 0 deletions
diff --git a/app-arch/cpio/cpio-2.9-r2.ebuild b/app-arch/cpio/cpio-2.9-r2.ebuild
new file mode 100644
index 000000000000..40e203eb3a8c
--- /dev/null
+++ b/app-arch/cpio/cpio-2.9-r2.ebuild
@@ -0,0 +1,40 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-arch/cpio/cpio-2.9-r2.ebuild,v 1.1 2008/06/01 23:04:31 vapier Exp $
+
+inherit eutils
+
+DESCRIPTION="A file archival tool which can also read and write tar files"
+HOMEPAGE="http://www.gnu.org/software/cpio/cpio.html"
+SRC_URI="mirror://gnu/cpio/${P}.tar.bz2"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~sparc-fbsd ~x86 ~x86-fbsd"
+IUSE="nls"
+
+DEPEND=""
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+	epatch "${FILESDIR}"/${P}-CVE-2007-4476.patch #196978
+	epatch "${FILESDIR}"/${P}-gnu-inline.patch #198817
+	epatch "${FILESDIR}"/${P}-restore-perms-owners.patch #218040
+}
+
+src_compile() {
+	econf \
+		$(use_enable nls) \
+		--bindir=/bin \
+		--with-rmt=/usr/sbin/rmt \
+		|| die
+	emake || die
+}
+
+src_install() {
+	emake install DESTDIR="${D}" || die
+	dodoc ChangeLog NEWS README
+	rm -f "${D}"/usr/share/man/man1/mt.1
+	rmdir "${D}"/usr/libexec || die
+}