dev-python/zope-i18nmessageid: EAPI 8, PEP517, remove namespace dep

Signed-off-by: Michał Górny <mgorny@gentoo.org>

1 files changed, 51 insertions, 0 deletions

diff --git a/dev-python/zope-i18nmessageid/zope-i18nmessageid-5.0.1-r1.ebuild b/dev-python/zope-i18nmessageid/zope-i18nmessageid-5.0.1-r1.ebuild
new file mode 100644
index 000000000000..834931f505be
--- /dev/null
+++ b/dev-python/zope-i18nmessageid/zope-i18nmessageid-5.0.1-r1.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} pypy3 )
+
+inherit distutils-r1
+
+MY_PN=${PN/-/.}
+MY_P=${MY_PN}-${PV}
+DESCRIPTION="Zope support for i18nmessageid (tagging source of i18n strings)"
+HOMEPAGE="
+	https://pypi.org/project/zope.i18nmessageid/
+	https://github.com/zopefoundation/zope.i18nmessageid/
+"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="ZPL"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+
+RDEPEND="
+	dev-python/six[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests unittest
+
+src_prepare() {
+	# strip rdep specific to namespaces
+	sed -i -e "s:'setuptools',::" setup.py || die
+	distutils-r1_src_prepare
+}
+
+python_compile() {
+	distutils-r1_python_compile
+	find "${BUILD_DIR}" -name '*.pth' -delete || die
+}
+
+python_test() {
+	cd "${BUILD_DIR}/install$(python_get_sitedir)" || die
+	# this is needed to keep the tests working while
+	# dev-python/namespace-zope is still installed
+	cat > zope/__init__.py <<-EOF || die
+		__path__ = __import__('pkgutil').extend_path(__path__, __name__)
+	EOF
+	eunittest
+	rm zope/__init__.py || die
+}