sci-astronomy/siril: add 1.0.6

Signed-off-by: Mario Haustein <mario.haustein@hrz.tu-chemnitz.de>
Closes: https://github.com/gentoo/gentoo/pull/27872
Signed-off-by: Joonas Niilola <juippis@gentoo.org>

2 files changed, 87 insertions, 0 deletions

diff --git a/sci-astronomy/siril/Manifest b/sci-astronomy/siril/Manifest
index dac4f7ecbbd2..c398922ee657 100644
--- a/sci-astronomy/siril/Manifest
+++ b/sci-astronomy/siril/Manifest
@@ -1,2 +1,3 @@
 DIST siril-1.0.3.tar.bz2 2900334 BLAKE2B 7ec4995ae0f2b66a8575ac6d680dd639bc6d4c429428c2b29eebf8ea1989dae4669bf81b957d4be7889616b09a3b4febb7c1f1da950d36c68bbec152d4cc0041 SHA512 bd8e5d1bba71b0f14f9284a5072e7524d6005c22c55bed45a8e0113456c94ea5ac2a2befbe84c1e827fa410ee9031215343183d2d49f52df681ee4f5dc1a478a
 DIST siril-1.0.5.tar.bz2 2893026 BLAKE2B f8a726962893e90b12c3dfef507652ab7b40ea0be2128ac29d056acb30e827ef35e6671788a8c254d9ea64cc39c8dae00c1e532ed3d6b3a1396ca92da333fe05 SHA512 f2bd614cf14b6b35f458dd75ba4e64db17d051fc9ac36c12e8b1ecdc4c79a19c6427464f3ebb946de80e00d66ed82451f36405c0a7d806332e1b2ce7a835891f
+DIST siril-1.0.6.tar.bz2 2893872 BLAKE2B 1f254dcb774c4bfb14fee4626d40e6eeedf866a7a96dca98502cd84e66b973c2201b1f88e2efcb89ce3401b13bd87a319b2ff11e7ba100d0689c9df429d01957 SHA512 afb5f1768a5884adcc13f2afd6fa386d836df5a1385b916df9df8da1fb464e0c8738123fb485ed92c749e596c744d5252a66444b840223488a0860e9324c4e9d
diff --git a/sci-astronomy/siril/siril-1.0.6.ebuild b/sci-astronomy/siril/siril-1.0.6.ebuild
new file mode 100644
index 000000000000..816f638fd2f1
--- /dev/null
+++ b/sci-astronomy/siril/siril-1.0.6.ebuild
@@ -0,0 +1,86 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson optfeature toolchain-funcs xdg
+
+DESCRIPTION="A free astronomical image processing software"
+HOMEPAGE="https://www.siril.org/"
+
+if [[ ${PV} == "9999" ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://gitlab.com/free-astro/${PN}.git"
+else
+	SRC_URI="https://gitlab.com/free-astro/siril/-/archive/${PV/_/-}/${PN}-${PV/_/-}.tar.bz2"
+	KEYWORDS="~amd64 ~x86"
+	S="${WORKDIR}/${PN}-${PV/_/-}"
+fi
+
+LICENSE="GPL-3+ Boost-1.0"
+SLOT="0"
+IUSE="curl ffmpeg heif jpeg openmp png raw tiff wcs"
+
+DEPEND="
+	>=dev-libs/glib-2.56.0:2
+	>=dev-libs/json-glib-1.2.6
+	>=dev-libs/libconfig-1.4[cxx]
+	>=media-gfx/exiv2-0.25
+	media-libs/librtprocess:=
+	>=media-libs/opencv-4.4.0:=
+	sci-libs/cfitsio
+	sci-libs/fftw:3.0=
+	sci-libs/gsl:=
+	x11-libs/cairo
+	>=x11-libs/gtk+-3.20.0:3
+	curl? ( net-misc/curl )
+	ffmpeg? ( media-video/ffmpeg:= )
+	heif? ( media-libs/libheif )
+	jpeg? ( media-libs/libjpeg-turbo:= )
+	png? ( >=media-libs/libpng-1.6.0 )
+	raw? ( media-libs/libraw )
+	tiff? ( media-libs/tiff )
+	wcs? ( >=sci-astronomy/wcslib-7.7 )
+"
+RDEPEND="
+	${DEPEND}
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-docfiles.patch"
+	"${FILESDIR}/${PN}-$(ver_cut 1-2)-dependencies.patch"
+	"${FILESDIR}/${PN}-$(ver_cut 1-2)-execinfo.patch"
+)
+
+DOCS=( README.md NEWS ChangeLog AUTHORS )
+
+pkg_pretend() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+pkg_setup() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dffms2=false
+		-Dcriterion=false
+		$(meson_use ffmpeg)
+		$(meson_use heif libheif)
+		$(meson_use jpeg libjpeg)
+		$(meson_use openmp)
+		$(meson_use png libpng)
+		$(meson_use raw libraw)
+		$(meson_use tiff libtiff)
+		$(meson_use wcs wcslib)
+		$(usex curl -Denable-libcurl=yes -Denable-libcurl=no)
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+	optfeature "gnuplot support" sci-visualization/gnuplot
+}