dev-python/pydantic: Bump to 1.10.5

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 83 insertions, 0 deletions

diff --git a/dev-python/pydantic/Manifest b/dev-python/pydantic/Manifest
index 12fdd2c04516..af52c45443b7 100644
--- a/dev-python/pydantic/Manifest
+++ b/dev-python/pydantic/Manifest
@@ -1 +1,2 @@
 DIST pydantic-1.10.4.gh.tar.gz 898916 BLAKE2B 506a53de6a59f858a7c8fd56cf18f8079d48eb4f6d3ba36d149141a7e2d471819a466bfc1c34c879f5ec90c0de385b2b89d58beb75660da7de282278092e901f SHA512 0566f89518c6f0171c9b49b5fb57e568286ed421d64655dde90a1565d0672bfef6237ed99e4120564ca2562c7e29e08d86db4fcec47e605aaa98d60845688e72
+DIST pydantic-1.10.5.gh.tar.gz 900106 BLAKE2B 6ad75bc0e58b2fea8e0e4c2e23e7b8de39779ec6f1acf05b693201f6ef63e2e6765cac2320ecf694086facdc5d38d9213cead7dc267b53bbec97f11e0f6ff67e SHA512 2f25e5ed3016a64af05674a21dd8dccf3af7e075237b0d078433fa347e58482113e243f9c21ddd55677432d22da692cbb24a682c5af2f09bfdb6fb5cbd53d408
diff --git a/dev-python/pydantic/pydantic-1.10.5.ebuild b/dev-python/pydantic/pydantic-1.10.5.ebuild
new file mode 100644
index 000000000000..7f061956a374
--- /dev/null
+++ b/dev-python/pydantic/pydantic-1.10.5.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( pypy3 python3_{9..11} )
+
+inherit distutils-r1
+
+MY_P=${P/_beta/b}
+DESCRIPTION="Data parsing and validation using Python type hints"
+HOMEPAGE="
+	https://github.com/pydantic/pydantic/
+	https://pypi.org/project/pydantic/
+"
+SRC_URI="
+	https://github.com/pydantic/pydantic/archive/v${PV/_beta/b}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="+native-extensions"
+
+RDEPEND="
+	>=dev-python/typing-extensions-4.1.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	native-extensions? (
+		dev-python/cython[${PYTHON_USEDEP}]
+	)
+	test? (
+		dev-python/hypothesis[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		dev-python/python-dotenv[${PYTHON_USEDEP}]
+		>=dev-python/python-email-validator-1.2.1[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	sed -i -e '/CFLAGS/d' setup.py || die
+	distutils-r1_src_prepare
+}
+
+python_compile() {
+	if [[ ${EPYTHON} == pypy3 ]] || ! use native-extensions; then
+		# do not build extensions on PyPy to workaround
+		# https://github.com/cython/cython/issues/4763
+		local -x SKIP_CYTHON=1
+	fi
+	distutils-r1_python_compile
+}
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	local -x PYTEST_PLUGINS=pytest_mock
+
+	local EPYTEST_DESELECT=(
+		# flaky test, known upstream
+		tests/test_hypothesis_plugin.py::test_can_construct_models_with_all_fields
+		# mypy linting causes regressions with new mypy versions
+		tests/mypy
+	)
+	case ${EPYTHON} in
+		pypy3)
+			EPYTEST_DESELECT+=(
+				tests/test_private_attributes.py::test_private_attribute
+				tests/test_private_attributes.py::test_private_attribute_annotation
+				tests/test_private_attributes.py::test_private_attribute_factory
+				tests/test_private_attributes.py::test_private_attribute_multiple_inheritance
+				tests/test_private_attributes.py::test_underscore_attrs_are_private
+			)
+			;;
+	esac
+	rm -rf pydantic || die
+	epytest
+}