dev-libs/rocm-comgr: strip off ROCM_PATH/include.

On Gentoo ROCM_PATH=/usr. We should not set the header path.

Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: Benda Xu <heroxbd@gentoo.org>

1 files changed, 39 insertions, 0 deletions

diff --git a/dev-libs/rocm-comgr/rocm-comgr-4.3.0-r1.ebuild b/dev-libs/rocm-comgr/rocm-comgr-4.3.0-r1.ebuild
new file mode 100644
index 000000000000..192ddca854e1
--- /dev/null
+++ b/dev-libs/rocm-comgr/rocm-comgr-4.3.0-r1.ebuild
@@ -0,0 +1,39 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake
+
+if [[ ${PV} == *9999 ]] ; then
+	EGIT_REPO_URI="https://github.com/RadeonOpenCompute/ROCm-CompilerSupport/"
+	inherit git-r3
+	S="${WORKDIR}/${P}/lib/comgr"
+else
+	SRC_URI="https://github.com/RadeonOpenCompute/ROCm-CompilerSupport/archive/rocm-${PV}.tar.gz -> ${P}.tar.gz"
+	S="${WORKDIR}/ROCm-CompilerSupport-rocm-${PV}/lib/comgr"
+	KEYWORDS="~amd64"
+fi
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-3.1.0-dependencies.patch
+	"${FILESDIR}"/${PN}-4.3.0_strip-usr-include.patch
+)
+
+DESCRIPTION="Radeon Open Compute Code Object Manager"
+HOMEPAGE="https://github.com/RadeonOpenCompute/ROCm-CompilerSupport"
+LICENSE="MIT"
+SLOT="0/$(ver_cut 1-2)"
+
+RDEPEND=">=dev-libs/rocm-device-libs-${PV}
+	>=sys-devel/llvm-roc-${PV}:="
+DEPEND="${RDEPEND}"
+
+src_configure() {
+	local mycmakeargs=(
+		-DLLD_DIR="${EPREFIX}/usr/lib/llvm/roc/lib/cmake/lld"
+		-DLLVM_DIR="${EPREFIX}/usr/lib/llvm/roc/lib/cmake/llvm"
+		-DClang_DIR="${EPREFIX}/usr/lib/llvm/roc/lib/cmake/clang"
+	)
+	cmake_src_configure
+}