dev-python/trio-websocket: New package, v0.9.2

New dependency of dev-python/selenium.

Signed-off-by: Michał Górny <mgorny@gentoo.org>

1 files changed, 47 insertions, 0 deletions

diff --git a/dev-python/trio-websocket/trio-websocket-0.9.2.ebuild b/dev-python/trio-websocket/trio-websocket-0.9.2.ebuild
new file mode 100644
index 000000000000..c0129ead5201
--- /dev/null
+++ b/dev-python/trio-websocket/trio-websocket-0.9.2.ebuild
@@ -0,0 +1,47 @@
+# Copyright 2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( pypy3 python3_{9..11} )
+
+inherit distutils-r1
+
+DESCRIPTION="WebSocket client and server implementation for Python Trio"
+HOMEPAGE="
+	https://github.com/HyperionGray/trio-websocket/
+	https://pypi.org/project/trio-websocket/
+"
+SRC_URI="
+	https://github.com/HyperionGray/trio-websocket/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	>=dev-python/async_generator-1.10[${PYTHON_USEDEP}]
+	>=dev-python/trio-0.11[${PYTHON_USEDEP}]
+	>=dev-python/wsproto-0.14[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		>=dev-python/pytest-trio-0.5.0[${PYTHON_USEDEP}]
+		dev-python/trustme[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+PATCHES=(
+	# backport from https://github.com/HyperionGray/trio-websocket/pull/138/
+	"${FILESDIR}"/${P}-async-gen.patch
+)
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest -p trio
+}