dev-util/global: add 6.6.14

Closes: https://bugs.gentoo.org/943798
Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 106 insertions, 0 deletions

diff --git a/dev-util/global/Manifest b/dev-util/global/Manifest
index 21699ebae4ab..7014b5007ff8 100644
--- a/dev-util/global/Manifest
+++ b/dev-util/global/Manifest
@@ -1,3 +1,4 @@
 DIST global-6.6.10.tar.gz 2999863 BLAKE2B 496bac144c935893b29e23bbb1fa4583a5d6d0ab1b8cd818ff592d7259bb6fa832d79666703f2ac179b5fd39095fd922b8861ad73879c5bac299f9b785797c0b SHA512 babbba6a8dc701b401a12d9961cb7510983e44c7f80836d6d0da165fd0d8cc695e20b7c241526839aef2a70c8bbf97727d910ff17c37751ba3438267139b45d1
 DIST global-6.6.13.tar.gz 3003671 BLAKE2B 476c918bad8f6d246ef6b50bcccdee9040ced2b529737e55cd5daa62d2b96d9f5073e1a48d98fe2ec0c2da68b1fb557b0f0f7d7d25eba8c5c5d784dda7b29cb1 SHA512 072d10a6911cef3bf66b5cf17e101f9c1ff29c993bf7db4c99164e5c1b18b4e3ddec31962c77beea2685cb116330919abb9b226d472d0003949a91286d0f1b6d
+DIST global-6.6.14.tar.gz 3012014 BLAKE2B 92972098f0aa4ffa242725d1604138b6898ee4742aacb8334b84f1ad8970a77e374c08da05b38acd75b43f13bf828a4765106df2c3db5b67bea2c0de69466213 SHA512 295b58cdbce3aca1a1cb47f87f6127d31860e07ba6003810f418dd1eff2e389ac78bcdb131d18e48d935cd42351eee7c5474fc2ff3bcd783a48a4ef178e5cad6
 DIST global-6.6.4.tar.gz 2988969 BLAKE2B 784087537094d27c10d1f2bc992e799c35ab6ce3b86e041c31279e6954b203e80676b3158ba95e7957456b75a213d70998aae9047836cd4d388212236f05a081 SHA512 cb4ed451d3aaf47c4c59cdc3f74c97d3171108177d4846b5dac843589710e66d87c9d7bbe080c3770329e8e40105ac52dcafb4609257347593cca4d94711f483
diff --git a/dev-util/global/global-6.6.14.ebuild b/dev-util/global/global-6.6.14.ebuild
new file mode 100644
index 000000000000..02d42e690bfe
--- /dev/null
+++ b/dev-util/global/global-6.6.14.ebuild
@@ -0,0 +1,105 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..13} )
+inherit autotools elisp-common flag-o-matic python-single-r1
+
+DESCRIPTION="Tag system to find an object location in various sources"
+HOMEPAGE="https://www.gnu.org/software/global/global.html"
+SRC_URI="mirror://gnu/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="doc emacs"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	dev-libs/libltdl
+	dev-db/sqlite
+	sys-libs/ncurses
+	$(python_gen_cond_dep '
+		dev-python/pygments[${PYTHON_USEDEP}]
+	')
+	emacs? ( >=app-editors/emacs-23.1:* )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	doc? (
+		app-text/texi2html
+		app-text/texlive-core
+		sys-apps/texinfo
+	)
+"
+
+SITEFILE="50gtags-gentoo.el"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-6.2.9-tinfo.patch"
+)
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	# bug #943798
+	append-cflags -std=gnu17
+
+	local myeconfargs=(
+		--with-python-interpreter="${PYTHON}"
+		--with-sqlite3 # avoid using bundled copy
+		$(use_with emacs lispdir "${SITELISP}/${PN}")
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_compile() {
+	if use doc; then
+		texi2pdf -q -o doc/global.pdf doc/global.texi || die
+		texi2html -o doc/global.html doc/global.texi || die
+	fi
+
+	if use emacs; then
+		elisp-compile *.el
+	fi
+
+	emake
+}
+
+src_install() {
+	default
+
+	rm -rf "${ED}"/var/lib || die
+
+	insinto /etc
+	doins gtags.conf
+
+	insinto /usr/share/vim/vimfiles/plugin
+	doins gtags.vim
+
+	if use emacs; then
+		elisp-install ${PN} *.{el,elc}
+		elisp-site-file-install "${FILESDIR}/${SITEFILE}"
+	fi
+
+	if use doc; then
+		# doc/global.pdf is generated if tex executable (e.g. /usr/bin/tex) is available.
+		[[ -f doc/global.pdf ]] && DOCS+=( doc/global.pdf )
+	fi
+
+	find "${ED}" -name '*.la' -type f -delete || die
+}
+
+pkg_postinst() {
+	use emacs && elisp-site-regen
+}
+
+pkg_postrm() {
+	use emacs && elisp-site-regen
+}