net-irc/ptlink-opm/ptlink-opm-1.1.1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59

# Copyright 1999-2004 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-irc/ptlink-opm/ptlink-opm-1.1.1.ebuild,v 1.3 2004/07/17 09:59:05 dholm Exp $

inherit eutils

MY_P="PTlink.OPM${PV}"

DESCRIPTION="PTlink Open Proxy Monitor"
HOMEPAGE="http://www.ptlink.net/"
SRC_URI="mirror://sourceforge/ptlinksoft/${MY_P}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86 ~ppc"
IUSE=""

DEPEND=""

S=${WORKDIR}/${MY_P}

src_unpack() {
	unpack ${A}
	sed -i \
		-e 's:ptopm\.dconf:/etc/ptlink-opm/ptopm.dconf:' \
		-e 's:ptopm\.log:log/ptopm.log:' \
		${S}/src/ptopm.c
}

src_compile() {
	econf || die "econf failed"

	# Now we're going to override the paths setup by configure
	echo "#define BPATH \"/usr/bin\"" > include/path.h
	echo "#define DPATH \"/var/lib/ptlink-opm\"" >> include/path.h

	emake || die "emake failed"
}

src_install() {
	newbin src/ptopm ptlink-opm

	keepdir /var/{lib,log}/ptlink-opm
	dosym /var/log/ptlink-opm /var/lib/ptlink-opm/log

	insinto /etc/ptlink-opm
	newins samples/ptopm.dconf.sample ptopm.dconf

	dodoc CHANGES README

	exeinto /etc/init.d
	newexe ${FILESDIR}/ptlink-opm.init.d ptlink-opm
	insinto /etc/conf.d
	newins ${FILESDIR}/ptlink-opm.conf.d ptlink-opm
}

pkg_postinst() {
	enewuser ptlink-opm
	chown ptlink-opm ${ROOT}/var/{log,lib}/ptlink-opm
}