dev-python/http-parser: Use PEP517 build

Signed-off-by: Michał Górny <mgorny@gentoo.org>

1 files changed, 44 insertions, 0 deletions

diff --git a/dev-python/http-parser/http-parser-0.9.0-r1.ebuild b/dev-python/http-parser/http-parser-0.9.0-r1.ebuild
new file mode 100644
index 000000000000..37fe90fe5524
--- /dev/null
+++ b/dev-python/http-parser/http-parser-0.9.0-r1.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit distutils-r1
+
+DESCRIPTION="HTTP request/response parser for python in C"
+HOMEPAGE="
+	https://github.com/benoitc/http-parser/
+	https://pypi.org/project/http-parser/
+"
+SRC_URI="
+	https://github.com/benoitc/http-parser/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~s390 ~sparc ~x86"
+IUSE="examples"
+
+BDEPEND="
+	dev-python/cython[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+python_configure_all() {
+	cython -3 http_parser/parser.pyx || die
+}
+
+python_install_all() {
+	local DOCS=( README.rst )
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+
+	distutils-r1_python_install_all
+}