dev-util/quilt: Version bump and minor fix

Fix download url

Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: Mike Pagano <mpagano@gentoo.org>

3 files changed, 64 insertions, 1 deletions

diff --git a/dev-util/quilt/Manifest b/dev-util/quilt/Manifest
index 380e0647ab06..e2e543d43e71 100644
--- a/dev-util/quilt/Manifest
+++ b/dev-util/quilt/Manifest
@@ -1 +1,2 @@
 DIST quilt-0.66.tar.gz 413069 BLAKE2B 41201d54cb26d4761413365fe19b65bd6971ada1e69198d2edbc346df6a3060ff3af4d80551d68ab4ffe003183bc0a28515ce1d070db95f2b1a04a0680ac4fb2 SHA512 c2cb75c0937612e1e0da25b713acf629b6b5aacbd8254d8bd17220b63c7b8ca996cd9d0315a32d67d54a4a7dc01b212cdda33afaacf3db063da757f1973306f4
+DIST quilt-0.67.tar.gz 543713 BLAKE2B 691b42378a862bfaa8ac9ca042d03d149aaada05894e1d9b92ad4ddf213bf13674c08b72788626ed49c8ccbc792c31e5bc827f8911bf7b0e23733fbc75fca1d1 SHA512 2dcf9396444484e1664f3dc9bf6a024d11fbaac4e984a295b269bab2649e254dafe3dd89d8f79cfaf1c33d2aa80a803ea55eef4debbc1ebc8d3459ecfa52e4ec
diff --git a/dev-util/quilt/quilt-0.66-r1.ebuild b/dev-util/quilt/quilt-0.66-r1.ebuild
index 8d6ead9a83ba..4ae623c1eb56 100644
--- a/dev-util/quilt/quilt-0.66-r1.ebuild
+++ b/dev-util/quilt/quilt-0.66-r1.ebuild
@@ -7,7 +7,7 @@ inherit bash-completion-r1
 
 DESCRIPTION="quilt patch manager"
 HOMEPAGE="https://savannah.nongnu.org/projects/quilt"
-SRC_URI="https://savannah.nongnu.orgdownload/quilt/${P}.tar.gz"
+SRC_URI="https://savannah.nongnu.org/download/quilt/${P}.tar.gz"
 
 LICENSE="GPL-2"
 SLOT="0"
diff --git a/dev-util/quilt/quilt-0.67.ebuild b/dev-util/quilt/quilt-0.67.ebuild
new file mode 100644
index 000000000000..4ae623c1eb56
--- /dev/null
+++ b/dev-util/quilt/quilt-0.67.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="8"
+
+inherit bash-completion-r1
+
+DESCRIPTION="quilt patch manager"
+HOMEPAGE="https://savannah.nongnu.org/projects/quilt"
+SRC_URI="https://savannah.nongnu.org/download/quilt/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-solaris"
+IUSE="emacs graphviz"
+# unresolved test failures
+RESTRICT="test"
+
+RDEPEND="sys-apps/ed
+	dev-util/diffstat
+	graphviz? ( media-gfx/graphviz )
+	elibc_Darwin? ( app-misc/getopt )
+	elibc_SunOS? ( app-misc/getopt )
+	>=sys-apps/coreutils-8.32-r1"
+
+PDEPEND="emacs? ( app-emacs/quilt-el )"
+
+pkg_setup() {
+	use graphviz && return 0
+	echo
+	elog "If you intend to use the folding functionality (graphical illustration of the"
+	elog "patch stack) then you'll need to remerge this package with USE=graphviz."
+	echo
+}
+
+src_prepare() {
+	# Add support for USE=graphviz
+	use graphviz || PATCHES+=( "${FILESDIR}"/${PN}-0.66-no-graphviz.patch )
+	default
+}
+
+src_configure() {
+	[[ ${CHOST} == *-darwin* || ${CHOST} == *-solaris* ]] && \
+		myconf="${myconf} --with-getopt=${EPREFIX}/usr/bin/getopt-long"
+	econf ${myconf}
+}
+
+src_install() {
+	emake BUILD_ROOT="${D}" install
+
+	rm -rf "${ED}"/usr/share/doc/${P}
+	dodoc AUTHORS TODO "doc/README" "doc/README.MAIL" "doc/quilt.pdf"
+
+	rm -rf "${ED}"/etc/bash_completion.d
+	newbashcomp bash_completion ${PN}
+
+	# Remove the compat symlinks
+	rm -rf "${ED}"/usr/share/quilt/compat
+
+	# Remove Emacs mode; newer version is in app-emacs/quilt-el, bug 247500
+	rm -rf "${ED}"/usr/share/emacs
+}