media-libs/libchamplain/libchamplain-0.8.3.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/libchamplain/libchamplain-0.8.3.ebuild,v 1.8 2012/08/14 22:57:01 tetromino Exp $

EAPI="3"
GCONF_DEBUG="no"

inherit gnome2

DESCRIPTION="Clutter based world map renderer"
HOMEPAGE="http://projects.gnome.org/libchamplain/"

LICENSE="LGPL-2"
SLOT="0.8"
KEYWORDS="amd64 x86"
IUSE="debug doc gtk +introspection"

RDEPEND="
	dev-libs/glib:2
	>=x11-libs/cairo-1.4
	net-libs/libsoup-gnome:2.4
	media-libs/clutter:1.0[introspection?]
	media-libs/memphis:0.2[introspection?]
	dev-db/sqlite:3
	gtk? (
		x11-libs/gtk+:2[introspection?]
		media-libs/memphis:0.2[introspection?]
		>=media-libs/clutter-gtk-0.10:0.10 )"
DEPEND="${RDEPEND}
	virtual/pkgconfig
	doc? ( >=dev-util/gtk-doc-1.9 )
	introspection? ( >=dev-libs/gobject-introspection-0.6.3 )"

pkg_setup() {
	DOCS="AUTHORS ChangeLog NEWS README"
	G2CONF="${G2CONF}
		--disable-static
		--enable-memphis
		$(use_enable debug)
		$(use_enable gtk)
		$(use_enable introspection)"
}

src_prepare() {
	gnome2_src_prepare

	# Drop DEPRECATED flags, bug #387335
	sed -i -e 's:-D[A-Z_]*DISABLE_DEPRECATED:$(NULL):g' \
		tidy/Makefile.am tidy/Makefile.in || die
}