media-libs/libquicktime/libquicktime-0.9.7-r1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87

# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/libquicktime/libquicktime-0.9.7-r1.ebuild,v 1.23 2007/07/22 08:53:22 drac Exp $

WANT_AUTOMAKE=latest
WANT_AUTOCONF=latest

inherit libtool eutils autotools

DESCRIPTION="A library based on quicktime4linux with extensions"
HOMEPAGE="http://libquicktime.sourceforge.net"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz
	mirror://gentoo/${PN}-m4-1.tar.bz2"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="alpha amd64 ia64 ppc ppc64 sparc x86"

IUSE="gtk jpeg mmx vorbis png dv ieee1394 X"

RDEPEND="dv? ( media-libs/libdv )
	gtk? ( >=x11-libs/gtk+-2.4.0 )
	png? ( media-libs/libpng )
	jpeg? ( media-libs/jpeg )
	vorbis? ( media-libs/libvorbis )
	ieee1394? ( sys-libs/libavc1394 sys-libs/libraw1394 )
	X? ( x11-libs/libXaw x11-libs/libXv x11-proto/xextproto )
	!virtual/quicktime"
DEPEND="${RDEPEND}
	>=sys-apps/sed-4.0.5
	dev-util/pkgconfig"

PROVIDE="virtual/quicktime"

pkg_setup() {
	if has_version '=x11-base/xorg-x11-6*' && ! built_with_use x11-base/xorg-x11 xv; then
		die "You need xv support to compile ${PN}."
	fi
}

src_unpack() {
	unpack ${A}
	cd "${S}"
	sed -i -e "s:\(have_libavcodec=\)true:\1false:g" configure.ac
	epatch "${FILESDIR}"/${P}-dv.patch
	epatch "${FILESDIR}"/${P}-unrice.patch
	cp "${WORKDIR}"/m4/* m4/
	AT_M4DIR="m4" eautoreconf
	elibtoolize
}

src_compile() {
	econf --enable-shared \
		--enable-static \
		$(use_enable mmx) \
		$(use_enable ieee1394 firewire) \
		$(use_with dv libdv) \
		$(use_with X x) \
		--without-cpuflags || die "econf failed."
	emake || die "emake failed."
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed."

	# Compatibility with software that uses quicktime prefix, but
	# don't do that when building for Darwin/MacOS
	[[ ${CHOST} != *-darwin* ]] && \
		dosym /usr/include/lqt /usr/include/quicktime
}

pkg_preinst() {
	if [[ -d /usr/include/quicktime && ! -L /usr/include/quicktime ]]; then
		elog "For compatibility with other quicktime libraries, ${PN} was"
		elog "going to create a /usr/include/quicktime symlink, but for some"
		elog "reason that is a directory on your system."
		if $(has_version =media-libs/libquicktime-0.9.4); then
			elog "It seems this directory belongs to libquicktime-0.9.4."
			elog "We'll delete that directory now."
			rm -rvf /usr/include/quicktime
	    else
			elog "Please check that is empty, and remove it, or submit a bug"
			elog "telling us which package owns the directory."
			die "/usr/include/quicktime is a directory."
	    fi
	fi
}