media-radio/tucnak: Version bump

Package-Manager: Portage-2.3.40, Repoman-2.3.9

2 files changed, 69 insertions, 0 deletions

diff --git a/media-radio/tucnak/Manifest b/media-radio/tucnak/Manifest
index 4c7521cf4cd2..5a57d05d8bb0 100644
--- a/media-radio/tucnak/Manifest
+++ b/media-radio/tucnak/Manifest
@@ -1 +1,2 @@
 DIST tucnak-4.11.tar.gz 3517554 BLAKE2B 70f704f1251a9a8411ffceaff56b445160affe523e3aa665e7a6a54a2b3c8bfa5e934143b8a342d02240b929a9219287ca2eed74de1d2a906905162fcc2ad74b SHA512 510c13b181f2417e7fddfd13d808288624bfbf3c0e26cab712a7401d24e53432ad4a270a43f8224a75359a2a31ea3f4d7992583bee8188292ed7d8bc5ad8e8a0
+DIST tucnak-4.13.tar.gz 3516237 BLAKE2B 81d2f11ff2cc619ff22072355b08341115f4fcf33af9e9348a73980ba09e61282027d0b0f838682a2143b5d7d06db38b6b8ee502f16dfcded4e63eddb757afdb SHA512 5d5ca272240442cf2727a1285e560f04df6de96f88d990171a53320fb436b46ead7da1701ec4192fc18fab5f97b7a0b50a1025675e78653390301ee3b739d0d3
diff --git a/media-radio/tucnak/tucnak-4.13.ebuild b/media-radio/tucnak/tucnak-4.13.ebuild
new file mode 100644
index 000000000000..911cc5d37830
--- /dev/null
+++ b/media-radio/tucnak/tucnak-4.13.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit autotools flag-o-matic multilib
+
+DESCRIPTION="Amateur Radio VHF Contest Logbook"
+HOMEPAGE="http://tucnak.nagano.cz"
+SRC_URI="http://tucnak.nagano.cz/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="alsa fftw gpm hamlib suid"
+
+RDEPEND="dev-libs/glib:2
+	dev-libs/libzia
+	media-libs/libsndfile
+	>=media-libs/libsdl-1.2
+	alsa? ( media-libs/alsa-lib )
+	fftw? ( sci-libs/fftw:3.0 )
+	gpm? ( sys-libs/gpm )
+	hamlib? ( media-libs/hamlib )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+src_prepare() {
+	eapply_user
+	# fix destop file
+	sed -i -e "s/HamRadio/HamRadio;/" share/applications/tucnak.desktop || die
+	# fix doc install path
+	sed -i -e "s/docsdir/# docsdir/" \
+		-e "s/docs_DATA =/# docs_DATA/" \
+		-e "s/EXTRA_DIST =/# EXTRA_DIST =/" Makefile.am doc/Makefile.am || die
+	eautoreconf
+}
+
+src_configure() {
+	append-ldflags -L/usr/$(get_libdir)/hamlib
+	econf $(use_with alsa) \
+		$(use_with gpm) $(use_with hamlib) \
+		$(use_with fftw fftw3)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+	dodoc AUTHORS ChangeLog doc/NAVOD.pdf
+	if use suid ; then
+		fperms 4711 /usr/bin/soundwrapper
+	fi
+}
+
+pkg_postinst() {
+	elog "In order to use sound with tucnak add yourself to the 'audio' group"
+	elog "and to key your rig via the parport add yourself to the 'lp' group"
+	elog ""
+	elog "tucnak can be used with the following additional packages:"
+	elog "	   media-radio/cwdaemon  : Morse output via code cwdaemon"
+	elog "                             (No need to recompile)"
+	if use suid ; then
+		ewarn "You have choosen to install the little helper program 'soundwrapper'"
+		ewarn "setuid by setting USE=suid. That helper is only needed if you"
+		ewarn "want to use morse sidetone output via the PC speaker."
+		ewarn ""
+		ewarn "While the helper should be safe by design be aware that setting"
+		ewarn "any program setuid is a security risk."
+	fi
+}