app-editors/texworks: Version bump (v0.6.6)

Package-Manager: Portage-3.0.17, Repoman-3.0.2
Signed-off-by: Mikle Kolyada <zlogene@gentoo.org>

2 files changed, 80 insertions, 0 deletions

diff --git a/app-editors/texworks/Manifest b/app-editors/texworks/Manifest
index 275991343549..eefbc10c4021 100644
--- a/app-editors/texworks/Manifest
+++ b/app-editors/texworks/Manifest
@@ -1 +1,2 @@
 DIST texworks-0.6.5.tar.gz 12140935 BLAKE2B 660606fe2e53d5f2a53e80792efbee368f5f2f402ab974761efc6e11a6f2233fd04672dcc3bf0155a070162616c1d5a9c7313825890e6fb0c6c4dc7af2c62d29 SHA512 d97bb7c3ad7bbb402be80556027ef19076dae91bb9449df2b45d54e89b492e32b8d6f109d1bda9388424af6218866d84a8c296c9bc2ef644cf2fac0d4b24939e
+DIST texworks-0.6.6.tar.gz 12385550 BLAKE2B 241a9e4649e489964c62bd44ca310ffa7d67ebcb6187568dbf5e5b7916d81e3d846f0492a22e35d2c8a57d182d32d129600570e3836c671ae723c236f82d6bd8 SHA512 65300dfbe4e0e2f3b387c868e343f6caeff4602b47afee5a02cce82e0e23b74fe559b4b54fb65d778748de56f38581305a9b3a53d743c957b7dc14ecce4546d1
diff --git a/app-editors/texworks/texworks-0.6.6.ebuild b/app-editors/texworks/texworks-0.6.6.ebuild
new file mode 100644
index 000000000000..f130e1a29fa8
--- /dev/null
+++ b/app-editors/texworks/texworks-0.6.6.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+LUA_COMPAT=( lua5-{1..3} )
+PYTHON_COMPAT=( python{3_7,3_8} )
+
+inherit lua-single python-single-r1 cmake virtualx xdg-utils
+
+DESCRIPTION="A simple interface for working with TeX documents"
+HOMEPAGE="http://tug.org/texworks/"
+SRC_URI="https://github.com/TeXworks/texworks/archive/release-${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="lua python"
+REQUIRED_USE="lua? ( ${LUA_REQUIRED_USE} )
+	python? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="app-text/hunspell:=
+	app-text/poppler[qt5]
+	dev-qt/designer:5
+	dev-qt/qtcore:5
+	dev-qt/qtconcurrent:5
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5
+	dev-qt/qtscript:5[scripttools]
+	lua? ( ${LUA_DEPS} )
+	python? ( ${PYTHON_DEPS} ) "
+
+DEPEND="dev-qt/linguist-tools:5
+	${RDEPEND}"
+
+BDEPEND="virtual/pkgconfig"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.6.5-cmake_lua_version.patch
+)
+
+S=${WORKDIR}/${PN}-release-${PV}
+
+RESTRICT="!test? ( test )"
+
+CMAKE_REMOVE_MODULES_LIST="FindLua"
+
+pkg_setup() {
+	use lua && lua-single_pkg_setup
+	python-single-r1_pkg_setup
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-Wno-dev
+		-DPREFER_BUNDLED_SYNCTEX=ON
+		-DWITH_LUA=$(usex lua ON OFF)
+		-DWITH_PYTHON=$(usex python ON OFF)
+		-DTeXworks_PLUGIN_DIR="/usr/$(get_libdir)/texworks"
+		-DTeXworks_DOCS_DIR="/share/doc/${PF}"
+		-DQTPDF_VIEWER=ON
+		-DBUILD_SHARED_LIBS=ON
+		-DBUILD_SHARED_PLUGINS=ON
+	)
+	use lua && mycmakeargs+=( -DLUA_VERSION="$(lua_get_version)" )
+	cmake_src_configure
+}
+
+src_test() {
+	virtx default_src_test
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+}