app-admin/diamond-4.0.515.20180315: bump for py3 support

Package-Manager: Portage-2.3.76, Repoman-2.3.16
Signed-off-by: Fabian Groffen <grobian@gentoo.org>

3 files changed, 91 insertions, 3 deletions

diff --git a/app-admin/diamond/Manifest b/app-admin/diamond/Manifest
index 3cfe85f452f6..d73e7280e28d 100644
--- a/app-admin/diamond/Manifest
+++ b/app-admin/diamond/Manifest
@@ -1,2 +1,3 @@
+DIST python-diamond-4.0.515.20180315.tar.gz 673084 BLAKE2B a1903368fc1b540028038a401cf68c772fd04d5d19dc7e3773c9909c1b4ccb5eeba6e184fd46da83e9c0234675e51331a4097a810191ac1a18242cbf96b0456c SHA512 8497362659fa43e4c72bd28d03ff9d8b3ccaab3901cb5e0e1e252340b70a6ab0972db37863daad0d7dd8e92c83a82f9ec151af07ca5fdafee0d214a7061b5f9f
 DIST python-diamond-4.0.515.tar.gz 620337 BLAKE2B 8df675f7e91086dc6e98166c3f6c25c7837bd53f720cd0dfdf05a1dd2954aaa190bfe8844d01acfcdf46d5be917c29c0e231f2b433a648d6dcc1f34e2c617d91 SHA512 8516e46f4f75400a55ca0127789344a897fc7cd6c10f0f8379d30db58de5a09ae676e340371cdf1a0c9ca894fd355699a1a0f430bfad148e32157d5eb97aaef5
 DIST python-diamond-4.0.tar.gz 491433 BLAKE2B ddf678b758b046b80fe347c2cd8ce2fec46f03e65415735d88969d66dc05466730e52df9e8efc27e3a3bff13862c4efcc393de6d05ec6d350e3912a706d298cb SHA512 c4a6e63bdc55f9e0ac2fbf3b644be91662635c08ecc864dfaaebf2fe62fb45609c099da63efd93ed498d2dc9e95bbcb64be09f715e21d59b30bce958a96dc56b
diff --git a/app-admin/diamond/diamond-4.0.515.20180315.ebuild b/app-admin/diamond/diamond-4.0.515.20180315.ebuild
new file mode 100644
index 000000000000..8882dd7f46ca
--- /dev/null
+++ b/app-admin/diamond/diamond-4.0.515.20180315.ebuild
@@ -0,0 +1,86 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+if [[ ${PV} = 9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/python-diamond/Diamond.git"
+	S=${WORKDIR}/diamond-${PV}
+else
+	GHASH=0f3eb04327d6d3ed5e53a9967d6c9d2c09714a47
+	SRC_URI="https://github.com/python-diamond/Diamond/archive/${GHASH}.tar.gz -> python-diamond-${PV}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~x86 ~amd64-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+	S=${WORKDIR}/Diamond-${GHASH}
+fi
+
+PYTHON_COMPAT=( python3_6 )
+
+inherit distutils-r1 prefix
+
+DESCRIPTION="Python daemon that collects and publishes system metrics"
+HOMEPAGE="https://github.com/python-diamond/Diamond"
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="test mongo mysql snmp redis"
+
+RDEPEND="dev-python/configobj
+	dev-python/setproctitle
+	mongo? ( dev-python/pymongo )
+	mysql? ( dev-python/mysql-python )
+	snmp? ( dev-python/pysnmp )
+	redis? ( dev-python/redis-py )
+	!kernel_linux? ( >=dev-python/psutil-3 )"
+DEPEND="${RDEPEND}
+	test? (
+		dev-python/mock
+		dev-python/pysnmp
+	)"
+
+src_prepare() {
+	# adjust for Prefix
+	hprefixify bin/diamond*
+
+	# fix the version (not set in GitHub archive)
+	sed -i -e "s/__VERSIONTOKENHERE__/${PV}/" src/diamond/version.py.tmpl || die
+	# fix psutil usage
+	sed -i -e 's/psutil\.network_io_counters/psutil.net_io_counters/' \
+		src/collectors/network/network.py || die
+	# fix symlink out of place
+	rm README.md || die
+	cp docs/index.md README.md || die
+
+	# this module isn't Python3 yet (lambda), if you use this and have a
+	# fix, let me know
+	rm src/diamond/handler/rrdtool.py || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	# don't want to depend on docker for just this
+	mv src/collectors/docker_collector/test/{test,no}docker_collector.py || die
+	# fails on binding ports
+	mv src/collectors/portstat/tests/{test,no}_portstat.py || die
+	"${PYTHON}" ./test.py || die "Tests fail with ${PYTHON}"
+}
+
+python_install() {
+	export VIRTUAL_ENV=1
+	distutils-r1_python_install
+	python_optimize
+	mv "${ED}"/usr/etc "${ED}"/ || die
+	rm "${ED}"/etc/diamond/*.windows  # won't need these
+	sed -i \
+		-e '/pid_file =/s:/var/run:/run:' \
+		"${ED}"/etc/diamond/diamond.conf.example || die
+	hprefixify "${ED}"/etc/diamond/diamond.conf.example
+}
+
+src_install() {
+	distutils-r1_src_install
+	newinitd "${FILESDIR}"/${PN}.initd ${PN}
+	newconfd "${FILESDIR}"/${PN}.confd ${PN}
+	keepdir /var/log/diamond
+}
diff --git a/app-admin/diamond/diamond-9999.ebuild b/app-admin/diamond/diamond-9999.ebuild
index 57df76bc0741..73f30e45464a 100644
--- a/app-admin/diamond/diamond-9999.ebuild
+++ b/app-admin/diamond/diamond-9999.ebuild
@@ -1,7 +1,7 @@
-# Copyright 1999-2017 Gentoo Foundation
+# Copyright 1999-2019 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=5
+EAPI=6
 
 if [[ ${PV} = 9999* ]]; then
 	inherit git-r3
@@ -13,7 +13,7 @@ else
 	S=${WORKDIR}/Diamond-${PV}
 fi
 
-PYTHON_COMPAT=( python2_7 )
+PYTHON_COMPAT=( python3_6 )
 
 inherit distutils-r1 prefix
 
@@ -55,6 +55,7 @@ python_test() {
 python_install() {
 	export VIRTUAL_ENV=1
 	distutils-r1_python_install
+	python_optimize
 	mv "${ED}"/usr/etc "${ED}"/ || die
 	rm "${ED}"/etc/diamond/*.windows  # won't need these
 	sed -i \