dev-ruby/i18n: add 0.8.1

Package-Manager: portage-2.3.3

1 files changed, 48 insertions, 0 deletions

diff --git a/dev-ruby/i18n/i18n-0.8.1.ebuild b/dev-ruby/i18n/i18n-0.8.1.ebuild
new file mode 100644
index 000000000000..ca90001dbac7
--- /dev/null
+++ b/dev-ruby/i18n/i18n-0.8.1.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+USE_RUBY="ruby21 ruby22 ruby23"
+
+RUBY_FAKEGEM_RECIPE_TEST="test"
+RUBY_FAKEGEM_RECIPE_DOC="rdoc"
+RUBY_FAKEGEM_EXTRADOC="CHANGELOG.md README.md"
+
+RUBY_FAKEGEM_GEMSPEC="${PN}.gemspec"
+
+inherit ruby-fakegem versionator
+
+DESCRIPTION="Add Internationalization support to your Ruby application"
+HOMEPAGE="http://rails-i18n.org/"
+SRC_URI="https://github.com/svenfuchs/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="$(get_version_component_range 1-2)"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE=""
+
+ruby_add_bdepend "test? (
+	>=dev-ruby/activesupport-4.2
+	dev-ruby/bundler
+	>=dev-ruby/mocha-0.13
+	dev-ruby/test_declarative )"
+
+each_ruby_test() {
+	case ${RUBY} in
+		*ruby22|*ruby23)
+			versions="4.2 5.0"
+			;;
+		*)
+			versions="4.2"
+			;;
+	esac
+
+	for version in ${versions} ; do
+		if has_version "dev-ruby/activesupport:${version}" ; then
+			einfo "Running tests with activesupport ${version}"
+			BUNDLE_GEMFILE="${S}/gemfiles/Gemfile.rails-${version}.x" ${RUBY} -S bundle exec ${RUBY} -S rake test || die
+		fi
+	done
+}