games-strategy/naev: add 0.9.3

Signed-off-by: Ionen Wolkens <ionen@gentoo.org>

2 files changed, 95 insertions, 0 deletions

diff --git a/games-strategy/naev/Manifest b/games-strategy/naev/Manifest
index 9df0818b37c3..ef66f2b36f61 100644
--- a/games-strategy/naev/Manifest
+++ b/games-strategy/naev/Manifest
@@ -1 +1,2 @@
 DIST naev-0.9.2-source.tar.xz 394764972 BLAKE2B 003a82cfc1fcfb6b597732d2e6691efb0f11867be6d82f7c18bc6c943e9a48dbaa5c126a39740a8d5f7a6e6ac0d3ff2f0b5f6c7c0504787c4d6872543fe99f3d SHA512 2bc31b78ee069d5d5b983e41b456a077101688dee31ad12d54016aa517d6cc3c970c7ff3b4a89b80ab04315e2e227a397c8202e7cbe3ee57cdac6c153032fc29
+DIST naev-0.9.3-source.tar.xz 394876456 BLAKE2B 9648ee9a93a02ec5ace552b25033cae16c38a48a869763bc381050f2724445fd5cf08708053ad4c939cdc99a27244126819e9416bc61d8d6148078eeea26e50e SHA512 150091f10ce05cbd5b2c4c434abe83124db56618b80f727994c135d1331c594406c9e8f03596feddb5739061c866e19b115fd0a86a19ea306cc811bb3dd944aa
diff --git a/games-strategy/naev/naev-0.9.3.ebuild b/games-strategy/naev/naev-0.9.3.ebuild
new file mode 100644
index 000000000000..d13f7615980f
--- /dev/null
+++ b/games-strategy/naev/naev-0.9.3.ebuild
@@ -0,0 +1,94 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+LUA_COMPAT=( lua5-1 luajit )
+PYTHON_COMPAT=( python3_{8..10} )
+inherit lua-single meson python-any-r1 virtualx xdg
+
+DESCRIPTION="2D space trading and combat game, in a similar vein to Escape Velocity"
+HOMEPAGE="https://naev.org/"
+SRC_URI="https://github.com/naev/naev/releases/download/v${PV}/${P}-source.tar.xz"
+S="${WORKDIR}/${PN}-0.9.2" # 0.9.3 tarball uses wrong directory
+
+LICENSE="
+	GPL-3+ BSD BSD-2 CC-BY-2.0 CC-BY-3.0 CC-BY-4.0 CC-BY-SA-2.0
+	CC-BY-SA-3.0 CC-BY-SA-4.0 CC0-1.0 MIT public-domain"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc"
+REQUIRED_USE="${LUA_REQUIRED_USE}"
+
+RDEPEND="
+	${LUA_DEPS}
+	dev-games/physfs
+	dev-libs/libunibreak:=
+	dev-libs/libxml2
+	media-libs/freetype:2
+	media-libs/libsdl2[joystick,opengl,video]
+	media-libs/libvorbis
+	media-libs/openal
+	media-libs/sdl2-image[png,webp]
+	sci-libs/cholmod
+	sci-libs/cxsparse
+	sci-libs/openblas
+	sci-libs/suitesparse
+	sci-mathematics/glpk:=
+	virtual/libintl
+	virtual/opengl"
+DEPEND="
+	${RDEPEND}
+	test? (
+		dev-games/physfs[zip]
+		media-libs/libsdl2[X]
+		media-libs/mesa[llvm]
+	)"
+BDEPEND="
+	$(python_gen_any_dep 'dev-python/pyyaml[${PYTHON_USEDEP}]')
+	sys-devel/gettext
+	doc? (
+		app-doc/doxygen[dot]
+		dev-lua/ldoc
+	)"
+
+python_check_deps() {
+	python_has_version "dev-python/pyyaml[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	lua-single_pkg_setup
+	python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+
+	sed -i "s/'lua51'/'lua'/" meson.build || die
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature doc docs_c)
+		$(meson_feature doc docs_lua)
+		$(meson_feature lua_single_target_luajit luajit)
+	)
+
+	meson_src_configure
+}
+
+src_test() {
+	virtx meson_src_test
+}
+
+src_install() {
+	local DOCS=( CHANGELOG Readme.md )
+	meson_src_install
+
+	if use doc; then
+		dodir /usr/share/doc/${PF}/html
+		mv "${ED}"/usr/{doc/naev/{c,lua},share/doc/${PF}/html} || die
+		rm -r "${ED}"/usr/doc || die
+	fi
+	rm -r "${ED}"/usr/share/doc/naev || die
+}