proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 62 insertions, 0 deletions

diff --git a/dev-python/django-compressor/django-compressor-1.4.ebuild b/dev-python/django-compressor/django-compressor-1.4.ebuild
new file mode 100644
index 000000000000..630de33b6a20
--- /dev/null
+++ b/dev-python/django-compressor/django-compressor-1.4.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 python3_{3,4} )
+
+inherit distutils-r1
+
+MY_PN="${PN/-/_}"
+
+DESCRIPTION="Compresses linked and inline javascript or CSS into a single cached file"
+HOMEPAGE="https://github.com/django-compressor/django-compressor"
+SRC_URI="https://github.com/jezdez/django_compressor/archive/${PV}.tar.gz -> ${P}.tar.gz"
+KEYWORDS="amd64 x86"
+IUSE="doc test"
+
+LICENSE="MIT"
+SLOT="0"
+
+RDEPEND="
+	dev-python/django[${PYTHON_USEDEP}]
+	>=dev-python/django-appconf-0.4[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	dev-python/versiontools[${PYTHON_USEDEP}]
+	test? (
+		dev-python/django[${PYTHON_USEDEP}]
+		dev-python/django-discover-runner[${PYTHON_USEDEP}]
+		dev-python/unittest2[${PYTHON_USEDEP}]
+		dev-python/beautifulsoup:4[${PYTHON_USEDEP}]
+		dev-python/html5lib[${PYTHON_USEDEP}]
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/jinja[${PYTHON_USEDEP}]
+		dev-python/lxml[${PYTHON_USEDEP}]
+		dev-python/Coffin[${PYTHON_USEDEP}]
+		dev-python/jingo[${PYTHON_USEDEP}]
+	)"
+DISTUTILS_IN_SOURCE_BUILD=1
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	# https://github.com/django-compressor/django-compressor/issues/531 532
+	pushd "${BUILD_DIR}/lib" > /dev/null || die
+	if python_is_python3; then
+		sed -e s':test_cachekey:_&:' -e s':test_css:_&:g' \
+			 -i compressor/tests/test_base.py || die
+	fi
+	set -- django-admin.py test compressor --settings=compressor.test_settings
+	echo "$@"
+	"$@" || die "Tests failed with ${EPYTHON}"
+	popd > /dev/null || die
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+	distutils-r1_python_install_all
+}