1 files changed, 62 insertions, 0 deletions
diff --git a/sci-libs/coinor-bonmin/coinor-bonmin-1.7.4.ebuild b/sci-libs/coinor-bonmin/coinor-bonmin-1.7.4.ebuild
new file mode 100644
index 000000000000..8b2e2cdd2f35
--- /dev/null
+++ b/sci-libs/coinor-bonmin/coinor-bonmin-1.7.4.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sci-libs/coinor-bonmin/coinor-bonmin-1.7.4.ebuild,v 1.1 2014/01/15 19:31:56 bicatali Exp $
+
+EAPI=5
+
+inherit autotools-utils multilib
+
+MYPN=Bonmin
+
+DESCRIPTION="COIN-OR Basic Open-source Nonlinear Mixed INteger programming"
+HOMEPAGE="https://projects.coin-or.org/Bonmin/"
+SRC_URI="http://www.coin-or.org/download/source/${MYPN}/${MYPN}-${PV}.tgz"
+
+LICENSE="CPL-1.0"
+SLOT="0/4"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc examples glpk static-libs test"
+
+RDEPEND="
+	sci-libs/coinor-cbc:=
+	sci-libs/coinor-clp:=
+	sci-libs/ipopt:="
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	doc? ( virtual/latex-base )
+	test? ( sci-libs/coinor-sample )"
+
+S="${WORKDIR}/${MYPN}-${PV}/${MYPN}"
+
+src_configure() {
+	local myeconfargs=(
+		--enable-dependency-linking
+	)
+	autotools-utils_src_configure
+}
+
+src_compile() {
+	autotools-utils_src_compile all $(use doc && echo doc)
+}
+
+src_test() {
+	autotools-utils_src_test test
+}
+
+src_install() {
+	autotools-utils_src_install
+	# add missing include files needed from coinor-couenne and others
+	insinto /usr/include/coin
+	doins \
+		src/Interfaces/BonCurvatureEstimator.hpp \
+		src/Interfaces/BonExitCodes.hpp \
+		src/Algorithms/QuadCuts/BonLinearCutsGenerator.hpp
+
+	use doc && dodoc doc/BONMIN_UsersManual.pdf
+	# already installed
+	rm "${ED}"/usr/share/coin/doc/${MYPN}/{README,AUTHORS,LICENSE} || die
+	if use examples; then
+		insinto /usr/share/doc/${PF}/examples
+		doins -r examples/*
+	fi
+}