media-libs/libmediainfo: version bump to 0.7.96

2 files changed, 84 insertions, 0 deletions

diff --git a/media-libs/libmediainfo/Manifest b/media-libs/libmediainfo/Manifest
index 08bad8ad6b0b..725ecc009738 100644
--- a/media-libs/libmediainfo/Manifest
+++ b/media-libs/libmediainfo/Manifest
@@ -1,2 +1,3 @@
 DIST libmediainfo_0.7.94.tar.xz 1591624 SHA256 10e7926373611815e494ff00ee0fc8766076b4f241da153a9baf7dfa029cad32 SHA512 80a71b84e4799dd1057cc9f44695bff4b4e468cea3c99a068d4abde1e07b534901100fd05a79071c2d96aa104111f8ed7e6e462f2355b097efe4671743ffaa43 WHIRLPOOL 08484fed520fff31eefa01d7b7fb35516d7d07e9770e8cf0841becb52a500ac05e9d24a110e2193d7445d4755cffe3fe35871a991e64833d00b46ad28204c401
 DIST libmediainfo_0.7.95.tar.xz 1596832 SHA256 432cd106d93fa067d61b36bad5376a431448fea1fa40b7397b851506b562d96a SHA512 635fa904515a7bd57b490a3da0bb2dab91629e9a2866b36cd69752e34aa4bd5947ba8b80c45c9788ad1832f92536fa291e1cbaed0ae10e983fe5941b800b25bd WHIRLPOOL 48f7f383f3e8a3f9fea150e0a5befc7d37931bcfd81ff1c237ecfc59fecb9e0b0cc56a0e6ff93286369209c90cdcd3aa4a3d3c42dcbe2298a33024ed0de2476b
+DIST libmediainfo_0.7.96.tar.xz 1597404 SHA256 fd68e334b29da7c2e1afe5664ef6678d71f00d439c2156b94388a9b481444265 SHA512 14cfe6d11038263e2f11ed9c36a8b954d0937dea9cd7401b26e90e92f2695afc81a388b674669184ecce033d681eaa9f190636d674fd230a24e1196a6ed1992b WHIRLPOOL e0a3048962bcf0d55b5e67461110a1cec1498351cd11e59bfece29a4b461f66191e3d4373a8473d2889dc2f868d8045f905063c6fd877df0e88cf7e44dfae85e
diff --git a/media-libs/libmediainfo/libmediainfo-0.7.96.ebuild b/media-libs/libmediainfo/libmediainfo-0.7.96.ebuild
new file mode 100644
index 000000000000..fb27ee39247a
--- /dev/null
+++ b/media-libs/libmediainfo/libmediainfo-0.7.96.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit autotools eutils flag-o-matic
+
+MY_PN="MediaInfo"
+DESCRIPTION="MediaInfo libraries"
+HOMEPAGE="http://mediaarea.net/mediainfo/ https://github.com/MediaArea/MediaInfoLib"
+SRC_URI="http://mediaarea.net/download/source/${PN}/${PV}/${P/-/_}.tar.xz"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="curl doc mms static-libs"
+
+RDEPEND="sys-libs/zlib
+	dev-libs/tinyxml2:=
+	>=media-libs/libzen-0.4.34[static-libs=]
+	curl? ( net-misc/curl )
+	mms? ( >=media-libs/libmms-0.6.1[static-libs=] )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )"
+
+# tests try to fetch data from online sources
+RESTRICT="test"
+
+S=${WORKDIR}/${MY_PN}Lib/Project/GNU/Library
+
+src_prepare() {
+	eapply -p4 "${FILESDIR}"/${PN}-0.7.63-pkgconfig.patch
+	eapply_user
+
+	sed -i 's:-O2::' configure.ac || die
+	append-cppflags -DMEDIAINFO_LIBMMS_DESCRIBE_SUPPORT=0
+
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--enable-shared \
+		--with-libtinyxml2 \
+		$(use_with curl libcurl) \
+		$(use_with mms libmms) \
+		$(use_enable static-libs static) \
+		$(use_enable static-libs staticlibs)
+}
+
+src_compile() {
+	default
+
+	if use doc; then
+		cd "${WORKDIR}"/${MY_PN}Lib/Source/Doc
+		doxygen Doxyfile || die
+	fi
+}
+
+src_install() {
+	if use doc; then
+		local HTML_DOCS=( "${WORKDIR}"/${MY_PN}Lib/Doc/*.html )
+	fi
+
+	default
+
+	edos2unix ${PN}.pc #414545
+	insinto /usr/$(get_libdir)/pkgconfig
+	doins ${PN}.pc
+
+	for x in ./ Archive Audio Duplicate Export Image Multiple Reader Tag Text Video; do
+		insinto /usr/include/${MY_PN}/${x}
+		doins "${WORKDIR}"/${MY_PN}Lib/Source/${MY_PN}/${x}/*.h
+	done
+
+	insinto /usr/include/${MY_PN}DLL
+	doins "${WORKDIR}"/${MY_PN}Lib/Source/${MY_PN}DLL/*.h
+
+	dodoc "${WORKDIR}"/${MY_PN}Lib/*.txt
+
+	prune_libtool_files
+}