blob: 399f1754853a1ad546eeda8d77598aca3e4263c6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-process/psmisc/psmisc-22.21-r2.ebuild,v 1.4 2015/04/12 10:08:25 zlogene Exp $
EAPI="4"
inherit eutils
DESCRIPTION="A set of tools that use the proc filesystem"
HOMEPAGE="http://psmisc.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="alpha amd64 arm arm64 hppa ia64 m68k ~mips ppc ppc64 s390 sh sparc x86 ~amd64-linux ~arm-linux ~ia64-linux ~x86-linux"
IUSE="ipv6 nls selinux X"
RDEPEND=">=sys-libs/ncurses-5.7-r7
nls? ( virtual/libintl )
selinux? ( sys-libs/libselinux )"
DEPEND="${RDEPEND}
>=sys-devel/libtool-2.2.6b
nls? ( sys-devel/gettext )"
DOCS="AUTHORS ChangeLog NEWS README"
src_prepare() {
epatch "${FILESDIR}/${P}-fuser_typo_fix.patch"
}
src_configure() {
econf \
$(use_enable selinux) \
--disable-harden-flags \
$(use_enable ipv6) \
$(use_enable nls)
}
src_compile() {
# peekfd is a fragile crap hack #330631
nonfatal emake -C src peekfd || touch src/peekfd{.o,}
emake
}
src_install() {
default
use X || rm -f "${ED}"/usr/bin/pstree.x11
[[ -s ${ED}/usr/bin/peekfd ]] || rm -f "${ED}"/usr/bin/peekfd
[[ -e ${ED}/usr/bin/peekfd ]] || rm -f "${ED}"/usr/share/man/man1/peekfd.1
# fuser is needed by init.d scripts; use * wildcard for #458250
dodir /bin
mv "${ED}"/usr/bin/*fuser "${ED}"/bin || die
}
|
GitWeb
