app-text/nuspell: allow app-text/ronn-ng instead of app-text/ronn

ronn is going away and is replaced by ronn-ng.

(Revbump because otherwise the package manager has no reason to be
aware that it can be liberated of app-text/ronn and choose app-text/ronn-ng
otherwise, when app-text/ronn gets masked.)

Bug: https://bugs.gentoo.org/770907
Signed-off-by: Sam James <sam@gentoo.org>

1 files changed, 51 insertions, 0 deletions

diff --git a/app-text/nuspell/nuspell-4.0.0-r1.ebuild b/app-text/nuspell/nuspell-4.0.0-r1.ebuild
new file mode 100644
index 000000000000..fa2f0d78afd0
--- /dev/null
+++ b/app-text/nuspell/nuspell-4.0.0-r1.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake
+
+DESCRIPTION="Spell checker library and CLI for complex natural languages"
+HOMEPAGE="https://nuspell.github.io/ https://github.com/nuspell/nuspell"
+SRC_URI="https://github.com/nuspell/nuspell/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-3+"
+SLOT="0/4"  # due to libnuspell.so.4
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+RDEPEND="dev-libs/icu"
+DEPEND="${RDEPEND}
+	test? ( >=dev-cpp/catch-2.3.0:0 )
+	>=dev-libs/boost-1.62[icu,nls]"
+BDEPEND="doc? ( || ( app-text/ronn-ng app-text/ronn ) )"
+
+DOCS=( CHANGELOG.md )
+
+RESTRICT="!test? ( test )"
+
+src_prepare() {
+	rm -R external/Catch2/ || die
+	if ! use test ; then
+		rm -R external/hunspell/ || die
+	fi
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_TESTING=$(usex test)
+	)
+
+	cmake_src_configure
+}
+
+pkg_postinst() {
+	einfo
+	einfo 'Nuspell needs language packs and/or dictionaries to be of use'
+	einfo 'e.g. package app-dicts/myspell-en or one of its siblings.'
+	einfo
+	einfo 'Besides MySpell dictionaries, for other options please'
+	einfo 'see https://nuspell.github.io/#languages-and-users .'
+	einfo
+}