media-gfx/gnome-photos: version bump 3.24.2 → 3.24.3

Fix support for gegl >=0.3.16. Drop gnome-desktop and replace it with
calls to the thumbnailer service. Translation updates.

Package-Manager: Portage-2.3.8, Repoman-2.3.3

2 files changed, 67 insertions, 0 deletions

diff --git a/media-gfx/gnome-photos/Manifest b/media-gfx/gnome-photos/Manifest
index 5f9c370c1f93..ac8e34bdf49c 100644
--- a/media-gfx/gnome-photos/Manifest
+++ b/media-gfx/gnome-photos/Manifest
@@ -1,2 +1,3 @@
 DIST gnome-photos-3.22.6.tar.xz 962468 SHA256 476a901e4ed3eb9759a5e379937ff91e985f2f796de8d76289580b8b2f7fd86e SHA512 4fb2a67b5acdbd63cf6f252d0116a4b759e0e6daae48d638ce96ec35f24deee44720c45cb0720a26b6a380e66bbde1619173de340375828bc2f4ef943606fe26 WHIRLPOOL 78557d62348844a6cba345f7a9f6eff8e584494e0f0fc95f6410ff0f4f05ef888e7f2bdefbf03904ff7e9fffcd1d81a7c3373ebd58ee182a91eddbcc129320e0
 DIST gnome-photos-3.24.2.tar.xz 984372 SHA256 31ddc078ad2f6bc4bbfa2f71eb23377782750b9cb2ad2b0e6ff2a1971548cdf9 SHA512 6747d7f7b0fe8710f299a7cd72916a1abd2e6296d642f9d7bf027de731f0fa4e0f862cb6bcb5622bb2d69298b911433df2a31f37f1f7d02fd4e5582234fe0c9f WHIRLPOOL f8abd3026cbc28b32253e59a89468f44cd5d852394c3e0881e9d06af92776b386ebd97a80d31f54db19a18cfcb94af68cafa87c6a5edbae8f9e063e01a7ce412
+DIST gnome-photos-3.24.3.tar.xz 984796 SHA256 cd365629ce584d223c023676a88b6194012bbc561c4a4b1c8eca462425e76288 SHA512 254fc37cfdfcd1b2d854e1ddb5a71d28aab6da3caa6a8739dcbecdabc8a9cb449b2b4080319bb9b73d4b16464f7a7ab7060304fd1194f3bc8cacc67497567a2c WHIRLPOOL 1cd7bc12fb529fe3f5e168ccee3b1e2ad1f9d6f6d8ece6aad6b05fa49a51115c25d17f43f3532364f5ff0dfd46c8999fc40dec9815227abe94f889a476561e9d
diff --git a/media-gfx/gnome-photos/gnome-photos-3.24.3.ebuild b/media-gfx/gnome-photos/gnome-photos-3.24.3.ebuild
new file mode 100644
index 000000000000..72c739cc8396
--- /dev/null
+++ b/media-gfx/gnome-photos/gnome-photos-3.24.3.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 )
+
+inherit gnome2 python-any-r1 virtualx
+
+DESCRIPTION="Access, organize and share your photos on GNOME"
+HOMEPAGE="https://wiki.gnome.org/Apps/Photos"
+
+LICENSE="GPL-2+ LGPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="flickr test upnp-av"
+
+COMMON_DEPEND="
+	>=app-misc/tracker-1:=[miner-fs]
+	>=dev-libs/glib-2.44:2
+	gnome-base/gsettings-desktop-schemas
+	>=dev-libs/libgdata-0.15.2:0=[gnome-online-accounts]
+	media-libs/babl
+	>=media-libs/gegl-0.3.14:0.3[cairo,jpeg2k,raw]
+	media-libs/gexiv2
+	>=media-libs/grilo-0.3.0:0.3=
+	>=media-libs/libpng-1.6:0=
+	>=net-libs/gnome-online-accounts-3.8:=
+	>=net-libs/libgfbgraph-0.2.1:0.2
+	sci-geosciences/geocode-glib
+	>=x11-libs/cairo-1.14
+	x11-libs/gdk-pixbuf:2
+	>=x11-libs/gtk+-3.22.15:3
+"
+# gnome-online-miners is also used for google, facebook, DLNA - not only flickr
+# but out of all the grilo-plugins, only upnp-av and flickr get used, which have USE flags here,
+# so don't pull it always, but only if either USE flag is enabled
+RDEPEND="${COMMON_DEPEND}
+	net-misc/gnome-online-miners[flickr?]
+	upnp-av? ( media-plugins/grilo-plugins:0.3[upnp-av] )
+	flickr? ( media-plugins/grilo-plugins:0.3[flickr] )
+"
+DEPEND="${COMMON_DEPEND}
+	app-text/yelp-tools
+	dev-util/desktop-file-utils
+	>=dev-util/intltool-0.50.1
+	virtual/pkgconfig
+	test? ( $(python_gen_any_dep 'dev-util/dogtail[${PYTHON_USEDEP}]') )
+"
+
+python_check_deps() {
+	use test && has_version "dev-util/dogtail[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+src_configure() {
+	# XXX: how to deal with rdtscp support, x86intrin
+	gnome2_src_configure \
+		$(use_enable test dogtail)
+}
+
+src_test() {
+	virtx emake check
+}