dev-util/android-tools: 9.0.0_p3-r1 revbump for bug 691764

This patch prevents collisions with the gettid() function in glibc-2.30.

Closes: https://bugs.gentoo.org/691764
Package-Manager: Portage-2.3.81, Repoman-2.3.20
Signed-off-by: Zac Medico <zmedico@gentoo.org>

2 files changed, 136 insertions, 0 deletions

diff --git a/dev-util/android-tools/Manifest b/dev-util/android-tools/Manifest
index fb65eeeaa15b..1420ab0f3a98 100644
--- a/dev-util/android-tools/Manifest
+++ b/dev-util/android-tools/Manifest
@@ -14,6 +14,7 @@ DIST android-tools-8.1.0_r1-extras.tar.xz 275952 BLAKE2B 0fd3c536fee6ffbe2cdd432
 DIST android-tools-8.1.0_r1-f2fs-tools.tar.xz 93924 BLAKE2B b8b6c7ba4c3f5309bfcfc91bd57d018d7af66f8dd25590207fd545f0dba02961826bf9963a56c7994feea5db8f9caedfe4fe62870420d9544283f87ec337cfb8 SHA512 de726be0691c58a5093098bd30cfc06c4312c44bec040cbecd594694cb7b38742dafd1f00b08c18f1b70abf56571738eb3e85e612f082e09e51a98980444e069
 DIST android-tools-8.1.0_r1-selinux.tar.xz 3188060 BLAKE2B 8c513d858e8dcaed705975ad61f362d7b1c2252685a63a1ad6035f36b0b402f1857ac5d2635d35ffa10f05b4a2605f30f27dcc5e9d91930eb0656f3ce2da036d SHA512 8799f10b4dba840ecea8f6abb8166c2e137eb3f0d9c5cfb132c661cf17800f2eeaafb1b4ec9e8974fc3324fae99e3654e52397c987faf1d48ab6148152d84f11
 DIST android-tools-8.1.0_r1.ninja.xz 2740 BLAKE2B 34473e33970cefdaf82bbe4524665fd50e6617cf867757ca07cdccc2e7356f43ef4bb455080ef4bac516ddba3c4e4120f0b27306e84725f8d5738a81800e3a53 SHA512 707e0e1c53832a42384e93d363f80007b76f18166b9f3f7d516431410b05319b1acc804daa1fddc218e11feb48de48683efb5203f4fa6d80646dcb1a2953139f
+DIST android-tools-9.0.0_p3-fix-build-with-glibc-2.30.patch 1262 BLAKE2B fa2d3cd31e82dd3b17bb840096c6158f1b117cb12b8b3c6f6c604efd85f880346c04e8e98b17bebd68d56e06cdc126677ad96dbd6214175544a9b93020292956 SHA512 21c2501fa24f59489e656ac5122c906476ad573e63f6dcc88605dafde9d4b8927ea904708caaababd12155153d969d2480aff591d98057859e8b885e94aa126a
 DIST android-tools-9.0.0_r3-arch.tar.xz 7628 BLAKE2B d0d7267d41ade2031d72236c18850ea329afbdd57a2b5bf25837e405d3e66d7aaef5b48996e7aafd4cf6e4543de03ba6549823845e5e8cb35c6d4bc900b8e275 SHA512 534d99fe15b3a3ba4f2a7331662fdb8645424830122cc4c1ff0b44d43059280610389147d4a916c55b3be71ac84d019223c90993cbdae2588f9e9737f0b5606d
 DIST android-tools-9.0.0_r3-core.tar.gz 27484684 BLAKE2B d071adacd5be0341a9114e57242fe51f623773683b9db2735eac9231a77cc22651f09e1c63682e729494aa6409939696a5635afcd5e8a40ec0f75d2784c00ffc SHA512 0edc8b02b57085ce88b39c987284af1c681870594b20ab9ecf4be98a0cfdff2905bc80f5d8eeb7fbc7f4604b800b6f95bc6b2b0321c900bf833313dfcbb2eefb
 DIST android-tools-9.0.0_r3-e2fsprogs.tar.xz 5255616 BLAKE2B 5fe62da70686148d755c60c1cef4b64d80f0c6a891d13a778d2a3209f950b0f9c5b19bf39ed28c5d38d01103ef1ea474133f57b7104a4fdf80eafd8edc17a3a5 SHA512 a9c3c180ddb96f10710a18794b20cfc641d40af3643a1133091127a40c27fa724b6e6f1af8e66fc1e1ca33053e33499b910880eab05979a2de95a0d3d7a79f93
