dev-util/meld/meld-1.7.1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81

# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/meld/meld-1.7.1.ebuild,v 1.2 2013/03/31 04:18:04 tetromino Exp $

EAPI="5"
GCONF_DEBUG="no"
PYTHON_COMPAT=( python2_{6,7} )

inherit eutils python-single-r1 gnome2 multilib

DESCRIPTION="A graphical diff and merge tool"
HOMEPAGE="http://meldmerge.org/"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
IUSE="+highlight gnome"

# FIXME: switch pygtksourceview and gconf-python to python-r1
RDEPEND="
	${PYTHON_DEPS}
	>=dev-python/pygtk-2.14:2[${PYTHON_USEDEP}]
	>=dev-python/pygobject-2.8:2[${PYTHON_USEDEP}]
	dev-python/dbus-python[${PYTHON_USEDEP}]
	dev-python/pycairo[${PYTHON_USEDEP}]
	highlight? ( >=dev-python/pygtksourceview-2.10[${PYTHON_USEDEP}] )
	gnome? ( >=dev-python/gconf-python-2.22:2 )
"
DEPEND="${RDEPEND}
	dev-util/gtk-doc-am
	dev-util/intltool
	app-text/scrollkeeper
"

src_prepare() {
	# fix the prefix so its not in */local/*
	sed -e "s:/usr/local:${EPREFIX}/usr:" \
		-e "s:\$(prefix)/lib:\$(prefix)/$(get_libdir):" \
		-i INSTALL || die "sed 1 failed"

	# don't install anything to /usr/share/doc/meld
	sed -e "s:\$(docdir)/meld:\$(docdir)/${PF}:" \
		-i INSTALL || die "sed 2 failed"

	# don't run scrollkeeper (with the wrong path),
	# leave that to gnome2.eclass #145833
	sed -e '/scrollkeeper-update/s/\t/&#/' \
		-i help/*/Makefile || die "sed 4 failed"

	# don't run update-*-database, leave that to eclass
	sed -e '/update-.*-database/d' \
		-i Makefile || die "sed 5 failed"

	strip-linguas -i "${S}/po"
	local mylinguas=""
	for x in ${LINGUAS}; do
		mylinguas="${mylinguas} ${x}.po"
	done

	if [ -n "${mylinguas}" ]; then
		sed -e "s/PO:=.*/PO:=${mylinguas}/" \
			-i po/Makefile || die "sed 6 failed"
	fi

	# Fix .desktop entry
	sed -e 's/\(MimeType.*\)/\1;/' \
		-i data/meld.desktop.in || die

	gnome2_src_prepare
}

src_configure() {
	:
}

src_install() {
	DOCS="NEWS"
	gnome2_src_install
	python_fix_shebang "${ED}"/usr/bin
	doman meld.1
}