games-strategy/scorched3d/scorched3d-40.1d.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57

# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-strategy/scorched3d/scorched3d-40.1d.ebuild,v 1.5 2007/05/12 09:20:55 beandog Exp $

inherit eutils wxwidgets games

DESCRIPTION="Multi-player tank battle in 3D (OpenGL)"
HOMEPAGE="http://www.scorched3d.co.uk/"
SRC_URI="mirror://sourceforge/${PN}/Scorched3D-${PV}-src.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="amd64 ~ppc x86"
IUSE="mysql"

DEPEND="virtual/opengl
	virtual/glu
	media-libs/libogg
	media-libs/libvorbis
	media-libs/openal
	media-libs/freealut
	media-libs/libsdl
	media-libs/sdl-net
	>=x11-libs/wxGTK-2.6
	>=media-libs/freetype-2
	mysql? ( virtual/mysql )"

S=${WORKDIR}/scorched

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}"/${P}-freealut.patch
}

pkg_setup() {
	games_pkg_setup
	WX_GTK_VER="2.6" need-wxwidgets unicode
}

src_compile() {
	egamesconf \
		--disable-dependency-tracking \
		--datadir="${GAMES_DATADIR}/${PN}" \
		--with-docdir="/usr/share/doc/${PF}" \
		--with-wx-config="${WX_CONFIG}" \
		$(use_with mysql) \
		|| die
	emake || die "emake failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	newicon data/windows/tank.bmp ${PN}.bmp
	make_desktop_entry ${PN} "Scorched 3D" /usr/share/pixmaps/${PN}.bmp
	prepgamesdirs
}