blob: 0d9b261579d3c1f50fdc8738f575d7a693546f47 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
|
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-misc/strigi/strigi-0.6.4.ebuild,v 1.10 2009/04/11 00:12:35 scarabeus Exp $
EAPI="2"
inherit cmake-utils eutils
DESCRIPTION="Fast crawling desktop search engine with Qt4 GUI"
HOMEPAGE="http://strigi.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~hppa ~ppc ~ppc64 ~x86"
IUSE="+clucene +dbus debug exif fam hyperestraier inotify log +qt4 test"
COMMONDEPEND="
dev-libs/libxml2
virtual/libiconv
>=virtual/poppler-utils-0.8
clucene? ( >=dev-cpp/clucene-0.9.19[-debug] )
dbus? ( sys-apps/dbus
|| ( ( x11-libs/qt-dbus:4
x11-libs/qt-gui:4 )
=x11-libs/qt-4.3*:4[dbus] )
)
exif? ( >=media-gfx/exiv2-0.17 )
fam? ( virtual/fam )
hyperestraier? ( app-text/hyperestraier )
log? ( >=dev-libs/log4cxx-0.10.0 )
qt4? (
|| ( ( x11-libs/qt-core:4
x11-libs/qt-gui:4
x11-libs/qt-dbus:4 )
=x11-libs/qt-4.3*:4[dbus] )
)
!clucene? (
!hyperestraier? (
>=dev-cpp/clucene-0.9.19[-debug]
)
)
"
DEPEND="${COMMONDEPEND}
test? ( dev-util/cppunit )"
RDEPEND="${COMMONDEPEND}"
src_prepare() {
epatch "${FILESDIR}"/${P}-gcc44.patch
}
src_configure() {
# Strigi needs either expat or libxml2.
# However libxml2 seems to be required in both cases, linking to 2 xml parsers
# is just silly, so we forcefully disable linking to expat.
# Enabled: POLLING (only reliable way to check for files changed.)
mycmakeargs="${mycmakeargs}
-DENABLE_EXPAT=OFF -DENABLE_POLLING=ON
-DFORCE_DEPS=ON -DENABLE_CPPUNIT=OFF
-DENABLE_REGENERATEXSD=OFF
$(cmake-utils_use_enable clucene CLUCENE)
$(cmake-utils_use_enable dbus DBUS)
$(cmake-utils_use_enable exif EXIV2)
$(cmake-utils_use_enable fam FAM)
$(cmake-utils_use_enable hyperestraier HYPERESTRAIER)
$(cmake-utils_use_enable inotify INOTIFY)
$(cmake-utils_use_enable log LOG4CXX)
$(cmake-utils_use_enable qt4 DBUS)
$(cmake-utils_use_enable qt4 QT4)"
if ! use clucene && ! use hyperestraier; then
mycmakeargs="${mycmakeargs} -DENABLE_CLUCENE=ON"
fi
cmake-utils_src_configure
}
src_test() {
mycmakeargs="${mycmakeargs} -DENABLE_CPPUNIT=ON"
cmake-utils_src_configure
cmake-utils_src_compile
pushd "${CMAKE_BUILD_DIR}" > /dev/null
ctest --extra-verbose || die "Tests failed."
popd > /dev/null
}
pkg_postinst() {
if ! use clucene && ! use hyperestraier; then
elog "Because you didn't enable any of the supported backends:"
elog "clucene, hyperestraier and sqlite"
elog "clucene support was silently installed."
elog "If you prefer another backend, be sure to reinstall strigi"
elog "and to enable that backend use flag"
fi
}
|
GitWeb