games-puzzle/seatris: port to EAPI 7, games.eclass--

Signed-off-by: Sam James <sam@gentoo.org>

1 files changed, 30 insertions, 13 deletions

diff --git a/games-puzzle/seatris/seatris-0.0.14.ebuild b/games-puzzle/seatris/seatris-0.0.14-r1.ebuild
index d13a963fa7c4..6669683f0a9d 100644
--- a/games-puzzle/seatris/seatris-0.0.14.ebuild
+++ b/games-puzzle/seatris/seatris-0.0.14-r1.ebuild
@@ -1,8 +1,9 @@
-# Copyright 1999-2020 Gentoo Authors
+# Copyright 1999-2021 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=5
-inherit eutils toolchain-funcs games
+EAPI=7
+
+inherit toolchain-funcs
 
 DESCRIPTION="A color ncurses tetris clone"
 HOMEPAGE="http://www.earth.li/projectpurple/progs/seatris.html"
@@ -12,16 +13,28 @@ LICENSE="GPL-2"
 SLOT="0"
 KEYWORDS="~amd64 ~ppc64 ~x86"
 
-RDEPEND="sys-libs/ncurses"
-DEPEND="${DEPEND}
-	virtual/pkgconfig"
+DEPEND="sys-libs/ncurses:="
+RDEPEND="
+	${DEPEND}
+	acct-group/gamestat
+"
+BDEPEND="virtual/pkgconfig"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-as-needed.patch
+)
 
 src_prepare() {
+	default
+
 	sed -i \
-		-e "s:/var/lib/games:${GAMES_STATEDIR}:" \
+		-e "s:/var/lib/games:/var/lib/${PN}:" \
 		scoring.h seatris.6 || die
+}
 
-	epatch "${FILESDIR}"/${P}-as-needed.patch
+src_configure() {
+	tc-export CC
+	econf
 }
 
 src_compile() {
@@ -29,11 +42,15 @@ src_compile() {
 }
 
 src_install() {
-	dogamesbin seatris
+	dobin seatris
+
 	doman seatris.6
 	dodoc ACKNOWLEDGEMENTS HISTORY README TODO example.seatrisrc
-	dodir "${GAMES_STATEDIR}"
-	touch "${D}${GAMES_STATEDIR}/seatris.score"
-	fperms 660 "${GAMES_STATEDIR}/seatris.score"
-	prepgamesdirs
+
+	dodir /var/lib/${PN}
+	touch "${ED}"/var/lib/${PN}/seatris.score || die
+	fperms 660 /var/lib/${PN}/seatris.score
+
+	fowners -R root:gamestat /var/lib/${PN}
+	fperms g+s /usr/bin/${PN}
 }