kde-apps/kwave: 20.08.1 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 88 insertions, 0 deletions

diff --git a/kde-apps/kwave/Manifest b/kde-apps/kwave/Manifest
index e8a65fdeff71..188fbb626a94 100644
--- a/kde-apps/kwave/Manifest
+++ b/kde-apps/kwave/Manifest
@@ -1,2 +1,3 @@
 DIST kwave-20.04.3.tar.xz 6195772 BLAKE2B ddcc0080514bf3b096662d520540f8c5759f56bcd1c25b8f6775260cdb31d017c8fcaaf2e9428275c1345327a902cb43398f85653a03db58fb8976daade2b86c SHA512 f57712472ba19695c77904a804c7dd599cc762e7018fed1d16398746156c25832795215d71aa54b143671342db6a1e442f79bfaed491e16657b820e14ac1306d
 DIST kwave-20.08.0.tar.xz 6868992 BLAKE2B a0d35fe1701d8ed885ebcc6e4d2c284fd88d2f13938bd77f948678ed538ed141bddd43b35335fc1770a5ee42e32b0c4c8208de0dcd1a5c2b9f2940e41a142fe7 SHA512 b8abdf75eddbb158797f246ef7c9a82ad312554a901cf9c02fa8d2a5adbe923caa436eddcf3189cf2c4be89c4194c27a71f17bbb540803eb181e533bb7c90904
+DIST kwave-20.08.1.tar.xz 6868340 BLAKE2B 90ea0a3ad3ba48291578fe42d7c57a34c9b03e6082df0830b6ef27ecb084600ccb3600e524c55f21e093d67242f779d0cbcdf300856979b5162cb054c70f8d03 SHA512 e5d53bdfce2953662ab25edb5c6c3886bb9d4dee6f15c7fb7c09f5a559c9b835bc0e7d6be62eca79c8db298c8e51646a3279c5e200ae3aa2117943d52692b0e1
diff --git a/kde-apps/kwave/kwave-20.08.1.ebuild b/kde-apps/kwave/kwave-20.08.1.ebuild
new file mode 100644
index 000000000000..2f575cfef221
--- /dev/null
+++ b/kde-apps/kwave/kwave-20.08.1.ebuild
@@ -0,0 +1,87 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="forceoptional"
+KFMIN=5.72.0
+QTMIN=5.14.2
+inherit ecm kde.org
+
+DESCRIPTION="Sound editor built on KDE Frameworks 5 that can edit many types of audio files"
+HOMEPAGE="https://kde.org/applications/multimedia/org.kde.kwave"
+
+LICENSE="CC-BY-SA-3.0 CC0-1.0 GPL-2+ LGPL-2+ handbook? ( FDL-1.2 ) opus? ( BSD-2 )"
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="alsa flac mp3 opus oss pulseaudio +qtmedia vorbis"
+
+BDEPEND="
+	sys-devel/gettext
+	handbook? ( || (
+		gnome-base/librsvg
+		virtual/imagemagick-tools[png,svg]
+	) )
+"
+RDEPEND="
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	media-libs/audiofile:=
+	>=sci-libs/fftw-3
+	media-libs/libsamplerate
+	alsa? ( media-libs/alsa-lib )
+	flac? ( media-libs/flac )
+	mp3? (
+		media-libs/id3lib
+		media-libs/libmad
+		|| (
+			media-sound/lame
+			media-sound/toolame
+			media-sound/twolame
+		)
+	)
+	qtmedia? ( >=dev-qt/qtmultimedia-${QTMIN}:5 )
+	opus? (
+		media-libs/libogg
+		media-libs/opus
+	)
+	pulseaudio? ( media-sound/pulseaudio )
+	vorbis? (
+		media-libs/libogg
+		media-libs/libvorbis
+	)
+"
+DEPEND="${RDEPEND}
+	>=dev-qt/qtconcurrent-${QTMIN}:5
+"
+
+DOCS=( AUTHORS CHANGES LICENSES README TODO )
+
+src_configure() {
+	local mycmakeargs=(
+		-DDEBUG=$(usex debug)
+		-DWITH_ALSA=$(usex alsa)
+		-DWITH_DOC=$(usex handbook)
+		-DWITH_FLAC=$(usex flac)
+		-DWITH_MP3=$(usex mp3)
+		-DWITH_OGG_VORBIS=$(usex vorbis)
+		-DWITH_OGG_OPUS=$(usex opus)
+		-DWITH_OSS=$(usex oss)
+		-DWITH_PULSEAUDIO=$(usex pulseaudio)
+		-DWITH_QT_AUDIO=$(usex qtmedia)
+	)
+
+	ecm_src_configure
+}