1 files changed, 56 insertions, 0 deletions
diff --git a/sci-biology/samtools/samtools-0.1.18-r2.ebuild b/sci-biology/samtools/samtools-0.1.18-r2.ebuild
new file mode 100644
index 000000000000..8611ab2e5597
--- /dev/null
+++ b/sci-biology/samtools/samtools-0.1.18-r2.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sci-biology/samtools/samtools-0.1.18-r2.ebuild,v 1.1 2013/01/27 18:09:51 jlec Exp $
+
+EAPI=5
+
+inherit multilib toolchain-funcs
+
+DESCRIPTION="Utilities for SAM (Sequence Alignment/Map), a format for large nucleotide sequence alignments"
+HOMEPAGE="http://samtools.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="examples"
+KEYWORDS="~amd64 ~x86 ~x64-macos"
+
+RDEPEND="sys-libs/ncurses"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+src_prepare() {
+	sed \
+		-e '/^CC/s:=:?=:g' \
+		-e "/^LIBCURSES/s:=.*$:= $(pkg-config --libs ncurses):g" \
+		-e '/^CFLAGS=/s:=:?=:' \
+		-e "s/\$(CC) \$(CFLAGS)/& \$(LDFLAGS)/g" \
+		-e "s/-shared/& \$(LDFLAGS)/" \
+		-i "${S}"/{Makefile,misc/Makefile} || die #358563
+	sed -i 's~/software/bin/python~/usr/bin/env python~' "${S}"/misc/varfilter.py || die
+
+	tc-export CC
+}
+
+src_compile() {
+	emake dylib
+	emake
+}
+
+src_install() {
+	dobin samtools $(find misc -type f -executable)
+
+	dolib.so libbam.so.1
+	dosym libbam.so.1 /usr/$(get_libdir)/libbam.so
+
+	insinto /usr/include/bam
+	doins bam.h bgzf.h faidx.h kaln.h khash.h kprobaln.h kseq.h ksort.h sam.h
+
+	doman ${PN}.1
+	dodoc AUTHORS ChangeLog NEWS
+
+	if use examples; then
+		insinto /usr/share/${PN}
+		doins -r examples
+	fi
+}