dev-python/zope-exceptions: New package, dep of zope.testing

1 files changed, 39 insertions, 0 deletions

diff --git a/dev-python/zope-exceptions/zope-exceptions-4.1.0.ebuild b/dev-python/zope-exceptions/zope-exceptions-4.1.0.ebuild
new file mode 100644
index 000000000000..976197f62dec
--- /dev/null
+++ b/dev-python/zope-exceptions/zope-exceptions-4.1.0.ebuild
@@ -0,0 +1,39 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} pypy{,3} )
+inherit distutils-r1
+
+MY_PN=${PN/-/.}
+MY_P=${MY_PN}-${PV}
+
+DESCRIPTION="General purpose exceptions for Zope packages"
+HOMEPAGE="https://pypi.python.org/pypi/zope.exceptions https://github.com/zopefoundation/zope.exceptions"
+SRC_URI="mirror://pypi/${MY_PN::1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="ZPL"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+
+# TODO: extras?
+RDEPEND="dev-python/namespace-zope[${PYTHON_USEDEP}]
+	dev-python/zope-interface[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? ( dev-python/zope-testrunner[${PYTHON_USEDEP}] )"
+
+S=${WORKDIR}/${MY_P}
+
+python_test() {
+	esetup.py test
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	# remove .pth files since dev-python/namespace-zope handles the ns
+	find "${D}" -name '*.pth' -delete || die
+}