app-office/QtBitcoinTrader/QtBitcoinTrader-9999.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76

# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-office/QtBitcoinTrader/QtBitcoinTrader-9999.ebuild,v 1.5 2014/10/14 19:34:24 alexxy Exp $

EAPI=5

if [[ $PV = *9999* ]]; then
	eclass=git-2
	EGIT_REPO_URI="
		git://github.com/JulyIGHOR/QtBitcoinTrader.git
		https://github.com/JulyIGHOR/QtBitcoinTrader.git"
	EGIT_BRANCH="testing"
	SRC_URI=""
	KEYWORDS=""
else
	eclass=vcs-snapshot
	SRC_URI="https://github.com/JulyIGHOR/QtBitcoinTrader/archive/v${PV}.tar.gz -> ${P}.tar.gz"
	KEYWORDS="~amd64 ~x86"
fi

inherit base fdo-mime qmake-utils ${eclass}

DESCRIPTION="Mt.Gox and BTC-e Bitcoin Trading Client"
HOMEPAGE="https://github.com/JulyIGHOR/QtBitcoinTrader"

LICENSE="GPL-3"
SLOT="0"
IUSE="qt4 qt5"

REQUIRED_USE="
	^^ ( qt4 qt5 )
"

DEPEND="
	dev-libs/openssl
	sys-libs/zlib
	qt4? (
		dev-qt/qtgui:4
		dev-qt/qtmultimedia:4
		dev-qt/qtscript:4
		)
	qt5? (
		dev-qt/qtcore:5
		dev-qt/qtgui:5
		dev-qt/qtnetwork:5
		dev-qt/qtscript:5
		dev-qt/qtwidgets:5
		dev-qt/qtmultimedia:5
	)
"
RDEPEND="${DEPEND}"

src_configure() {
	if use qt4; then
		eqmake4 \
			src/${PN}_Desktop.pro \
			PREFIX="${EPREFIX}/usr" \
			DESKTOPDIR="${EPREFIX}/usr/share/applications" \
			ICONDIR="${EPREFIX}/usr/share/pixmaps"
	elif use qt5; then
		eqmake5 \
			src/${PN}_Desktop.pro \
			PREFIX="${EPREFIX}/usr" \
			DESKTOPDIR="${EPREFIX}/usr/share/applications" \
			ICONDIR="${EPREFIX}/usr/share/pixmaps"
	fi
}

src_install() {
	emake INSTALL_ROOT="${D}" install
	einstalldocs
}

pkg_postinst() {
	fdo-mime_desktop_database_update
}