app-admin/ansible-base: 2.10.3 bump

Package-Manager: Portage-3.0.8, Repoman-3.0.2
Signed-off-by: Matthew Thode <prometheanfire@gentoo.org>

2 files changed, 78 insertions, 0 deletions

diff --git a/app-admin/ansible-base/Manifest b/app-admin/ansible-base/Manifest
index 9fddfe32080b..43097ea86806 100644
--- a/app-admin/ansible-base/Manifest
+++ b/app-admin/ansible-base/Manifest
@@ -1 +1,2 @@
 DIST ansible-base-2.10.2.tar.gz 6023200 BLAKE2B 80abfa3fab56d3f997cbe90b557ffd5004b216709d6ba2c6d50ea0fb7a2e5a2ad49ce83bfc7a17054582e786f53ce29814d8b5a3fc2408a1e729b1647619080c SHA512 2ee60303841e88d3451ddbcc4c18473d3a37253873406b0783816b1bbf9d8404599ebed12bac7c7f32693314048668b84f3a1c593621c7b8c37a7b48687c769b
+DIST ansible-base-2.10.3.tar.gz 5836841 BLAKE2B 000ee1e369beb450a9a58680030fc7605f62020a28f0ec4634569be0b12ca54c79d0c36a6022895f93b6f8449b8f8483e07590eeea233383490600bbce600aff SHA512 4da2c79c7d990bbe07e136447643484d947e512693194017623deadd88d6556dac67865069182059ae2daf82a13876600dc5472712d6ab6e0556cb829fce3b5b
diff --git a/app-admin/ansible-base/ansible-base-2.10.3.ebuild b/app-admin/ansible-base/ansible-base-2.10.3.ebuild
new file mode 100644
index 000000000000..c30b5bcbb879
--- /dev/null
+++ b/app-admin/ansible-base/ansible-base-2.10.3.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6..9} )
+
+inherit distutils-r1 eutils
+
+DESCRIPTION="Model-driven deployment, config management, and command execution framework"
+HOMEPAGE="https://ansible.com/"
+SRC_URI="https://releases.ansible.com/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86 ~x64-macos"
+IUSE="doc test"
+RESTRICT="test"
+
+RDEPEND="
+	dev-python/paramiko[${PYTHON_USEDEP}]
+	dev-python/jinja[${PYTHON_USEDEP}]
+	dev-python/pyyaml[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	dev-python/cryptography[${PYTHON_USEDEP}]
+	dev-python/httplib2[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+	dev-python/netaddr[${PYTHON_USEDEP}]
+	dev-python/pexpect[${PYTHON_USEDEP}]
+	net-misc/sshpass
+	virtual/ssh
+	!<app-admin/ansible-2.10
+"
+# ansible-2.10 or above is needed for the collections
+DEPEND="
+	!<app-admin/ansible-2.10
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	>=dev-python/packaging-16.6[${PYTHON_USEDEP}]
+	doc? (
+		dev-python/sphinx[${PYTHON_USEDEP}]
+		dev-python/sphinx-notfound-page[${PYTHON_USEDEP}]
+		>=dev-python/pygments-2.4.0[${PYTHON_USEDEP}]
+	)
+	test? (
+		${RDEPEND}
+		dev-python/nose[${PYTHON_USEDEP}]
+		>=dev-python/mock-1.0.1[${PYTHON_USEDEP}]
+		dev-python/passlib[${PYTHON_USEDEP}]
+		dev-python/coverage[${PYTHON_USEDEP}]
+		dev-python/unittest2[${PYTHON_USEDEP}]
+		dev-vcs/git
+	)"
+
+python_compile() {
+	# disable version checks on upgrade
+	export ANSIBLE_SKIP_CONFLICT_CHECK=1
+	distutils-r1_python_compile
+}
+
+python_compile_all() {
+	if use doc; then
+		cd docs/docsite || die
+		export CPUS=4
+		emake -f Makefile.sphinx html
+	fi
+}
+
+python_test() {
+	nosetests -d -w test/units -v --with-coverage --cover-package=ansible --cover-branches || die
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/docsite/_build/html/. )
+	distutils-r1_python_install_all
+
+	dodoc -r examples
+}