blob: 943d27b8c798008e122c801821384a141d1c8815 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
|
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-cdr/brasero/brasero-3.2.0-r1.ebuild,v 1.3 2012/11/07 21:44:04 tetromino Exp $
EAPI="4"
GCONF_DEBUG="no"
GNOME2_LA_PUNT="yes"
inherit autotools eutils gnome2 multilib
DESCRIPTION="Brasero (aka Bonfire) is yet another application to burn CD/DVD for the gnome desktop."
HOMEPAGE="http://projects.gnome.org/brasero/"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86"
IUSE="+css doc +introspection +libburn mp3 nautilus packagekit playlist test tracker"
COMMON_DEPEND="
>=dev-libs/glib-2.29.14:2
>=x11-libs/gtk+-3.0.0:3[introspection?]
>=media-libs/gstreamer-0.10.15:0.10
>=media-libs/gst-plugins-base-0.10:0.10
>=dev-libs/libxml2-2.6:2
>=x11-libs/libnotify-0.6.1
media-libs/libcanberra[gtk3]
x11-libs/libICE
x11-libs/libSM
introspection? ( >=dev-libs/gobject-introspection-0.6.3 )
libburn? (
>=dev-libs/libburn-0.4
>=dev-libs/libisofs-0.6.4 )
nautilus? ( >=gnome-base/nautilus-2.91.90 )
playlist? ( >=dev-libs/totem-pl-parser-2.29.1 )
tracker? ( >=app-misc/tracker-0.12 )"
RDEPEND="${COMMON_DEPEND}
media-libs/gst-plugins-good:0.10
media-plugins/gst-plugins-gconf:0.10
media-plugins/gst-plugins-meta:0.10[mp3?]
x11-themes/hicolor-icon-theme
css? ( media-libs/libdvdcss:1.2 )
!libburn? (
app-cdr/cdrdao
app-cdr/dvd+rw-tools
virtual/cdrtools )
mp3? ( media-libs/gst-plugins-ugly:0.10 )
packagekit? ( app-admin/packagekit-base )"
DEPEND="${COMMON_DEPEND}
app-text/gnome-doc-utils
virtual/pkgconfig
sys-devel/gettext
dev-util/intltool
gnome-base/gnome-common:3
>=dev-util/gtk-doc-am-1.12
doc? ( >=dev-util/gtk-doc-1.12 )
test? ( app-text/docbook-xml-dtd:4.3 )"
# eautoreconf deps
# gnome-base/gnome-common
# dev-util/gtk-doc-am
PDEPEND="gnome-base/gvfs"
pkg_setup() {
G2CONF="${G2CONF}
--disable-scrollkeeper
--disable-caches
--disable-dependency-tracking
$(use_enable !libburn cdrtools)
$(use_enable !libburn cdrkit)
$(use_enable !libburn cdrdao)
$(use_enable !libburn growisofs)
$(use_enable introspection)
$(use_enable libburn libburnia)
$(use_enable nautilus)
$(use_enable playlist)
$(use_enable tracker search)"
DOCS="AUTHORS ChangeLog MAINTAINERS NEWS README"
}
src_prepare() {
# Useful upstream patches, will be in next release
epatch "${FILESDIR}/${P}-brasero-nautilus.desktop.patch"
epatch "${FILESDIR}/${P}-brasero.desktop.patch"
epatch "${FILESDIR}/${P}-drive-not-selected.patch"
# Fix linking against installed libraries, bug #340767, gnome #641233
# requires eautoreconf
epatch "${FILESDIR}/${PN}-2.91.6-build-plugins-against-local-library.patch"
intltoolize --force --copy --automake || die "intltoolize failed"
eautoreconf
gnome2_src_prepare
}
pkg_postinst() {
gnome2_pkg_postinst
echo
elog "If ${PN} doesn't handle some music or video format, please check"
elog "your USE flags on media-plugins/gst-plugins-meta:0.10"
}
|
GitWeb