app-text/libgxps: Version bump to 0.3.2

Signed-off-by: Matt Turner <mattst88@gentoo.org>

1 files changed, 51 insertions, 0 deletions

diff --git a/app-text/libgxps/libgxps-0.3.2.ebuild b/app-text/libgxps/libgxps-0.3.2.ebuild
new file mode 100644
index 000000000000..051579ab2eaf
--- /dev/null
+++ b/app-text/libgxps/libgxps-0.3.2.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit gnome.org meson xdg-utils
+
+DESCRIPTION="Library for handling and rendering XPS documents"
+HOMEPAGE="https://wiki.gnome.org/Projects/libgxps"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="gtk-doc +introspection jpeg lcms tiff"
+
+RDEPEND="
+	>=app-arch/libarchive-2.8
+	>=dev-libs/glib-2.36:2
+	media-libs/freetype:2
+	media-libs/libpng:0
+	>=x11-libs/cairo-1.10[svg]
+	introspection? ( >=dev-libs/gobject-introspection-1.54:= )
+	jpeg? ( virtual/jpeg:0 )
+	lcms? ( media-libs/lcms:2 )
+	tiff? ( media-libs/tiff:0[zlib] )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	app-text/docbook-xsl-stylesheets
+	dev-libs/libxslt
+	gtk-doc? ( dev-util/gtk-doc )
+	virtual/pkgconfig
+"
+
+# There is no automatic test suite, only an interactive test application
+RESTRICT="test"
+
+src_configure() {
+	local emesonargs=(
+		-Denable-test=false
+		$(meson_use gtk-doc enable-gtk-doc)
+		-Denable-man=true
+		-Ddisable-introspection=$(usex introspection false true)
+		$(meson_use lcms with-liblcms2)
+		$(meson_use jpeg with-libjpeg)
+		$(meson_use tiff with-libtiff)
+	)
+
+	xdg_environment_reset
+	meson_src_configure
+}