games-strategy/naev: add 0.9.1

This version add/shifts several dependencies around, openal is no
longer optional and SDL_mixer unused (so is sdl2[sound]).

Also adds openblas, it can use other implementations but upstream
notes that everything else is experimental so let's stick to what's
known to work for now.

Tests (which try to start the game and see if it gets to the main
menu) now fail under Xvfb without mesa[llvm] (0.8.2 didn't), and
would segfault without physfs[zip] (but that's only needed for
meson_overlay.zip which isn't used outside tests). May still be
more needed that tinderboxes may pickup.

Signed-off-by: Ionen Wolkens <ionen@gentoo.org>

2 files changed, 92 insertions, 0 deletions

diff --git a/games-strategy/naev/Manifest b/games-strategy/naev/Manifest
index ae47dea235a7..8e10e46cfb54 100644
--- a/games-strategy/naev/Manifest
+++ b/games-strategy/naev/Manifest
@@ -1 +1,2 @@
 DIST naev-0.8.2-source.tar.gz 394232958 BLAKE2B 2e109636cb1d282bc8236c84ee40b9b96224baf70bf315677b6a02bf9c4c0059d34c5225c31b925a8c66c5995fd9ab8fc022816b66a7e1c174e017e3ebf5e956 SHA512 2ad120639efc13635370bb498d0a4100b2306779cf593e6aecffd331e0f4dec1b8af4729b2c4d484af1be9069d2ac7e47e17ebdc8ce65af878fcff9484f810b0
+DIST naev-0.9.1-source.tar.xz 394715556 BLAKE2B d90cbbc19f10a00060b3ca5ad3f62ef4291e352c7546c11141bd065ebc20efc0f676fb64af1d3dcf43957c62e59819445a5aa0babde579cdb936af136dd538a4 SHA512 d822eb2e22bcb564a0aec38c33205eedacf8399450725fc9709809e0c19a5c426b9a739f9c004691da8bf7b5393d1ed719a36a256a9e3e29d5a0917c9f72bd0f
diff --git a/games-strategy/naev/naev-0.9.1.ebuild b/games-strategy/naev/naev-0.9.1.ebuild
new file mode 100644
index 000000000000..e4bd429a52f1
--- /dev/null
+++ b/games-strategy/naev/naev-0.9.1.ebuild
@@ -0,0 +1,91 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+LUA_COMPAT=( lua5-1 luajit )
+PYTHON_COMPAT=( python3_{8..10} )
+inherit lua-single meson python-any-r1 virtualx xdg
+
+DESCRIPTION="2D space trading and combat game, in a similar vein to Escape Velocity"
+HOMEPAGE="https://naev.org/"
+SRC_URI="https://github.com/naev/naev/releases/download/v${PV}/${P}-source.tar.xz"
+
+LICENSE="
+	GPL-3+ BSD BSD-2 CC-BY-2.0 CC-BY-3.0 CC-BY-4.0 CC-BY-SA-2.0
+	CC-BY-SA-3.0 CC-BY-SA-4.0 CC0-1.0 MIT public-domain"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc"
+REQUIRED_USE="${LUA_REQUIRED_USE}"
+
+RDEPEND="
+	${LUA_DEPS}
+	dev-games/physfs
+	dev-libs/libunibreak:=
+	dev-libs/libxml2
+	media-libs/freetype:2
+	media-libs/libsdl2[X,joystick,opengl,video]
+	media-libs/libvorbis
+	media-libs/openal
+	media-libs/sdl2-image[png,webp]
+	sci-libs/cholmod
+	sci-libs/cxsparse
+	sci-libs/openblas
+	sci-libs/suitesparse
+	sci-mathematics/glpk:=
+	virtual/libintl
+	virtual/opengl"
+DEPEND="
+	${RDEPEND}
+	test? (
+		dev-games/physfs[zip]
+		media-libs/mesa[llvm]
+	)"
+BDEPEND="
+	$(python_gen_any_dep 'dev-python/pyyaml[${PYTHON_USEDEP}]')
+	sys-devel/gettext
+	doc? (
+		app-doc/doxygen[dot]
+		dev-lua/ldoc
+	)"
+
+python_check_deps() {
+	has_version -b "dev-python/pyyaml[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	lua-single_pkg_setup
+	python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+
+	sed -i "s/'lua51'/'lua'/" meson.build || die
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature doc docs_c)
+		$(meson_feature doc docs_lua)
+		$(meson_feature lua_single_target_luajit luajit)
+	)
+
+	meson_src_configure
+}
+
+src_test() {
+	virtx meson_src_test
+}
+
+src_install() {
+	local DOCS=( CHANGELOG Readme.md )
+	meson_src_install
+
+	if use doc; then
+		mv "${ED}"/usr/{doc/naev/{c,lua},share/doc/${PF}} || die
+		rm -r "${ED}"/usr/doc || die
+	fi
+	rm -r "${ED}"/usr/share/doc/naev || die
+}