diff --git a/dev-util/android-tools/android-tools-9.0.0_p3-r1.ebuild b/dev-util/android-tools/android-tools-9.0.0_p3-r1.ebuild
new file mode 100644
index 000000000000..973b6de27c5e
--- /dev/null
+++ b/dev-util/android-tools/android-tools-9.0.0_p3-r1.ebuild
@@ -0,0 +1,135 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+PYTHON_COMPAT=( python2_7 python3_{5,6,7} )
+CMAKE_MAKEFILE_GENERATOR="ninja"
+
+inherit flag-o-matic bash-completion-r1 ninja-utils toolchain-funcs cmake-utils python-r1 python-utils-r1
+
+MY_PV="${PV/_p/_r}"
+MY_P=${PN}-${MY_PV}
+
+DESCRIPTION="Android platform tools (adb, fastboot, and mkbootimg)"
+HOMEPAGE="https://android.googlesource.com/platform/system/core.git/"
+# See helper scripts in files/ for creating these tarballs and getting this hash.
+BORINGSSL_SHA1="45210dd4e21ace9d28cb76b3f83303fcdd2efcce"
+GLIBC_GETTID_PATCH="${P}-fix-build-with-glibc-2.30.patch"
+# The ninja file was created by running the ruby script from archlinux by hand and fixing the build vars.
+# No point in depending on something large/uncommon like ruby just to generate a ninja file.
+SRC_URI="https://git.archlinux.org/svntogit/community.git/snapshot/community-0ffb7b41d599741d100a6a00a4bb20e162cd3f90.tar.xz -> ${MY_P}-arch.tar.xz
+	https://github.com/android/platform_system_core/archive/android-${MY_PV}.tar.gz -> ${MY_P}-core.tar.gz
+	https://github.com/google/boringssl/archive/${BORINGSSL_SHA1}.tar.gz -> boringssl-${BORINGSSL_SHA1}.tar.gz
+	mirror://gentoo/${MY_P}-e2fsprogs.tar.xz https://dev.gentoo.org/~zmedico/dist/${MY_P}-e2fsprogs.tar.xz
+	mirror://gentoo/${MY_P}-extras.tar.xz https://dev.gentoo.org/~zmedico/dist/${MY_P}-extras.tar.xz
+	mirror://gentoo/${MY_P}-selinux.tar.xz https://dev.gentoo.org/~zmedico/dist/${MY_P}-selinux.tar.xz
+	mirror://gentoo/${MY_P}-f2fs-tools.tar.xz https://dev.gentoo.org/~zmedico/dist/${MY_P}-f2fs-tools.tar.xz
+	mirror://gentoo/${MY_P}.ninja.xz https://dev.gentoo.org/~zmedico/dist/${MY_P}.ninja.xz
+	https://raw.githubusercontent.com/nmeum/android-tools/8a30dba5768304176fd78aaa131242f6b880f828/patches/core/0022-Use-glibc-s-gettid-when-using-glibc-2.30.patch -> ${GLIBC_GETTID_PATCH}"
+
+# The entire source code is Apache-2.0, except for fastboot which is BSD-2.
+LICENSE="Apache-2.0 BSD-2"
+SLOT="0"
+KEYWORDS="amd64 ~arm x86 ~x86-linux"
+IUSE="python"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+DEPEND="sys-libs/zlib:=
+	dev-libs/libpcre2:=
+	virtual/libusb:1="
+RDEPEND="${DEPEND}
+	python? ( ${PYTHON_DEPS} )"
+DEPEND+="
+	dev-lang/go"
+
+S=${WORKDIR}
+CMAKE_USE_DIR="${S}/boringssl"
+
+unpack_into() {
+	local archive="$1"
+	local dir="$2"
+
+	mkdir -p "${dir}"
+	pushd "${dir}" >/dev/null || die
+	unpack "${archive}"
+	if [[ ${dir} != ./* ]] ; then
+		mv */* ./ || die
+	fi
+	popd >/dev/null
+}
+
+src_unpack() {
+	unpack_into "${MY_P}-arch.tar.xz" arch
+	unpack_into "${MY_P}-core.tar.gz" core
+	unpack_into "${MY_P}-e2fsprogs.tar.xz" ./e2fsprogs
+	unpack_into "${MY_P}-extras.tar.xz" extras
+	unpack_into "${MY_P}-f2fs-tools.tar.xz" ./f2fs-tools
+	unpack_into "${MY_P}-selinux.tar.xz" ./selinux
+	unpack_into boringssl-${BORINGSSL_SHA1}.tar.gz boringssl
+
+	unpack "${MY_P}.ninja.xz"
+	mv "${MY_P}.ninja" "build.ninja" || die
+
+	# Avoid depending on gtest just for its prod headers when boringssl bundles it.
+	ln -s ../../boringssl/third_party/googletest/include/gtest core/include/ || die
+}
+
+src_prepare() {
+	sed -e 's:elseif (${CMAKE_SYSTEM_PROCESSOR} STREQUAL "i386"):\0\n  set(ARCH "x86")\nelseif (${CMAKE_SYSTEM_PROCESSOR} STREQUAL "i586"):' \
+		-i "${S}"/boringssl/CMakeLists.txt || die #668792
+
+	cd "${S}"/core || die
+	eapply "${WORKDIR}"/arch/trunk/fix_build_core.patch
+	eapply "${FILESDIR}"/android-tools-8.1.0_p1-build.patch
+	eapply "${DISTDIR}/${GLIBC_GETTID_PATCH}"
+
+	cd "${S}"/selinux || die
+	eapply "${WORKDIR}"/arch/trunk/fix_build_selinux.patch
+
+	cd "${S}"/e2fsprogs || die
+	eapply "${WORKDIR}"/arch/trunk/fix_build_e2fsprogs.patch
+
+	cd "${S}"/extras
+	sed -e 's|^#include <sys/cdefs.h>$|/*\0*/|' \
+		-e 's|^__BEGIN_DECLS$|#ifdef __cplusplus\nextern "C" {\n#endif|' \
+		-e 's|^__END_DECLS$|#ifdef __cplusplus\n}\n#endif|' \
+		-i ext4_utils/include/ext4_utils/ext4_crypt{,_init_extensions}.h || die #580686
+
+	cd "${S}" || die
+	default
+
+	sed -E \
+		-e "s|^(CC =).*|\\1 $(tc-getCC)|g" \
+		-e "s|^(CXX =).*|\\1 $(tc-getCXX)|g" \
+		-e "s|^(CFLAGS =).*|\\1 ${CFLAGS}|g" \
+		-e "s|^(CPPFLAGS =).*|\\1 ${CPPFLAGS}|g" \
+		-e "s|^(CXXFLAGS =).*|\\1 ${CXXFLAGS}|g" \
+		-e "s|^(LDFLAGS =).*|\\1 ${LDFLAGS}|g" \
+		-e "s|^(PKGVER =).*|\\1 ${MY_PV}|g" \
+		-i build.ninja || die
+
+	# The pregenerated ninja file expects the build/ dir.
+	BUILD_DIR="${CMAKE_USE_DIR}/build"
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	append-lfs-flags
+
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	# We only need a few libs from boringssl.
+	cmake-utils_src_compile libcrypto.a libssl.a
+
+	eninja
+}
+
+src_install() {
+	dobin adb e2fsdroid ext2simg fastboot mke2fs.android
+	dodoc core/adb/*.{txt,TXT} core/fastboot/README.md
+	use python && python_foreach_impl python_doexe core/mkbootimg/mkbootimg
+	newbashcomp arch/trunk/bash_completion.fastboot fastboot
+}