app-admin/mongo-tools: bump to 3.0.15 and 3.2.15

Package-Manager: Portage-2.3.6, Repoman-2.3.2
Closes: https://github.com/gentoo/gentoo/pull/5062

1 files changed, 56 insertions, 0 deletions

diff --git a/app-admin/mongo-tools/mongo-tools-3.0.15.ebuild b/app-admin/mongo-tools/mongo-tools-3.0.15.ebuild
new file mode 100644
index 000000000000..221680a90f84
--- /dev/null
+++ b/app-admin/mongo-tools/mongo-tools-3.0.15.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+
+inherit eutils
+
+MY_PV=${PV/_rc/-rc}
+MY_P=${PN}-r${MY_PV}
+
+DESCRIPTION="A high-performance, open source, schema-free document-oriented database"
+HOMEPAGE="http://www.mongodb.org"
+SRC_URI="https://github.com/mongodb/mongo-tools/archive/r${MY_PV}.tar.gz -> mongo-tools-${MY_PV}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="sasl ssl"
+
+# Maintainer note:
+# openssl DEPEND constraint, see:
+# https://github.com/mongodb/mongo-tools/issues/11
+
+RDEPEND="!<dev-db/mongodb-3.0.0"
+DEPEND="${RDEPEND}
+	dev-lang/go:=
+	sasl? ( dev-libs/cyrus-sasl )
+	ssl? ( dev-libs/openssl )"
+
+S=${WORKDIR}/${MY_P}
+
+src_prepare() {
+	# ensure we use bash wrt #582906
+	sed -e 's@/bin/sh@/bin/bash@g' -i build.sh || die
+
+	# see #608292
+	epatch "${FILESDIR}/${PN}-3.2.10-pie.patch"
+}
+
+src_compile() {
+	local myconf
+
+	if use sasl; then
+	  myconf="${myconf} sasl"
+	fi
+
+	if use ssl; then
+	  myconf="${myconf} ssl"
+	fi
+
+	./build.sh ${myconf} || die "build failed"
+}
+
+src_install() {
+	dobin bin/*
+}