net-analyzer/fping/fping-3.1_rc1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-analyzer/fping/fping-3.1_rc1.ebuild,v 1.2 2012/03/07 06:57:33 jer Exp $

EAPI=4

inherit flag-o-matic

MY_P=${P/_rc/-rc}

DESCRIPTION="A utility to ping multiple hosts at once"
HOMEPAGE="http://fping.org/"
SRC_URI="http://fping.org/dist/${MY_P}.tar.gz"

LICENSE="fping"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~amd64-linux ~x86-linux ~x86-macos"
IUSE="ipv6"

S="${WORKDIR}/${MY_P}"

src_prepare() {
	if use ipv6; then
		cp -a "${S}" "${S}-6"
	fi
}

src_configure() {
	default
	if use ipv6; then
		cd "${S}-6"
		append-flags -DIPV6
		econf
	fi
}

src_compile() {
	default
	if use ipv6; then
		cd "${S}-6"
		emake
	fi
}

src_install () {
	dosbin "${S}"/src/${PN}
	fperms 4555 /usr/sbin/fping #241930
	if use ipv6; then
		newsbin "${S}"-6/src/fping fping6
		fperms 4555 /usr/sbin/fping6
	fi
	doman doc/fping.8
	dodoc ChangeLog README
}